Jump to content

Standard Waking Talks, Resting Talks, C-ARANJ & C-ARAND


cmorgan

Recommended Posts

Lots of tutorials out there, I think, on DreamTalks, hassles with Dream Timers, and all sorts of stuff, so this will probably be more of a "post the talks and be done with it".

 

The easiest - a straightforward "on waking, outside, after Underdark". .bcs, .dlg, and PartyRested(). No need t=for the DreamScript, C-ARAJD, as that script only runs at rest - and since there is no before-rest | after-rest pairing, this one is a straightforward one.

 

c-aran.baf addition:

/* On waking banter, after Underdark : bcs */  

IF
 InParty(Myself)
 Global("c-aranwakeup","LOCALS",0)
 Global("Chapter","GLOBAL",6)
 CombatCounter(0)
 !StateCheck(Myself,CD_STATE_NOTVALID)
 InMyArea(Player1)
 !StateCheck(Player1,CD_STATE_NOTVALID)
 PartyRested()  // this one makes it immediately after rest
 !RealGlobalTimerNotExpired("c-aransmalltalk","GLOBAL") // not while smalltalk timer is still running, so we don't load up
 OR(2)
 AreaType(OUTDOOR)
 AreaType(FOREST)
 !AreaType(DUNGEON)
THEN  
 RESPONSE #100
SetGlobal("c-aranwakeup","LOCALS",1)
RealSetGlobalTimer("c-aransmalltalk","GLOBAL",300)
PlaySong(0)
PlaySound("c-aranft")
StartDialogNoSet(Player1)
END

 

c-aranj.d addition, two possibilities - waking up during day, or waking up during night

/* On waking banter, after Underdark : dlg */  

IF ~Global("c-aranwakeup","LOCALS",1) TimeOfDay(DAY)~ c_nice_to_see_day
 SAY ~[ARAN] Birds. Daylight. Sunrise. Blighted hells, it be nice to stretch out after a real sleep, an' see th' sky...~
 IF ~~ THEN DO ~SetGlobal("c-aranwakeup","LOCALS",2)~ GOTO c_we_made_it
END

IF ~Global("c-aranwakeup","LOCALS",1) TimeOfDay(NIGHT)~ c_nice_to_see_night
 SAY ~[ARAN] Stars. Breezes. Selune Herself, shinin' down. Blighted hells, it be nice to stretch out after a real sleep, an' see th' sky...~
 IF ~~ THEN DO ~SetGlobal("c-aranwakeup","LOCALS",2)~ GOTO c_we_made_it
END

IF ~~ c_we_made_it
 SAY ~[ARAN] for awhile there, I thought we might never get topside again. I did not relish th' thought o' endin' up stuck down in th' Underdark permanent-like.~
 ++ ~[PC] Oh, it wasn't so bad. At least we knew almost everything we met was just waiting for a chance to kill us.~ + c_like_they_arent_now
 ++ ~[PC] The classic Whitehand juxtaposition - say something nice, but add a swear word or two strong enough to blister the ears of young children.~ + c_beautiful_words
 ++ ~[PC] Good, you are up. Get some food going, fast. I am starving!~ + c_and_not_fungus
 + ~Global("c-aranrom","GLOBAL",2) Global("c-aransex","GLOBAL",1)~ + ~[PC] Hey, I am not done with you yet. I still have some unattended romantic business to finish...~ + c_going_to_kill_me
 ++ ~[PC] Shhh. Not so loud. I am going back to sleep for awhile.~ + c_get_up
END

IF ~~ c_like_they_arent_now
 SAY ~[ARAN] We don't have to be in Underdark for that to be true, eh? If danger be th' spice o' life, then I think you be cayenne, paprikea, an' burnin' oil all rolled into one!~
 IF ~~ THEN GOTO c_get_up
END

IF ~~ c_beautiful_words
 SAY ~[ARAN] Fervent feelin's fill foul phrases full, eh? I guess I should o' said "Mystra's Tears", or "Lathander's Smile", or some such.~
 IF ~~ THEN GOTO c_get_up
END  

IF ~~ c_and_not_fungus
 SAY ~[ARAN] Praise be to th' gods, we don't have to worry about no strange creatures showin' up in th' food, an' there be not a mushroom or fungus in sight. Real meal, an' open air.~
 IF ~~ THEN GOTO c_get_up
END  

IF ~~ c_going_to_kill_me
 SAY ~[ARAN] Good gods, woman. You are like to kill me. We can always stop for a mite later, but we'd best be movin' on.~
 IF ~~ THEN GOTO c_get_up
END  

IF ~~ c_get_up
 SAY ~[ARAN] Now, pop right out o' that there bedroll, <CHARNAME>... my cookin' muscles have been all cramped down underground. I can feel a first-class meal comin' on. An' I be in th' mood for a right fine <DAYNIGHT> o' travel an' adventure!~
 IF ~~ THEN EXIT
END

 

Taking ideas for expansion, but sometimes short and sweet is all the scenery dialog you need.

 

Reminders to self - Classic Modder Mixups to recheck in main files -

 

Posible Mismatches:

 

SCOPE.

we set a timer on each fun talk and flirt that tries to space out potential scenery dialog/ fun talks so that you don't end up with several becoming evaluated true at the same time. Some places that tend to load up include the start of every major area, and every chapter, so there is a talk-fest and then not so much. But, is it consistent in its usage? we need to recheck

 

RealSetGlobalTimer("c-aransmalltalk","GLOBAL",300) <-> !RealGlobalTimerNotExpired("c-aransmalltalk","GLOBAL")

 

as a pairing, because if we use the game time timers on either side of this in other code, it will not do what we want it to do.

 

Same with variables - edited above code just now because I set a LOCALS and closed a GLOBAL, which will not work quite as intended...

 

Global("c-aranwakeup","LOCALS",0) <-> SetGlobal("c-aranwakeup","LOCALS",1)

Link to comment

Yep - forgot that. BioWare does the banter file thing, so it doesn't crash because it isn't in .bcs and it is called by the banter engine, which skips folks - the J-file, not so much...

 

fixed.

Link to comment

Messing about with resting in the Keep. As a player, I tend to hang around there whether or not DeArnise is installed, so for this one a few sidelines for the female PC, but for the male ones. The good news about GLOBAL is you can use them even if the mod (in this case Chanelle from Romantic Encounters) is not installed, as long as the "0" condition still makes sense.

 

/* Idea from Jastey's Ajantis code - making sure RE materials and such don't play at the same time - may need to extend with other mod's usage of timers, so only one dreamscript initiated at-rest thing is called. */
/* add to trigger block of scripts in C-ARAND */
/*	!RealGlobalTimerNotExpired("RE_DreamTimer","GLOBAL") */


/* add to transition of dialogs called from C-ARAND to C-ARANJ */
/* RealSetGlobalTimer("RE_DreamTimer","GLOBAL",100) */


/* c-arand.bcs */
/* Stone Walls, Stone Hearts, Stone Heads : Dream Script, De'Arnise Keep (Stronghold) Script */
IF
 InParty(Myself)
 !RealGlobalTimerNotExpired("RE_DreamTimer","GLOBAL")
 CombatCounter(0)
 !StateCheck(Myself,CD_STATE_NOTVALID)
 !StateCheck(Player1,CD_STATE_NOTVALID)
 OR(3)
 AreaCheck("AR1305")
 AreaCheck("AR1306")
 AreaCheck("AR1307")
THEN  
 RESPONSE #100
SetGlobal("c-arandreamstone","GLOBAL",1)
RealSetGlobalTimer("c-aransmalltalk","GLOBAL",300)
RealSetGlobalTimer("c-arandreamtalk","GLOBAL",5000)	
PlaySong(0)
PlaySound("c-aranft")
StartDialogNoSet(Player1)
END

/* Stone Walls, Stone Hearts, Stone Heads : Dream Script, De'Arnise Keep (Stronghold) Dialog */ 

IF ~Global("c-arandreamstone","GLOBAL",1) TimeOfDay(DAY)~ c_in_keep_stronghold_dream_day
 SAY ~[ARAN] There you are. I thought you might be off tryin' to get some sleep.  Hells, there be a shortage o' candles in this place, eh? It be daylight outside, but in here it be gloomier than a one legged man at a dancin' contest. Anyways, I needed to bend your ear a mite.~
 IF ~~ GOTO c_future_direction
END

IF ~Global("c-arandreamstone","GLOBAL",1) TimeOfDay(NIGHT)~ c_in_keep_stronghold_dream_night
 SAY ~[ARAN] There you are. I thought you might be off tryin' to get some sleep.  Hells, there be a shortage o' candles in this place, eh? It be night outside so you'd think they would run out some good lanterns or a spell or two an' brighten th' place up, but in here it be gloomier than a one legged man at a dancin' contest. Anyways, I needed to bend your ear a mite.~
 IF ~~ GOTO c_future_direction  
END  

IF ~~ c_future_direction  
 SAY ~[ARAN] Now that you have a solid defensible position, mayhap you want to gather an army, an' get settled a mite before takin' on th' rest of the world, eh? Not that you have to listen to me, tryin' to tell you what to do. I just keep these lips flappin' way too much.~
 + ~Gender(Player1,FEMALE)~ + ~[PC] Actually, I had some other ideas for those lips of yours. I think I need a respite from all this heavy responsibility.~ + c_start_makeout
 + ~Gender(Player1,FEMALE)~ + ~[PC] I agreed to help Nalia because it was in my best interests. We will wait for as long as it takes me to figure out how to best profit from all of this.~ + c_stone_heart_f
 ++ ~[PC] We have to make sure that the Keep is secured, and things are settled. But we need to move on as quickly as we can, too. I am debating whether to take Nalia along, or leave her here to make sure things get reorganized.~ + c_stone_wall
 ++ ~[PC] You have no idea what you are talking about, and even if you did, what makes you think I want to hear it from you?~ + c_stone_head  
 ++ ~[PC] Aran. Shut up. Go away. Now.~ + c-aranshutup39
 + ~!HPPercentLT(Player1,30)~ + ~[PC] I think we had better move on quickly. I do not think we can afford to wait.~ + c_stone_keep_uninjured
 + ~HPPercentLT(Player1,30)~ + ~[PC] I think we had better move on quickly. I do not think we can afford to wait.~ + c_stone_keep_injured
 + ~Gender(Player1,MALE)~ + ~[PC] I agreed to help Nalia because it was in my best interests. We will wait for as long as it takes me to figure out how to best profit from all of this.~ + c_stone_heart_m   
 + ~Gender(Player1,MALE) Global("RE_ChanelleFlirt","GLOBAL",1) !Global("RE_ChanelleSex","GLOBAL",1)~ + ~[PC] Actually, I was thinking of taking a bath. I think there is a set of washtubs in the master suite.~ + c_cute_maid_rumor
 + ~Gender(Player1,MALE) !Global("RE_ChanelleFlirt","GLOBAL",1) Global("RE_ChanelleSex","GLOBAL",1)~ + ~[PC] Actually, I was thinking of taking a bath. I think there is a set of washtubs in the master suite.~ + c_cute_maid_rumor  
 + ~Gender(Player1,MALE) !Global("RE_ChanelleFlirt","GLOBAL",1) !Global("RE_ChanelleSex","GLOBAL",1)~ + ~[PC] Actually, I was thinking of taking a bath. I think there is a set of washtubs in the master suite.~ + c_cute_maid 
END

IF ~~ c_cute_maid
 SAY ~[ARAN] That sounds like a right nice idea. Just so you know, though, one o' th' maids was askin' about you, for some odd chore or somethin'. I'd duck in an' out o' there right quick, so you don't get no more things to handle tonight. But about my questions, do you have some time, or not?~
 IF ~~ THEN GOTO c_to_business
END  

IF ~~ c_cute_maid_rumor
 SAY ~[ARAN] Riiiight. A bath. Got it. Just be a mite bit more careful when you get in that water, eh? There were a powerful lot o' screamin' an' laughin' last time, an' I think some o' th' servants are beginnin' to talk. But before you go dippin' your various parts into various things, do you have that mite bit o' time?~
 IF ~~ THEN GOTO c_to_business
END 

IF ~~ c_stone_head // 7 replies possible, down to 5 if non-edwin/minsc
 SAY ~[ARAN] What are you blighted well talkin' about? This be my forte, eh? I thought you'd be wantin' some help gettin' this place in order.~
 ++ ~[PC] I can handle things myself. Just go get some sleep, and I'll give you orders in the morning.~ + c_finish_angry_norom
 + ~InParty("edwin") !InParty("minsc") !Global("c-aranrom","GLOBAL",1) !Global("c-aranrom","GLOBAL",2)~ + ~[PC] If I wanted some unwashed idiot spouting orders about how to do things, I would have asked Edwin to run things for me. Even he would give better advice than you.~ + c_finish_angry_norom
 + ~!InParty("edwin") InParty("minsc") !Global("c-aranrom","GLOBAL",1) !Global("c-aranrom","GLOBAL",2)~ + ~[PC] If I wanted some unwashed idiot spouting orders about how to do things, I would have asked Minsc to run things for me. Even he would give better advice than you.~ + c_finish_angry_norom
 + ~InParty("edwin") InParty("minsc") !Global("c-aranrom","GLOBAL",1) !Global("c-aranrom","GLOBAL",2)~ + ~[PC] If I wanted some unwashed idiot spouting orders about how to do things, I would have asked Minsc or Edwin to run things for me. Both would give better advice than you.~ + c_finish_angry_norom
 ++ ~[PC] I appreciate the input, but I have too much on my hands right now. How about we have a good night's sleep, and then you draft up some plans on how you would go about defending this place. We can have a meeting tomorrow to go over it, ok?~ + c_finish_friend
 + ~InParty("edwin") !InParty("minsc") OR(2) Global("c-aranrom","GLOBAL",1) Global("c-aranrom","GLOBAL",2)~ + ~[PC] If I wanted some unwashed idiot spouting orders about how to do things, I would have asked Edwin to run things for me. Even he would give better advice than you.~ + c_finish_angry_rom
 + ~!InParty("edwin") InParty("minsc") OR(2) Global("c-aranrom","GLOBAL",1) Global("c-aranrom","GLOBAL",2)~ + ~[PC] If I wanted some unwashed idiot spouting orders about how to do things, I would have asked Minsc to run things for me. Even he would give better advice than you.~ + c_finish_angry_rom
 + ~InParty("edwin") InParty("minsc") OR(2) Global("c-aranrom","GLOBAL",1) Global("c-aranrom","GLOBAL",2)~ + ~[PC] If I wanted some unwashed idiot spouting orders about how to do things, I would have asked Minsc or Edwin to run things for me. Both would give better advice than you.~ + c_finish_angry_rom
 + ~Gender(Player1,FEMALE)~ + ~[PC] Hey, don't get upset. You get all cute and kissable when you are upset, and I might be too tired to resist your charms.~ + c_start_makeout
 + ~Gender(Player1,MALE)~ + ~[PC] Hey, don't get upset. I am just too tired to think about this right now. We are all heroes, here - why don't you go relax by flirting with one of the cute chambermaids? They probably won't be able to resist your charms.~ + c_finish_friend
 ++ ~[PC] Well, talk, then. But make it quick.~ + c_to_business
 ++ ~[PC] I'm sorry. That was a little short. Blame it on the lack of sleep, and this whole "save the world every day" thing we seeem to have going.~ + c_to_business
END

IF ~~ c_stone_keep_uninjured
 SAY ~[ARAN] Well fine. But there be some good tactical thought behind stayin' put for awhile. These lands have had th' crap kicked out o' 'em, and mayhap seein' you around a couple more times will give them a morale boost. Plus, give us a mite bit o' a rest to build up some scrolls an' supplies before movin' on.~
 IF ~~ THEN GOTO c_to_business
END

IF ~~ c_stone_keep_uninjured
 SAY ~[ARAN] Bloody hells, <CHARNAME>... look at you! There be half an inch o' you what hasn't been ripped, torn, or otherwise mauled. You need a good solid rest, some magical healin', an' mayhap an armorsmith to put th' party gear back in operation. An' there be some good tactical thought behind stayin' put for awhile. These lands have had th' crap kicked out o' 'em, and mayhap seein' you around a couple more times will give them a morale boost. Plus, give us a mite bit o' a rest to build up some scrolls an' supplies before movin' on.~  
 IF ~~ THEN GOTO c_to_business
END

IF ~~ c_start_makeout // only attainable by Gender(Player1,FEMALE)
 SAY ~[ARAN] Now, hold on one second. Do you think I be so easy you can just have your way wi' me any time you want?~
 ++ ~[PC] Well, seeing as you are not really complaining while I am currently wrapping my arms around your neck and brushing your cheek with my eyelashes, yes.~ + c_makeout_resolve
 ++ ~[PC] Judging by how close you are holding me, and how your lips keep grazing my ear, yes.~ + c_makeout_resolve
 ++ ~[PC] Look, all that grabbing at my waist with your hands is very much unwanted. Go find someone else, because I am just not interested.~ + c_to_business 
 ++ ~[PC] On second thought, I don't know if this is the time and place, Aran. I'm not even sure I want this kind of attention from you.~ + c_makeout_decide   
 + ~Global("c-aranflirtstop","GLOBAL",0)~ + ~[PC] I let you flirt because it keeps you in line, but I am very much in love with someone else. I am not sure we should be sneaking around, even if it is fun.~ + c_makeout_decide
 + ~Global("c-aranflirtstop","GLOBAL",1)~ + ~[PC] You are so easy to tease. Forget it, Aran. I told you I did not want you to flirt with me. I just wanted to see what you would say.~ + c_makeout_decide 
 ++ ~[PC] Yes.~ + c_makeout_decide 
END

IF ~~ c_makeout_decide 
 SAY ~[ARAN] Now, I'm not rightly goin' to argue wi' you. A little kissin' never hurt nobody, an' there be naught else we can do in just a stolen moment, eh? So do you want to kiss, or not?~
 ++ ~[PC] Judging by how close you are holding me, and how your lips keep grazing my ear, yes.~ + c_makeout_resolve
 ++ ~[PC] Well, seeing as you are not really complaining while I am currently wrapping my arms around your neck and brushing your cheek with my eyelashes, yes.~ + c_makeout_resolve
 ++ ~[PC] Nope. Tactical distraction. Works every time. Now, why don't you say what it is you were trying to say?~ + c_to_business 
 ++ ~[PC] I was joking, Aran. The thought of kissing you actually is quite disgusting. What is it you are annoying me with now?~ + c_to_business
 ++ ~[PC] You are easily misdirected with the mere offer of affection. That is a tactical weakness that I do so enjoy exploiting. One day, it will kill you.~ + c_to_business
END

IF ~~ c_makeout_resolve 
 SAY ~[ARAN] Well, I did have me some ideas for th' security an' defense o' this place, but I have naught in th' way o' resistance to your womanly wiles, eh?~
 IF ~~ THEN GOTO c_finish_makeout
END

IF ~~ c_to_business
 SAY ~[ARAN] I was just offerin' some help, is all. I done found some o' th' architectural drawin's, an' land levies for militia service. I wanted to get a word in wi' you on how to proceed.~
 + ~HPPercentLT(Player1,40)~ + ~[PC] No time like the present, though I wish I could have rested first. I think I will drip blood all over this parchment. Let's see... yes. Go ahead and call up these militia for at least one tenday service, until we can get everything covered with professionals.~ +  c_finish_friend 
 + ~!HPPercentLT(Player1,40)~ + ~[PC] No time like the present, though I wish I could have rested first. Let's see... yes. Go ahead and call up these militia for at least one tenday service, until we can get everything covered with professionals.~ + c_finish_friend  
 + ~HPPercentLT(Player1,40)~ + ~[PC]  I think I will sit down for a minute, seeing as most of my body hurts.  Let's see... yes. Go ahead and pull what you need from manpower and supplies to block off that section. Less to defend means more attention on rebuilding.~ +  c_finish_friend
 + ~!HPPercentLT(Player1,40)~ + ~[PC] Hmmm. Yes, this makes sense. Go ahead and pull what you need from manpower and supplies to block off that section. Less to defend means more attention on rebuilding.~ + c_finish_friend  
 ++ ~[PC] I will take a look at this information tomorrow, Aran. But if you are all fired up about working, you could go over the tax levies, and draw up a short list of those we could extort for more money.~ + c_audit
 ++ ~[PC] Why are you bothering me with all of this? I want your skills focused on finding how much there is left in the treasury, and how much we have to help with the rebuilding.~ + c_audit
 ++ ~[PC] Why are you bothering me with all of this? I want your skills focused on finding how much there is left in the treasury, and how much we can raise taxes.~ + c_audit  
 + ~Class(Player1,FIGHTER_ALL)~ + ~[PC] I am well versed in fighting. All we need is the strength to hold this place for awhile. You are too interested in the details.~ + c_details  
 + ~Class(Player1,MAGE_ALL)~ + ~[PC] If you think it will help, go bother with all that petty detail. All I am really interested is wandering the library, and checking for spell components.~ + c_details  
 + ~OR(2) Class(Player1,CLERIC_ALL) Class(Player1,PALADIN_ALL)~ + ~[PC] I am sure you mean well, but I don't have time to concentrate on the details. What I really need is time to pray to my god and gather my strength.~ + c_details  
 + ~Class(Player1,THIEF_ALL)~ + ~[PC All we need is the illusion of strength to hold this place for awhile. Being pinned down to a fortress is not my idea of being subtle. Do I really need to be bothered with all these details?~ + c_details  
 + ~Class(Player1,BARD_ALL)~ + ~[PC] I am more interested in the stories, songs, and poetry that our conquest of this place will inspire. I need some time and space to sit down and concentrate. Do I really need to be bothered with all these details?~ + c_details  
END

IF ~~ c_audit
 SAY ~[ARAN] Sure thing. Inventory, check what be left o' th' raided treasury an' what can be built back up, check into th' land leases, th' whole audit.~
 ++ ~[PC] And Aran... find every single way you can to get us more coin.~ + c_stone_heart_f
 + ~Gender(Player1,FEMALE) Global("c-aranrom","GLOBAL",2)~ + ~And Aran... don't you dare leave this room without kissing me.~ + c_good_order
 ++ ~[PC] And Aran... send me some food up from the kitchen. No dogmeat. Just real food.~ + c_there_goes_the_curry
 ++ ~[PC] You have your orders, so now will you please just let me go to sleep?~ + c_finish_alone
END

IF ~~ c_good_order
 SAY ~[ARAN] Now that be an order I can't rightly refuse. An' why would I want to, anyhow?~ 
 IF ~~ THEN GOTO c_finish_makeout
END

IF ~~ c_stone_heart_f
 SAY ~[ARAN] Whoa, now, I misread you right solid, I did. If this be a hostile takeover, you'd better let me know right quick, so I can set up a second set o' books.~
 + ~!Class("c-aran",PALADIN_ALL)~ + ~[PC] You would do that? Cheat these people?~ + c_me_no_you_yes   
 + ~Class("c-aran",PALADIN_ALL)~ + ~[PC] You would do that? Cheat these people?~ + c_me_no
 ++ ~[PC] That's right, make a joke about these poor people and what they have sufered through. Do you really think I want you to do that?~ + c_me_no
 ++ ~[PC] Look, forget I said anything. I am tired and short-tempered. I just want to be left alone so I can go to sleep.~ + c_finish_alone
END

IF ~~ c_stone_heart_m
 SAY ~[ARAN] Whoa, now, I misread you right solid, I did. I thought you were givin' her a hand on account o' she be quite easy on th' eyes, an' everyone knows a hero has more of a chance with beddin' th' fair maid. If this be a hostile takeover, you'd better let me know right quick, so I can set up a second set o' books.~
 + ~!Class("c-aran",PALADIN_ALL)~ + ~[PC] You would do that? Cheat these people?~ + c_me_no_you_yes   
 + ~Class("c-aran",PALADIN_ALL)~ + ~[PC] You would do that? Cheat these people?~ + c_me_no 
 ++ ~[PC] That's right, make a joke about these poor people and what they have sufered through. Do you really think I want you to do that?~ + c_me_no
 ++ ~[PC] Look, forget I said anything. I am tired and short-tempered. I just want to be left alone so I can go to sleep.~ + c_finish_alone
END

IF ~~ c_me_no
 SAY ~[ARAN] Me? Hells, no. Just wanted to see your face when I said it, eh? I guess it weren't that funny.~ 
 IF ~~ THEN GOTO c_to_business
END

IF ~~ c_me_no_you_yes
 SAY ~[ARAN] Me? Hells, no. I'd be out gettin' these people on th' road to recovery, an' mayhap makin' it less likely that they get cheated out o' their hard work. But I work for you. An' I have done things what would curdle th' blood in th' name o' "good". So it would be you doin' th' cheatin', not me.~
 ++ ~[PC] You are spineless, aren't you.~ + c_no_just_flexible
 ++ ~[PC] With that attitude, you will serve me very well.~ + c_serve_well
 ++ ~[PC] Perhaps one day I will have to test the limits of your loyalty. just how far would you go to serve me?~ + c_pretty_far
END

IF ~~ c_no_just_flexible
 SAY ~[ARAN] Not spineless. Just blighted flexible when it comes to absolute morality. You have a mission, an' when there be a priority mission, normal rules don't rightly apply. Neverwinter has some great readin' materials on this, if you ever visit up there. Sometimes th' ends justify th' means.~
 ++ ~[PC] The ends never justify the means. There is an absolute good, and an absolute bad. So no more talk about cheating these people.~ + c_finish_friend
 ++ ~[PC] Well said. The ends sometimes do justify the means. But in this case, I think we can afford to help these people.~ + c_finish_friend
 ++ ~[PC] You almost had it right, Aran. My goals are attained by any means necessary. Go do whatever you have to do to get me coin.~ + c_extort_money
END

IF ~~ c_serve_well
 SAY ~[ARAN] Well, given th' powers you have, it be a matter o' percentages, eh? I'm not spineless, just blighted flexible when it comes to absolute morality. You have a mission, an' when there be a priority mission, normal rules don't rightly apply. Neverwinter has some great readin' materials on this, if you ever visit up there. Sometimes th' ends justify th' means.~
 ++ ~[PC] The ends never justify the means. There is an absolute good, and an absolute bad. So no more talk about cheating these people.~ + c_finish_friend
 ++ ~[PC] Well said. The ends sometimes do justify the means. But in this case, I think we can afford to help these people.~ + c_finish_friend
 ++ ~[PC] You almost had it right, Aran. My goals are attained by any means necessary. Go do whatever you have to do to get me coin.~ + c_extort_money
END

IF ~~ c_stone_wall
 SAY ~[ARAN] On that point, I know better than to give no opinion. She could be a right passible party member, but she were born wi' a silver spoon in her mouth. Might be trouble. I'm right glad you have to make that decision, not me. Now, do you have a bit o' time, or should I go make myself useful elsewhere?~
 ++ ~[PC] Sure. What is it you want?~ + c_to_business  
 ++ ~[PC] All people do is wander up and talk to me all day and night. They prod me, poke me, question me... so no. Go away, and let me have a moment of peace and quiet all to myself.~ + c_finish_alone
END

IF ~~ c_finish_makeout
 SAY ~[ARAN] (His kisses are ferocious, demanding yours with rising passion. His hands hold your face, cupping you to his lips like a man driven by desperate thirst.)~
 = ~[ARAN] (Only the gentle knocking on the door reminds you that you have duties and appointments waiting before you can sleep, and you hastily compose yourself before Aran slips out of the door. The Captain of the Guard raises one eyebrow while requesting orders, but he is far too professional to inquire. When you catch a glimpse in the mirror, you see that your cheeks and lips are not quite as calm and composed as the Protector of the Keep might be expected to be.)~
 IF ~~ THEN DO ~RealSetGlobalTimer("RE_DreamTimer","GLOBAL",100) RestParty()~ EXIT
END

/* HPPercentLT(Player1,30) */
IF ~~ c_finish_hurt
 SAY ~[ARAN]  Now, that be a nice image, there. I can see why I know you will be a great leader. An' why I might just be fallin' for you, too.~
 IF ~~ THEN DO ~RealSetGlobalTimer("RE_DreamTimer","GLOBAL",100) RestParty()~ EXIT
END

IF ~~ c_finish_angry_norom
 SAY ~[ARAN] By Th' Red Knight's Sword, you are a sorry pain in th' arse. I thought I know where I stood wi' you. I guess I was wrong. Apparently, I stand somewhere south o' th' dungheap out by th' Keep's privy.~
 IF ~~ THEN DO ~RestParty()~ EXIT
END

IF ~~ c_finish_angry_rom
 SAY ~[ARAN] By Th' Red Knight's Sword, you are a sorry pain in th' arse. I thought I know where I stood wi' you. I guess I was wrong. Apparently, I stand somewhere south o' th' dungheap out by th' Keep's privy.~
 IF ~~ THEN DO ~SetGlobal("c-arandreamstone","GLOBAL",1) SetGlobalTimer("c-aranismad","GLOBAL",ONE_DAY) RealSetGlobalTimer("RE_DreamTimer","GLOBAL",100) RestParty()~ EXIT
END

IF ~~ c_there_goes_the_curry
 SAY ~[ARAN] Aye, then. No curry... err... Right. I'll be sendin' somethin' up quick as a flash.~
 IF ~~ THEN DO ~RestParty()~ EXIT
END

IF ~~ c_finish_alone
 SAY ~[ARAN] Right, then. I'll be leavin' you alone. Have a good night.~
 IF ~~ THEN DO ~RestParty()~ EXIT
END

IF ~~ c_pretty_far
 SAY ~[ARAN] I don't rightly know. Slavery, now, that be a deal killer. But short o' that, I guess we just have to see.~
 ++ ~[PC] And what will you do if I ever cross that unknown line?~ + c_dont_know
 ++ ~[PC] That is what I like about you. Always so vague and indecisive, and easy to manipulate.~ + c_finish_alone
 ++ ~[PC] That is what I hate about you. You keep letting me push you around.~ + c_finish_alone
 ++ ~[PC] Sorry.  should not have asked that question. I am in a foul mood tonight. I had better get some rest.~ + c_finish_alone
END

IF ~~ c_extort_money
 SAY ~[ARAN] Right. I'll let you get on wi' your work, an' mayhap I can come up wi' some extra coin somewhere. It might take a few days, mayhap even a tenday. I'll be lettin' you know.~
 IF ~~ THEN DO ~SetGlobal("c-aranextort","LOCALS",1) SetGlobalTimer("c-aranextorttalk","GLOBAL",TEN_DAYS) RestParty()~ EXIT
END

IF ~~ c_dont_know
 SAY ~[ARAN] I don't rightly know. I never did run out on no contract. But I suppose we all have a breakin' point somewhere, eh? Probably just leave. Mayhap fight you, mayhap just kill you. Fair warnin', an' all. But I suspect you will know long before I do. No sense thinkin' about it until it happens, on account o' I'm not blighted well likely to survive th' experience, eh?
 IF ~~ THEN DO ~RestParty()~ EXIT
END

IF ~~ c_details
 SAY ~[ARAN] Details matter. It be a labor o' love what creates a solid foundation, an' th' details be what shows you are doin' more than just th' work o' a hired sword. They be what shows you really care about th' people in your charge, an' provides 'em a sense o' your leadership. But I can see you be busy, so mayhap I will come bother you some other time.~
 IF ~~ THEN DO ~RestParty()~ EXIT
END

IF ~~ c_finish_friend
 SAY ~[ARAN] Now, that be a nice idea, there. I can see why I think you will be a great leader, someday. Well, mayhap already.~
 IF ~~ THEN DO ~RealSetGlobalTimer("RE_DreamTimer","GLOBAL",100) RestParty()~ EXIT
END



/* In C-ARAN.BCS */

IF
 InParty(Myself)
 Global("c-aranextort","GLOBAL",1)
 GlobalTimerExpired("c-aranextorttalk","GLOBAL")
 CombatCounter(0)
 InMyArea(Player1)
 !StateCheck(Myself,CD_STATE_NOTVALID)
 !StateCheck(Player1,CD_STATE_NOTVALID)
THEN  
 RESPONSE #100
SetGlobal("c-aranextort","GLOBAL",2)
RealSetGlobalTimer("c-aransmalltalk","GLOBAL",300)
PlaySong(0)
PlaySound("c-aranft")
StartDialogNoSet(Player1)
END

/* Back in C-ARANJ.DLG */

IF ~Global("c-aranextort","LOCALS",2)~ THEN BEGIN c_aran_extort_choice
 SAY ~[ARAN] Hey, I found some way o' gainin' a mite bit o' extra coin out o' that Keep, just like you asked. There be some options open. You just tell me which one to chose, an' I can get it done right quick.~
 = ~[ARAN] First off, there be some outstandin' debts on th' part o' th' Merchant's Guild, on account o' we provide some protection. We could force collection, makin' them pay for "protection" on a regular basis, instead o' just when they need it, an' get a tidy sum. But turnin' th Guild against you means some serious penalties... merchants talk to everyone, an' a little bad blood can get to be a problem right quick.~
 = ~[ARAN] Second off, we could sell off some o' th' land what's able to be repossessed. It be a matter o' movin' families off farms they been workin' for generations, but th' law be th' law. Might piss people off a mite bit, though.~
 = ~[ARAN] Third, we could cut a deal wi' th' Trade Guild. Right now, there be two representatives vyin' for th' rights. Th' sorry bastard what's tryin' to get th' concession be a right mean bastard, but he has coin to spend, an' he'll give us some to approve him as th' representative next season.~
 = ~[ARAN] So, you want to collect on th' Guild, sell some land, or take a bribe for th' representative choice? Or none o' these?~
 ++ ~[PC] I don't like any of these options.~ DO ~SetSetGlobal("c-aranextort","GLOBAL",3)~ + c_best_of_bad_deal
 ++ ~[PC] Do all three.~ DO ~SetSetGlobal("c-aranextort","GLOBAL",3)~  + c_drive_revolt
 ++ ~[PC] Force the Guild, and take the bribe. Then our "representative" can clean things up for us over time.~ DO ~SetSetGlobal("c-aranextort","GLOBAL",3)~ + c_tricky
 ++ ~[PC] I don't want to mess with the Guild directly. There could be problems. So just kick those families off my land, and sell it.~  DO ~SetSetGlobal("c-aranextort","GLOBAL",3)~ + c_soldout
 ++ ~[PC] I don't want to mess with the Guild directly, and I don't need disgruntled tenants causing trouble. Just take the bribe. If the "representative" doesn't serve us well, then we can always make adjustments later.~ DO ~SetSetGlobal("c-aranextort","GLOBAL",3)~ + c_soldout
 ++ ~[PC] Force the Guild, and throw those people off of my land. But don't bother with taking the bribe. We can probably do better with an honest representative. They tend to actually follow rules, which puts them at a disadvantage.~ DO ~SetSetGlobal("c-aranextort","GLOBAL",3)~ + c_tricky
END

IF ~~ c_best_of_bad_deal
 SAY ~[ARAN] Look, th' truth be there is naught in th' way o' new coin to be had just by squeezin' th' books. I don't rightly recommend doin' any o' these things, but if you want th' coin, that's what I was able to find. Personally, I say give th' whole blighted idea up, an' let's go find somethin' to kill an' loot. Except for dragons. No dragons. They are a pain in th' arse.~
 = ~[ARAN] So, what be your orders?~
 ++ ~[PC] Forget the whole thing. It is just not worth it.~ + c_good_idea
 ++ ~[PC] Do all three.~ + c_drive_revolt
 ++ ~[PC] Force the Guild, and take the bribe. Then our "representative" can clean things up for us over time.~ + c_tricky
 ++ ~[PC] I don't want to mess with the Guild directly. There could be problems. So just kick those families off my land, and sell it.~ + c_soldout
 ++ ~[PC] I don't want to mess with the Guild directly, and I don't need disgruntled tenants causing trouble. Just take the bribe. If the "representative" doesn't serve us well, then we can always make adjustments later.~ + c_soldout
END

IF ~~ c_drive_revolt
 SAY ~[ARAN] Grumbar's Clay Fist, do you want a blighted revolt on your head? That might get us 3000 gold, but you would be askin' for a revolt. You sure you want to do that?~
 ++ ~[PC] Yes. We need the money. And revolts can be put down. What are they going to do, talk me to death?~ + c_you_da_boss
 ++ ~[PC] No. Forget the whole idea.~ + c_good_idea
 ++ ~[PC] What are my options again?~ + c_best_of_bad_deal
 ++ ~[PC] You are so unimaginative. What about falsifying documents and having people driven of their land so I can sell it? What about adding a tax for anyone who speaks Chondathan in public? I expected more out of you, Aran.~ + c_f_u
END

IF ~~ c_f_u
 SAY ~[ARAN] Cyric's Black Balls, there be limits. Corruption, kickin' out people on th' street, an' shakin' down th' guild for "protection" didn't go far enough for you? Forget it. I'm bloody well destroyin' this right now, an' to th' nine hells wi' you. Go find your own way o' dealin' wi' this. I got my limits.~
 IF ~~ THEN EXIT
END

IF ~~ c_you_da_boss
 SAY ~[ARAN] Xvim's Spit, you be... right. Just a job. Consider it done. An' me, I will go lookin' for somethin' to shield th' spittle that folks will send our direction every time they see us.~
 IF ~~ THEN DO ~GiveGoldForce(3000) IncrementGlobal("KPRevolt","GLOBAL",-4)~ EXIT
END

IF ~~  c_tricky
 SAY ~[ARAN] That I can do. Not exactly th' nicest thing in th' world, but it works. It means there will be some disgruntled people, but you don't make no omlette wi' out breakin' eggs.~
 IF ~~ THEN DO ~GiveGoldForce(2000) IncrementGlobal("KPRevolt","GLOBAL",-2)~ EXIT
END

IF ~~  c_soldout
 SAY ~[ARAN] That I can do. Not exactly th' nicest thing in th' world, but it works. It means there will be some disgruntled people, but you don't make no omlette wi' out breakin' eggs.~
 IF ~~ THEN DO ~GiveGoldForce(1000) IncrementGlobal("KPRevolt","GLOBAL",-1)~ EXIT
END

IF ~~ c_good_idea
 SAY ~[ARAN] Good idea. Sometimes, th' best thing to do is to let well enough alone, eh? We'll get th' gold some other way.~
 IF ~~ THEN EXIT
END

Link to comment

Heya cmorgan!

 

Found these, um, errors? for ya.

 

First:

IF ~~ c_stone_keep_uninjured

SAY ~[ARAN] Well fine. But there be some good tactical thought behind stayin' put for awhile. These lands have had th' crap kicked out o' 'em, and mayhap seein' you around a couple more times will give them a morale boost. Plus, give us a mite bit o' a rest to build up some scrolls an' supplies before movin' on.~

IF ~~ THEN GOTO c_to_business

END

 

IF ~~ c_stone_keep_uninjured

SAY ~[ARAN] Bloody hells, <CHARNAME>... look at you! There be half an inch o' you what hasn't been ripped, torn, or otherwise mauled. You need a good solid rest, some magical healin', an' mayhap an armorsmith to put th' party gear back in operation. An' there be some good tactical thought behind stayin' put for awhile. These lands have had th' crap kicked out o' 'em, and mayhap seein' you around a couple more times will give them a morale boost. Plus, give us a mite bit o' a rest to build up some scrolls an' supplies before movin' on.~

IF ~~ THEN GOTO c_to_business

END

They are both labelled uninjured but the bottom one should be injured, methinks.

 

 

For this one:

/* HPPercentLT(Player1,30) */

IF ~~ c_finish_hurt

SAY ~[ARAN] Now, that be a nice image, there. I can see why I know you will be a great leader. An' why I might just be fallin' for you, too.~

IF ~~ THEN DO ~RealSetGlobalTimer("RE_DreamTimer","GLOBAL",100) RestParty()~ EXIT

END

I can't find the preceding lead-in line. Um, there is no "+ c_finish_hurt", that I can find anyhow.

 

Great work though! :)

 

[edit] I'm wondering if there is any equivalent mention for a female PC who has had some fun with Channelle as there is for the male PC. But you did mention you aren't going to track the Romantic Encounters dalliances so that likely is out anyway.

 

[edit 2]Forgot about this:

+ ~Class(Player1,THIEF_ALL)~ + ~[PC All we need is the illusion of strength to hold this place for awhile. Being pinned down to a fortress is not my idea of being subtle. Do I really need to be bothered with all these details?~ + c_details

In the "IF ~~ c_to_business" section, [PC] is missing the closing bracket.

Link to comment

Archived

This topic is now archived and is closed to further replies.

×
×
  • Create New...