Jump to content

Photo

More dialogue fixes


9 replies to this topic

#1 CamDawg

CamDawg

    ALL GLORY TO THE HYPNOTOAD

  • Gibberling Poobah
  • 9753 posts
  • Gender:Not Telling

Posted 29 July 2017 - 01:26 PM

Some weeks back I also received, via PM, a couple hundred lines of .d code fixes that I'm working through for beta 3. So far they're solid--I'm not sure why the person PM'd instead of posted, but in case it was for anonymity I'm not going to out him or her. If it wasn't for anonymity, I hope they'll post and take their richly deserved credit.


Why is this Hypnotoad video so popu... ALL GLORY TO THE HYPNOTOAD.


#2 jastey

jastey
  • Gibberlings
  • 7532 posts
  • Gender:Female

Posted 29 July 2017 - 01:42 PM

This is both exciting and scary. Exciting - more dialogue lines, yay! But scary - will my mods' interjections still work????!!?!!11

Thank you for the work you put into this!



#3 CamDawg

CamDawg

    ALL GLORY TO THE HYPNOTOAD

  • Gibberling Poobah
  • 9753 posts
  • Gender:Not Telling

Posted 29 July 2017 - 04:34 PM

So far they've been smaller and/or more subtle fixes. For example, when Jaheira gets cursed by Ployer, you basically have three paths you can follow in her dialogue afterwards--one kicks her out, and only on one of the other two paths does she mention going to the government district and asking about the mages.


Why is this Hypnotoad video so popu... ALL GLORY TO THE HYPNOTOAD.


#4 CamDawg

CamDawg

    ALL GLORY TO THE HYPNOTOAD

  • Gibberling Poobah
  • 9753 posts
  • Gender:Not Telling

Posted 29 July 2017 - 09:42 PM

Here you go jastey--hopefully nothing that will cause much pain. The code was sent over without comments as to what it was changing or why, so the comments in the code are mine so I can remember why we're doing what. The changes:
 
// other "i'm leaving " replies lead here
ALTER_TRANS ACOLYTE2 BEGIN 2 END BEGIN 3 END BEGIN ~EPILOGUE~ ~GOTO 4~ END // originally went to 3

// one more line
ALTER_TRANS BANOMEN BEGIN 257 END BEGIN 0 END BEGIN ~EPILOGUE~ ~GOTO 258~ END // originally just exited

// better bernard response
ALTER_TRANS BERNARD BEGIN 8 END BEGIN 2 END BEGIN ~EPILOGUE~ ~GOTO 3~ END // originally to 5 (can get there from 3)

// banter with edwin mentions being in jaheira's domain and traveling back to the city
ADD_STATE_TRIGGER BJAHEIR 36 ~AreaType(FOREST)~

// one more nalia complaint before handoff to mazzy
ALTER_TRANS BNALIA BEGIN 0 END BEGIN 0 END BEGIN ~EPILOGUE~ ~GOTO 47~ END // originally went to bmazzy 3, now bnalia 47 > bmazzy 3

// valygar speaks as though lavok has already been taken care of
ADD_STATE_TRIGGER BVALYGA 41 ~Dead("Lavok02")~

// extra lines, better order in viconia's banter about husbands, now 156 > 158 > 159 > 157 > 87, was 156 > 157 > 87
ALTER_TRANS BVICONI BEGIN 156 END BEGIN 0 END BEGIN ~EPILOGUE~ ~GOTO 158~ END // originally went straight to 157
ALTER_TRANS BVICONI BEGIN 159 END BEGIN 0 END BEGIN ~EPILOGUE~ ~GOTO 157~ END // originally to 87

// restores extra exposition line re: lolth
ALTER_TRANS BVICONI BEGIN 332 END BEGIN 0 END BEGIN ~EPILOGUE~ ~GOTO 433~ END // originally went to 336, now 433 > 336
ALTER_TRANS BVICONI BEGIN 341 END BEGIN 0 END BEGIN ~EPILOGUE~ ~GOTO 433~ END // originally went to 336, now 433 > 336

// additional line about Nalia
ALTER_TRANS DALESON BEGIN 5 END BEGIN 2 END BEGIN ~EPILOGUE~ ~GOTO 32~ END // originally went to 11, but other Nalia questions go through 32 then 11

// threatening the beggar goes to correct response
ALTER_TRANS DBEGGAR BEGIN 1 END BEGIN 4 END BEGIN ~EPILOGUE~ ~GOTO 6~ END // originally went to 7

// restores an extra insult of Delcia's
ALTER_TRANS DELCIA BEGIN 38 END BEGIN 0 END BEGIN ~EPILOGUE~ ~GOTO 6~ END // original went to 7, now 6 > 7

// polite response from player leads to response implying rudeness from player
ALTER_TRANS GERETH BEGIN 3 END BEGIN 1 END BEGIN ~EPILOGUE~ ~GOTO 1~ END // originally went to 4
ALTER_TRANS GERETH BEGIN 3 END BEGIN 3 END BEGIN ~EPILOGUE~ ~GOTO 4~ END // actual impolite response went to 6

// asking about the play misses two lines of prior exposition
ALTER_TRANS HAERDAJ BEGIN 14 END BEGIN 0 END BEGIN ~EPILOGUE~ ~GOTO 53~ END // originally to 9, now 53 > 54 > 9

// asking for the long version also gets a few more lines
ALTER_TRANS HAERDAJ BEGIN 14 END BEGIN 1 END BEGIN ~EPILOGUE~ ~GOTO 50~ END // originally to 7, now 50 > 51 > 7

// asking about young conduit goes to completely unrelated state
ALTER_TRANS HAERDAJ BEGIN 15 END BEGIN 0 END BEGIN ~EPILOGUE~ ~GOTO 57~ END // originally to 8

// gives raelis a few more lines before asking for help
ALTER_TRANS HAERDAJ BEGIN 14 END BEGIN 2 3 END BEGIN ~EPILOGUE~ ~EXTERN RAELIS 64~ END // originally to raelis 9, now raelis 64 > 65 > 9

// checking for wrong item
REPLACE_TRANS_TRIGGER INSPECT BEGIN 31 END BEGIN 0 END ~PartyHasItem("MISC5J")~ ~PartyHasItem("MISC5G")~

// add mention of option to ask about mages in gov't district (jaheira-ployer quest) to match other dialogue branch
ALTER_TRANS JAHEIRAJ BEGIN 45 END BEGIN 0 END BEGIN ~EPILOGUE~ ~GOTO 80~ END // originally went straight to 44, now 80 > 44

// olma's dialogue not properly checking she's speaking to the lord of the manor
ADD_STATE_TRIGGER KPCOOK01 0 ~InPartySlot(LastTalkedToBy,0)~
ADD_STATE_TRIGGER KPCOOK01 1 ~InPartySlot(LastTalkedToBy,0)~
ADD_STATE_TRIGGER KPCOOK01 2 ~InPartySlot(LastTalkedToBy,0)~
ADD_STATE_TRIGGER KPCOOK01 3 ~InPartySlot(LastTalkedToBy,0)~
REPLACE_STATE_TRIGGER KPCOOK01 4 ~!InPartySlot(LastTalkedToBy,0)~

// goes to nicer, thanks for the money response
ALTER_TRANS KPMERC01 BEGIN 12 END BEGIN 0 END BEGIN ~EPILOGUE~ ~GOTO 9~ END // originally went to 14

// happiest farmers should go to happiest finish to dialogue
ALTER_TRANS KPFARM01 BEGIN 3 END BEGIN 0 END BEGIN ~EPILOGUE~ ~EXTERN KPFARM04 2~ END // originally went to kpfarm02 4 (happy, but not perfect ending)

// other "I'm leaving" replies go here
ALTER_TRANS NEVAZIAH BEGIN 23 END BEGIN 3 END BEGIN ~EPILOGUE~ ~GOTO 5~ END // originally went to 4, where he goes hostile

// brings lord ophal's trigger in line with all his other triggers
ADD_STATE_TRIGGER NOBLEM3 5 ~!Dead("noblew3")~

// missing journal entry
ALTER_TRANS PALERN BEGIN 1 END BEGIN 0 END BEGIN ~UNSOLVED_JOURNAL~ ~#11854~ END

// re-enable False()d response
REPLACE_TRANS_TRIGGER PELANNA BEGIN 13 END BEGIN 3 END ~False()~ ~~ // enable this response

// move up tassa spawn one state so she can appear next to pelanna and not use the existing tassa across the map
ALTER_TRANS PELANNA BEGIN 14 20 END BEGIN 0 END BEGIN ~ACTION~ ~~ END                                          // move from here...
ALTER_TRANS PELANNA BEGIN 13 END BEGIN 2 3 END BEGIN ~ACTION~ ~CreateCreatureObject("TASSA",Myself,0,0,0)~ END // .. to here

// prophet now answers the question before demanding worship
ALTER_TRANS PROPHET1 BEGIN 1 END BEGIN 1 END BEGIN ~EPILOGUE~ ~GOTO 10~ END // used to go directly to state 3, now passes through 10 first
ALTER_TRANS PROPHET1 BEGIN 2 END BEGIN 2 END BEGIN ~EPILOGUE~ ~GOTO 10~ END
ALTER_TRANS PROPHET1 BEGIN 5 END BEGIN 0 END BEGIN ~EPILOGUE~ ~GOTO 10~ END

// player reply about commission goes to comment about nobles; this reply appropriately talks about gold offered instead
ALTER_TRANS SCSARLES BEGIN 2 END BEGIN 3 END BEGIN ~EPILOGUE~ ~GOTO 7~ END // originally went to 5

// same question from 2 leads here
ALTER_TRANS SEWERM1 BEGIN 9 END BEGIN 1 END BEGIN ~EPILOGUE~ ~GOTO 6~ END // originally went to 2, where you could ask the identical question again

// other "i'm leaving " replies lead here
ALTER_TRANS SEWERM1 BEGIN 19 END BEGIN 3 END BEGIN ~EPILOGUE~ ~GOTO 22~ END // originally went to 21

// you can ask morsa about how you fare as guildmaster; this change allows you to do so on the first conversation, too
ALTER_TRANS SHTH04 BEGIN 1 END BEGIN 0 END BEGIN ~EPILOGUE~ ~GOTO 2~ END // originally just exited here

// wrong variable name
REPLACE_TRIGGER_TEXT ~TASSA~ ~"TalkedPelanna"~ ~"TalkedToPelanna"~

// restores extra ine from exposition
ALTER_TRANS TRAINER1 BEGIN 4 END BEGIN 0 END BEGIN ~EPILOGUE~ ~GOTO 13~ END // originally went straight to 5

// extra line in Count Claylan-Debutante Alicia banter
ALTER_TRANS WCUST02 BEGIN 0 END BEGIN 0 END BEGIN ~EPILOGUE~ ~EXTERN WCUST01 1~ END // used to just exit here
 
This fix I'm actually going to address with scripting:
 
ADD_TRANS_TRIGGER BAERIE 120 ~OR(2) Dead("Quayle") Dead("quaylem")~ DO 0
ADD_TRANS_TRIGGER BAERIE 120 ~!Dead("quaylem")~ DO 1
 
Fixpack adds the !Dead("quayle") check in state 120 so Aerie's banter branches appropriately if Quayle is alive or dead, but we've made a silly mistake. If Quayle gets killed by Kalah, his DV at the time is QuayleM, not Quayle, and he never spawns in the tent once the illusions are dispelled. I've added a bit to the area script that will set the SPRITE_IS_DEADQuayle global (making Dead("Quayle") true) in these circumstances.
 
Two other changes were sent over, but at this point I'm not including them:
 
ALTER_TRANS DOUG BEGIN 11 END BEGIN 0 END BEGIN ~EPILOGUE~ ~GOTO 10~ END
ADD_STATE_TRIGGER PLFARM06 0 ~Global("PaladinPlot","GLOBAL",8)~
DOUG is the dialogue file of Festule the Alchemist, who offers you the potion to drug the ogre in the Mazzy-Gorf the Squisher fight. This change in particular causes Festule to leave if you tell him his asking price for the potion is outrageous whereas before it simply went to an indignant reply from Festule about how you need to earn more money. In other places throughout the game, you're often given chances to try and negotiate prices, so it seems a bit harsh that you could try it here (and fail) and not get an opportunity to recover.
 
For PLFARM06, I'm going to do a bit more checking, but it appears to be an addition of a redundant trigger. He spawns at PaladinPlot=8 and this is his one available dialogue; anything >8 should get interrupted by PLFARM04 prior to 06 being able to speak.

Why is this Hypnotoad video so popu... ALL GLORY TO THE HYPNOTOAD.


#5 jastey

jastey
  • Gibberlings
  • 7532 posts
  • Gender:Female

Posted 31 July 2017 - 12:28 AM

Thank you!



#6 Abdal

Abdal
  • Members
  • 14 posts
  • Gender:Male

Posted 15 January 2018 - 07:29 AM

Are those restored extra lines included in the latest version of BG2EE or one can only get them for the regular BG2 (since BG2 Fixpack skips most of the stuff when used on a BG2EE install)?



#7 CamDawg

CamDawg

    ALL GLORY TO THE HYPNOTOAD

  • Gibberling Poobah
  • 9753 posts
  • Gender:Not Telling

Posted 15 January 2018 - 09:05 AM

They're going to be part of the 2.5 patch, yes. I'm pretty much working both ends at the moment--stuff found in the EE beta is being included in the current Fixpack betas and vice versa.


Why is this Hypnotoad video so popu... ALL GLORY TO THE HYPNOTOAD.


#8 Abdal

Abdal
  • Members
  • 14 posts
  • Gender:Male

Posted 16 January 2018 - 01:50 AM

They're going to be part of the 2.5 patch, yes. I'm pretty much working both ends at the moment--stuff found in the EE beta is being included in the current Fixpack betas and vice versa.

 

So you mean that the current beta of BG2EE(which can be downloaded already) got some of the restored stuff and fixes from the latest fixpack but the whole content will be released when it goes out of beta, right?

 

Or is all the CURRENT content from the fixpack in the beta already but more stuff is planned to be included in the fully finished ver 2.5?


Edited by Abdal, 16 January 2018 - 01:53 AM.


#9 Jarno Mikkola

Jarno Mikkola

    The Imp

  • Modders
  • 6830 posts
  • Gender:Male
  • Location:The town where the dead haven't keeled over, yet. In Finland.

Posted 16 January 2018 - 02:17 AM

 

They're going to be part of the 2.5 patch, yes. I'm pretty much working both ends at the moment--stuff found in the EE beta is being included in the current Fixpack betas and vice versa.

So you mean that the current beta of BG2EE(which can be downloaded already) got some of the restored stuff and fixes from the latest fixpack but the whole content will be released when it goes out of beta, right?

Or is all the CURRENT content from the fixpack in the beta already but more stuff is planned to be included in the fully finished ver 2.5?

 

It means that as the EE beta's are being made and released, the BG2Fixpack can benefit from that process and thus, some of the fixes can be installed into the non-EE games. The BG2fixpack is not meant for the EE games... as it's already "in" it, so to speak.


Edited by Jarno Mikkola, 16 January 2018 - 04:06 AM.

Welcome to the sanity, you are free to search for the limit, it's out there, we drew it in the sand.
Here's how to install all the ... mods you ever really could want to Infinity Engine games. I removed the stable word from there as Roxanne began to add BS mods that are likely to break compatibility from the BWS.

#10 Abdal

Abdal
  • Members
  • 14 posts
  • Gender:Male

Posted 16 January 2018 - 04:07 AM

 

 

They're going to be part of the 2.5 patch, yes. I'm pretty much working both ends at the moment--stuff found in the EE beta is being included in the current Fixpack betas and vice versa.

So you mean that the current beta of BG2EE(which can be downloaded already) got some of the restored stuff and fixes from the latest fixpack but the whole content will be released when it goes out of beta, right?

Or is all the CURRENT content from the fixpack in the beta already but more stuff is planned to be included in the fully finished ver 2.5?

 

It means that as the EE beta is being made, the BG2Fixpack can benefit from that process and thus, some of the fixes can be installed into the non-EE game. The BG2fixpack is not meant for the EE games... as it's already "in" it, so to speak.

 

 

Well, I just wondered if I should use my beta version of EE or use the fixpack on my original BG2 install for most restored content/fixes.

 

Since the latest update pre-beta happened like half a year ago(or more?) then I'm sure plenty of new stuff was added/improved/fixed by the fixpack since then so I was curious whether to finally give my beta of EE a try or use the fixpack on the original BG2 for the more "complete" experience...


Edited by Abdal, 16 January 2018 - 04:09 AM.




Reply to this topic



  


0 user(s) are reading this topic

0 members, 0 guests, 0 anonymous users