When is an I_C_T not an I_C_T?

[cmorgan]

When it is set up to run on a townsperson/guard with a designated dialog file, and that file is all RandomNumber() and all states use simple IF ~~ THEN EXIT triggers.

 

Luckily, following an exact copy and rebuild of BioWare™'s coding works great. Extend the dialogs with a RandomNum(2,1) and don't fill ot the second condition so that it has a 50% chance of firing, and then have at it...

 

APPEND DMTOWN1

IF ~See("c-aran") InParty("c-aran") !StateCheck("c-aran",CD_STATE_NOTVALID) RandomNum(2,1) Global("dmtown1aran","AR0500",0)~ THEN BEGIN a1774
 SAY ~By Helm... yer outfitted for battle. I'd give my right arm for some o' that gear.~
 IF ~~ THEN DO ~SetGlobal("dmtown1aran","AR0500",1)~ EXTERN ~C-ARANJ~ a1771 // chain
END

END

APPEND DMTOWN2

IF ~See("c-aran") InParty("c-aran") !StateCheck("c-aran",CD_STATE_NOTVALID) RandomNum(2,1) Global("dmtown1aran","AR0500",0)~ THEN BEGIN a1773
 SAY ~Ay, now... you looks like a sword for hire, you does. You lookin' for some work?~
 IF ~~ THEN DO ~SetGlobal("dmtown2aran","AR0500",1)~  EXTERN ~C-ARANJ~ a1772 // chain
END

END

APPEND GMTOWN01

IF ~See("c-aran") InParty("c-aran") !StateCheck("c-aran",CD_STATE_NOTVALID) RandomNum(2,1) Global("gmtown01aran","GLOBAL",0)~ THEN BEGIN a1775
 SAY ~Is that spitting really becessary? This is not the slums, you know.~
 IF ~~ THEN DO ~SetGlobal("gmtown01aran","GLOBAL",1)~  EXTERN ~C-ARANJ~ a1779  // join
END

IF ~See("c-aran") InParty("c-aran") !StateCheck("c-aran",CD_STATE_NOTVALID) RandomNum(2,1) Global("gmtown01aran","GLOBAL",0)~ THEN BEGIN a1776
 SAY ~Mmm...I haven't been to one of the spa tubs in ages.  It's the only luxury we, here, in the city really have.~
 IF ~~ THEN DO ~SetGlobal("gmtown01aran","GLOBAL",1)~  EXTERN ~C-ARANJ~ a1780 // chain
END

END

APPEND GMTOWN02

IF ~See("c-aran") InParty("c-aran") !StateCheck("c-aran",CD_STATE_NOTVALID) RandomNum(2,1) Global("gmtown02aran","GLOBAL",0)~ THEN BEGIN a1777
 SAY ~You, there!  You look like the fighting type!  Are you in the army?  Can I join through you?~
 IF ~~ THEN DO ~SetGlobal("gmtown02aran","GLOBAL",1)~ EXTERN ~C-ARANJ~ a1781
END

IF ~See("c-aran") InParty("c-aran") !StateCheck("c-aran",CD_STATE_NOTVALID) RandomNum(2,1) Global("gmtown02aran","GLOBAL",0)~ THEN BEGIN a1778  
 SAY ~I am here to join the glorious army of Amn!  There are victories to be had and both coin and women to earn!~
 IF ~~ THEN DO ~SetGlobal("gmtown02aran","GLOBAL",1)~ EXTERN ~C-ARANJ~ a1782
END

END

APPEND ~C-ARANJ~

IF ~~ a1779
 SAY ~[ARAN] I don't rightly think a little bit o' moisture is goin' to hurt anythin' around here. An' dust be dust, city or country. But I take your point, it were blighted rude o' me.~
 IF ~~ THEN EXIT
END

IF ~~ a1782
SAY ~[ARAN] Ah, that be th' call o' th' Wild Recruiter. "Join th' Army! Coin, Wine, Women, Song, Travel!" I'd be changin' that around, a mite. "Join th' Army! Lice! Weeks Of Tedious Boredom Punctuated By Moments O' Sheer Terror An' Mortal Danger! All th' Ditches you can Dig! Travel to New Places, Meet New People, Then Kill 'Em! Wine, Women, an' Song subject to your own coin, an' we don't pay for none o' th' problems what result." Then again, it probably wouldn't bring in young idiots what think duty in a far-flung colony be a walk in th' park.~
IF ~~ THEN EXIT
END

END


CHAIN ~C-ARANJ~ a1771
~[ARAN] They say th' gear don't make th' man. But it do help, eh?~
== DMTOWN1 ~[DMTOWN1] Take it from one who spent a little time in Maztica. Good gear saves lives.~
== ~C-ARANJ~ ~[ARAN] Brother, I hear you. You spend a long time?~
== DMTOWN1 ~[DMTOWN1] Two years before I came to my senses and went back to civilian life. I'll take my chances with the dangerous nightlife around here. At least that I can predict.~
== ~C-ARANJ~ ~[ARAN] Well, good luck to you. I don't think i could take th' quiet life for too long, but it seems to have agreed wi' you.~
== DMTOWN1 ~[DMTOWN1] Good luck and a pearl to you.~
EXIT

CHAIN ~C-ARANJ~ a1772
~[ARAN] Why, do you know o' any?~
== DMTOWN2 ~[DMTOWN2] Well, there's always some hirin' o' watchmen, and sometimes they need a bouncer at some inns.~
== ~C-ARANJ~ ~[ARAN] So, long story short, you got nothin'.~
== DMTOWN2 ~[DMTOWN2] Hey, don't get touchy. We were just makin' conversation!~
== ~C-ARANJ~ ~[ARAN] Civilians. Can't live with 'em, can't live wi' out 'em. An' if you take 'em out back to beat some sense into 'em, you end up wi' a tenday in jail an' a stiff fine.~
EXIT

CHAIN ~C-ARANJ~ a1781
~[ARAN] Why, sure thing. I can help you out right quick. You ever heard o' th' Jerva's Jerkins? They be th' toughest, most fierce company Amn has to be offerin'. An' I can get you an introduction, for only 5 gold.~
== GMTOWN02 ~[GMTOWN02] I don't have that much. What will 3 gold get me?~
== ~C-ARANJ~ ~[ARAN] Well, I could hook you up wi' a lad what served in th' regulars in Maztica...~
== GMTOWN02 ~[GMTOWN02] I really don't have more than 3 copper pieces to spare. What will that get me?~
== ~C-ARANJ~ ~[ARAN] For 3 coppers, I can start your hazin' ritual right away, by takin' your coin an' tossin' both you an' your bloody coin in th' nearest latrine.~
EXIT

CHAIN ~C-ARANJ~ a1780
~[ARAN] Now that be true enough. Though I doubt there be anythin' around here like those in Calimport, eh?~
== GMTOWN01 ~We have a much more civilized approach to bathing here in Amn. Although it does not appear that you are familiar with the concept of bathing.~
== ~C-ARANJ~ ~[ARAN] Bane's... right. Don't suppose it would do us much good if I respond. Shuttin' up an' soldierin'.~
EXIT