Jump to content

Retired Crossmod Author's Corner: Saerileth


cmorgan

Recommended Posts

SoA: Two banters, plus one Underdark Banter

 

File: aranaware_saerileth_SoAbanters.d

/* SoA Banters : Aran-Saerileth */
CHAIN IF ~Global("c-aran1saerileth","GLOBAL",0)
InParty(Myself) !StateCheck(Myself,CD_STATE_NOTVALID)
InParty("Saerileth") InMyArea("Saerileth") !StateCheck("Saerileth",CD_STATE_NOTVALID)
CombatCounter(0) !See([ENEMY])~
THEN C-ARANB c-aran1saerilethbanter
~[ARAN] Lady Paladin, I'd be a might happier if you would take th' time to answer me a question, beggin' my impertinence.~
DO ~SetGlobal("c-aran1saerileth","GLOBAL",1)~
== BSAERILE ~[sAERILETH] Speak on, Aran.~
== C-ARANB IF ~!Global("SaerilethRomanceActive","GLOBAL",2)~ THEN ~[ARAN] <CHARNAME>'s rightly leader here, an' I expect has reason to have so young a lass on th' front lines. I was workin' trade costers m'self at your age, so I got no problem wi' that. But you seem a bit more focused on what be right an' wrong than what be practical.~
== C-ARANB IF ~Global("SaerilethRomanceActive","GLOBAL",2)~ THEN ~[ARAN] <CHARNAME>'s rightly leader here, an' I expect has reason to have so young a lass on th' front lines. I was workin' trade costers m'self at your age, so I got no problem wi' that. But you both seem a mite bit more than just comrades in arms.~
== BSAERILE IF ~!Global("SaerilethRomanceActive","GLOBAL",2)~ THEN ~[sAERILETH] Which would thou choose when the choice must be made: goodness or utility? There is but one answer.~
== BSAERILE IF ~Global("SaerilethRomanceActive","GLOBAL",2)~ THEN ~[sAERILETH] I am his love, and he is mine own.~
== C-ARANB ~[ARAN] An' this answer serves Tyr, on account o' you bein' his Chosen an' all?~
== BSAERILE IF ~!Global("SaerilethRomanceActive","GLOBAL",2)~ THEN ~[sAERILETH] My life is, and hath ever been, Tyr's only. I shall follow his will so long as I have breath.~
== BSAERILE IF ~Global("SaerilethRomanceActive","GLOBAL",2)~ THEN ~[sAERILETH] My life is, and hath ever been, Tyr's. I shall follow his will so long as I have breath. <CHARNAME> knows this. He will understand the depth of my faith.~
== C-ARANB ~[ARAN] I'm not sure I understand that kind o' faith, is all. I never did.~
EXIT

 


/* SoA Banters : Saerileth-Aran */
CHAIN IF ~Global("c-saerileth1aran","GLOBAL",0)
InParty(Myself) !StateCheck(Myself,CD_STATE_NOTVALID)
InParty("c-aran") InMyArea("c-aran") !StateCheck("c-aran",CD_STATE_NOTVALID)
CombatCounter(0) !See([ENEMY])~
THEN BSAERILE c-saerileth1aranbanter
~[sAERILETH] Why dost thou reject the gods? The foul-mouthed oaths thou dost speak do disservice to all.~
DO ~SetGlobal("c-saerileth1aran","GLOBAL",1)~
== C-ARANB ~[ARAN] Come, now, Saerileth. There must o' been a time when you were not so tight-ar... err...  no, I suppose you never did let your hair down, so to speak. You haven't had enough time in life yet.~
== BSAERILE ~[sAERILETH] Thy jesting is misplaced, and I am not amused.~
== C-ARANB ~[ARAN] Now, don't you be gettin' all offended, lass. There be a place for a harmless bit o' language, sometimes. An' Tymora seems to be fine wi' me playin' fast an' loose.~
== C-ARANB IF ~OR(2) Class("c-aran",PALADIN_ALL) Class("c-aran",CLERIC_ALL)~ THEN ~[ARAN] How about we not get our respective gods into no minor squabble just on account o' my blasphemin', eh?~
== C-ARANB IF ~!Class("c-aran",PALADIN_ALL) !Class("c-aran",CLERIC_ALL)~ THEN ~[ARAN] I know I am no champion o' virtue. I done lost that in a card game when I... never you mind that. But I try to back <CHARNAME>, an' you back <CHARNAME>, so that has to count for somethin', eh?~
== BSAERILE IF ~OR(2) Class("c-aran",PALADIN_ALL) Class("c-aran",CLERIC_ALL)~ THEN ~[sAERILETH] I do pity thee that thou knowest not yet the wishes of thy god. Foul-mouthed blasphemy will forfeit the good will of all of the gods.~
== BSAERILE IF ~!Class("c-aran",PALADIN_ALL) !Class("c-aran",CLERIC_ALL)~ THEN ~[sAERILETH] I do pity thee that thou knowest not yet the power of worshiping one god above all others. Foul-mouthed blasphemy will forfeit the good will of all of the gods.~
== C-ARANB ~[ARAN] Is this somethin' where you are likely to raise a sword against me if I curse a mite here an' there?~
== BSAERILE ~[sAERILETH] As long as thou dost tread the path of good, I will sojourn with thee. But I warn thee... curb thy language.~
== C-ARANB ~[ARAN] You know, hearin' those words from a little slip o' a girl not even out o' apprentice age might be laughable in some circumstances. But seein' as you can hold your own in combat an' healin', I will take you right serious. At least, as far as I can. Hard to break old habits.~
EXIT

 

/* SoA UD Banters : Aran-Saerileth   */
CHAIN IF ~Global("c-drow","GLOBAL",1) Global("c-aranudsaerileth","GLOBAL",0)
InParty(Myself) !StateCheck(Myself,CD_STATE_NOTVALID)
InParty("Saerileth") InMyArea("Saerileth") !StateCheck("Saerileth",CD_STATE_NOTVALID)
CombatCounter(0) !See([ENEMY])~
THEN C-ARANB AranSaerUDBanter
~[ARAN] I know I don't rightly take you serious all th' time. You be a fine companion, though a mite bit stubborn an' mayhap a bit fanatical. But here, I can see why a lad might follow in your footsteps a mite. This place deserves to be eradicated.~
DO ~SetGlobal("c-aranudsaerileth","GLOBAL",1)~
== BSAERILE ~[sAERILETH] 'Twould be false in me to deny that the continued existence of this place doth trouble me.~
== C-ARANB ~[ARAN] I'd think it be time to call forth a holy crusade, an' clear 'em off out o' here. Mayhap destroy evey last one o' them.~
== BSAERILE ~[sAERILETH] Our mortal lives do oft seem full of injustice, but if our lots are here unjust, we may rest assured that the Maimed Tyr will not deny us justice when he doth judge us. But all of these creatures have chosen to serve evil. Their judgment hath been wrought, their lot decided, and eventually they shall fall to the power of Tyr.~
== C-ARANB ~[ARAN] I don't suppose there be some who might follow a good cause down here, eh? Mayhap one or two redeemed souls, trapped alongside all this scurryin' evil?~
== BSAERILE ~[sAERILETH] Forgive me. My zeal oft overcomes my discretion. In this matter, I spoke hastily; Tyr is the Judge, and I am his Champion. Perhaps there are a few souls the Maimed One would have me spare. It is not my decision to make.~
== C-ARANB ~[ARAN] Well, now you done got me worried. Usually, you be th' one takin' things to extremes. I was about to suggest we just send 'em all Tyr's way, an' let him figure out who goes where. I think down here, I be a might bit more comfortable wi' "guilt by association".~
EXIT

 

SoA: comment on romance

File: aranaware_saerileth_SoAcomment.baf

/* Saerileth Commentary SoA : Are you sure about this romance? : Activate */
IF
 InParty("Saerileth")
 InMyArea("Saerileth")
 !StateCheck("Saerileth",CD_STATE_NOTVALID)
 InParty(Myself)
 !StateCheck(Myself,CD_STATE_NOTVALID)
 CombatCounter(0)
 Global("SaerilethRomanceActive","GLOBAL",2)
 Global("c-aranpcsaerrom","GLOBAL",0)
THEN
 RESPONSE #100
SetGlobal("c-aranpcsaerrom","GLOBAL",1)
END

/* Saerileth Commentary SoA : Are you sure about this romance? : Initiate */
IF
GlobalTimerExpired("c-aransmalltalk","GLOBAL") // Timer (game-time) has expired
Global("c-silencearan","GLOBAL",0)	// a PID - set "silencer" for folks who hate unsolicited comments
Global("c-aranpcsaerrom","GLOBAL",1)
InParty(Myself)
!StateCheck(Myself,CD_STATE_NOTVALID)
!StateCheck(Player1,CD_STATE_NOTVALID)
THEN
RESPONSE #100
	StartDialogNoSet(Player1)
END

 

File: aranaware_saerileth_SoAdialog.d

APPEND C-ARANJ

/* Saerileth Commentary SoA : Are you sure about this romance? : Dialog */
IF WEIGHT #-1 ~Global("c-aranpcsaerrom","GLOBAL",1)~ THEN BEGIN carsar1
 SAY ~[ARAN] Now, this be naught in th' way o' my business. But I have to ask... are you an' Saerileth gettin' serious?~
 ++ ~[PC] Of course not. That is a ridiculous suggestion.~ DO ~SetGlobal("c-aranpcsaerrom","GLOBAL",2)~ + carsar2
 ++ ~[PC] What do you think?~ DO ~SetGlobal("c-aranpcsaerrom","GLOBAL",2)~ + carsar3
 ++ ~[PC] Yes.~ DO ~SetGlobal("c-aranpcsaerrom","GLOBAL",2)~ + carsar4
 ++ ~[PC] Are we holding hands and kissing occasionally? Yes, I think we are. Are we getting serious? I am not sure.~ DO ~SetGlobal("c-aranpcsaerrom","GLOBAL",2)~ + carsar4
 ++ ~[PC] Do I ask you about your dalliances with half of Faerun?~ DO ~SetGlobal("c-aranpcsaerrom","GLOBAL",2)~ + carsar3
 ++ ~[PC] Speak of this to me again, and you will be looking for a new line of work. And perhaps searching for your missing head.~ + carsar10
END

IF ~~ carsar2
 SAY ~[ARAN] You must be blighted blind, then. Th' lass looks at you wi' th' intensity o' first love, an' th' passions o' a full grown woman. You'd best be careful around her, on account o' she might get th' wrong idea - or worse, th' right one.~
 ++ ~[PC] I don't really need to be careful. I think I am falling for her.~ + carsar4
 ++ ~[PC] Are we holding hands and kissing occasionally? Yes, I think we are. Are we getting serious? I am not sure.~+ carsar8
 ++ ~[PC] Do I ask you about your dalliances with half of Faerun?~ DO ~SetGlobal("c-aranpcsaerrom","GLOBAL",2)~ + carsar3
 ++ ~[PC] Speak of this to me again, and you will be looking for a new line of work. And perhaps searching for your missing head.~ + carsar10
END  

IF ~~ carsar3
 SAY ~[ARAN] Look, <CHARNAME>, I love th' way women move, th' way they speak, th' way they smell, th' way they smile... hells, I just love women. But me an' someone what wears th' flower be a mite different than what you are talkin' about. First off, we all have th' age o' consent. Second off, if I tick off th' lady in question, she may box my ears, kick me, get me thrown into th' street, or mayhap carve me up a little, as be her choice. With Saerileth...~
 IF ~~ THEN GOTO carsar8
END

IF ~~ carsar4
 SAY ~[ARAN] Do you be kiddin' wi' me? A lass what has seen less than sixteen winters? Give her a year to come o' age a' make her own chices, an' mayhap I wouldn't kick her out o' my b... err...  well, she is pretty an' all, I guess. But she don't know squat about livin', let alone havin' a serious relationship. Tyr's Blasted Buttocks, don't send a child to do adult's work, <CHARNAME>. Love isn't just for play.~
 ++ ~[PC] Take one look into her eyes, and tell me that she does not love me.~ + carsar5
 ++ ~[PC] She is the Chosen of Tyr. She is strong enough, wise enough, and driven enough to know her own mind. Do you really think we would be together if she was not set on having it that way?~ +  carsar6
 ++ ~[PC] What, are you jealous? I did not know you were in love with her too.~ + carsar7
 ++ ~[PC] It is a passing crush, and I intend to have as much fun with her as her religious views will allow.~ + carsar8
 ++ ~[PC] So now you are an expert on serious relationships? That is a laugh. You don't even remember the barmaid's name the next morning.~ + carsar3
END

IF ~~ carsar5
 SAY ~[ARAN] Aye, she does. That be even more dangerous.~
 IF ~~ THEN GOTO carsar9
END

IF ~~ carsar6
 SAY ~[ARAN] Mayhap you are right. Mayhap she be older than her years, an' wiser than a sage; mayhap she be mature enough to understand that relationships be work as well as fun. But all that wisdom an' such be packed into a body what be still growin' an' changin'.~
 IF ~~ THEN GOTO carsar9
END

IF ~~ carsar7
 SAY ~[ARAN] Jealous? No possibility o' that, boyo. She scares me half to death.~
 IF ~~ THEN GOTO carsar9
END

IF ~~ carsar9
 SAY ~[ARAN] Look, <CHARNAME>, I love th' way women move, th' way they speak, th' way they smell, th' way they smile... hells, I just love women. But me an' someone what wears th' flower be a mite different than what you are talkin' about. First off, we all have th' age o' consent, meanin' we can make our own choices. Second off, if I tick off th' lady in question, she may box my ears, kick me, get me thrown into th' street, or mayhap carve me up a little, as be her choice. With Saerileth...~
 IF ~~ THEN GOTO carsar8
END

IF ~~ carsar8
 SAY ~[ARAN] You know how 'hell hath no fury like a woman scorned'? Well, take one look at her an' all you see is slim little hips, curves to die for, an' lips beggin' to be kissed - not one bit o' th' hells about her. Take a look in her eyes, though, an' you see an intensity an' a devotion that be downright scary. Now picture her if you hurt her. There won't be any place on any o' th' Planes where you could hide from her wrath. She'll rip you in half wi' her bare hands, then heal you up just so she can do it again.~
 ++ ~[PC] You are taking this too seriously. I am much more powerful than she is. She will never be able to defeat me.~ + carsar10
 ++ ~[PC] I don't intend to hurt her. I think she may be my soulmate.~ + carsar10
 ++ ~[PC] She's a bunny rabbit. What's she going to do, nibble my bum?~ +  carsar10 /* heh - Monty Python is fun. But this one might be a good one to lose. */
 ++ ~[PC] This is my business, not yours. Keep out of it.~ + carsar10
END

IF ~~ carsar10
 SAY ~[ARAN] None o' my business, anyways. You think you can handle it. But I have been on th' receivin' end o' a regular woman what feels she has been wronged, an' it were a mite painful. Breakin' th' heart o' someone with th' feelin's o' adolescent first love who just happens to be an accomplished fighter an' th Chosen o' Tyr... that's bloody suicide.~
 IF ~~ THEN EXIT
END

END

 

Installed and tested.

Link to comment

Banters donated to Crossmod Banter Pack; Reaction to romance talk placed into the regular .d and .baf in Aran Whitehand. Since non-existing dv's don't crash the game, using the dialogue as a "crossmod" is just a way to keep the standard mod free of bloat on installs that do not have Saerileth. And that ship has sailed - there are tons of pathways and diversions in the main mod screened by DV's only a few diehard Mega folks will even have the *chance* to see.

Link to comment

Archived

This topic is now archived and is closed to further replies.

×
×
  • Create New...