Jump to content

Photo

SoA Scenery: Noticing Sheri Without Patch Dependencies

crossmod coding soa romantic encounters BG2 aranw

6 replies to this topic

#1 cmorgan

cmorgan

    journeyman investigator

  • Gibberlings
  • 7097 posts
  • Gender:Male
  • Location:Glencoe, IL, USA

Posted 28 June 2015 - 01:30 PM


Misc Observations

  1. Aran mentioned Sheri, the bardess from Romantic Encounters, in an earlier conversation but doesn't react when the PC asks Sheri for a song. This seemed rather odd.

 

Sounds like a loophole to me. Let's clean up the "Sheri unrecognized" deal for female PC's.
Plus, we should probably help out male PCs too. Classic "Hey, there's this chick I know... oh... errr... daymn. Should have guessed she was going to be very into you. Or vice versa. Pun intended."


OK, let's try a "Side Commentary" that would fit. This beats trying to deal with coding dependent I_C_Ts - no hassles if things change in versions or updates of RE. Compatibility can be maintained by checking against 1 variable on existing or updated installs and updating AranW accordingly. No install order hassles, no mess, no fuss - easy-peasy.

.baf file extensions:

/* BEGIN TEST */

/* SoA Scenery: Acknowledging Sheri from Romantic Encounters */
/* OK, look for Sheri D'Avignon at the Mithrest Inn... */
IF
    InParty(Myself)
    !StateCheck(Myself,CD_STATE_NOTVALID)
    AreaCheck("AR0704")
    Global("c-aranRE_Sheri","GLOBAL",0)
THEN
    RESPONSE #100
        SetGlobal("c-aranRE_Sheri","GLOBAL",1)
END
/* trigger the comment (Dialog handles Exists("RE_Sheri) | Exists("RE_Sheri) */
IF
    !See([ENEMY])
    InParty(Myself)
    !StateCheck(Myself,CD_STATE_NOTVALID)
    InMyArea(Player1)
    !StateCheck(Player1,CD_STATE_NOTVALID)
    AreaCheck("AR0704")
    Global("c-aranRE_Sheri","GLOBAL",1)
THEN
    RESPONSE #100
        StartDialogueNoSet(Player1)
END
/* Rollback if player moves out of AR0704 before it triggers or other things happen to delay this */
IF
    InParty(Myself)
    !StateCheck(Myself,CD_STATE_NOTVALID)
    !AreaCheck("AR0704")
    Global("c-aranRE_SheriTalk","GLOBAL",1)
THEN
    RESPONSE #100
        SetGlobal("c-aranRE_SheriTalk","GLOBAL",0)
END

/* END TEST */
 

 

.d file extensions:

 

/* BEGIN TEST */

/* SoA Scenery: Acknowledging Sheri from Romantic Encounters */

/* Do we see her as existing or not? */
IF ~Global("c-aranRE_Sheri","GLOBAL",1)~ aran_precursor_sheri
  SAY ~[ARAN] Now, I be listenin'...~
  IF ~InMyArea("RE_Sheri")~ THEN DO ~SetGlobal("c-aranRE_Sheri","GLOBAL",2)~ GOTO aran_start_sheri
  IF ~!InMyArea("RE_Sheri")~ THEN DO ~SetGlobal("c-aranRE_Sheri","GLOBAL",2)~ GOTO aran_no_sheri
END

/* Let's make sure there is an excuse not to be directly involved in the I_C_Ts, for immersion/consistency */
/* start here if she is not around or not installed: if the area script is slow to process, no harm done, because we introduce *why* Aran is not in the interjections... so if it evaluates later, no inconsistency */
IF ~~ aran_no_sheri
  SAY ~[ARAN] Well, no Sheri tonight, it seems. An' that be a pity, too. She sings th' kind o' songs I like.~
  = ~[ARAN] Mayhap if we drop by again an' she be here, you do th' talkin', eh? On account o' I think I might have ticked her off proper last time I tried to get friendly wi' her.~
  ++ ~[PC] Let me guess. You made a clumsy pass at her and ended up insulting her.~ + aran_charged_sheri
  ++ ~[PC] Just when was this "last time"?~ + aran_longago_sheri
  ++ ~[PC] That is fine with me.~ + aran_worth_sheri
  ++ ~[PC] What kind of songs do you like?~ + aran_5_sheri
  + ~!Class(Player1,BARD_ALL)~ + ~[PC] I... I do not usually wander up to strangers and talk to them. Even bards and storytellers.~ + aran_worth_sheri
  + ~Class(Player1,BARD_ALL)~ + ~[PC] I do not usually wander up to strangers and talk to them. Even other bards and storytellers. I usually listen without interacting with them.~ + aran_worth_sheri
END  

/* Start here if she is around  */
IF ~~ aran_start_sheri
  SAY ~[ARAN] Aye, she be in right fine form tonight. An any night, for that matter.~
  = ~[ARAN] But mayhap you should do th' talkin'. I did not do so well on th' communication front last time we spoke. In fact, I mayhap be better off standin' a ways back an' just listenin'.~
  + ~Gender(Player1,MALE) Class(Player1,BARD_ALL) Class("c-aran",BARD_ALL)~ + ~[PC] The bard over there in the corner? Is she special?~ + pcbard_aranbard  /* PC is a bard, Aran is a bard : male */
  + ~Gender(Player1,MALE) Class(Player1,BARD_ALL) !Class("c-aran",BARD_ALL)~ + ~[PC] The bard over there in the corner? Is she special?~ + pcbard_arannotbard /* PC is a bard, Aran is not a bard : male */
  + ~Gender(Player1,MALE) !Class(Player1,BARD_ALL) Class("c-aran",BARD_ALL)~ + ~[PC] The bard over there in the corner? Is she special?~ + pcnotbard_aranbard /* PC is not a bard, Aran is a bard : male */
  + ~Gender(Player1,MALE) !Class(Player1,BARD_ALL) !Class("c-aran",BARD_ALL)~ + ~[PC] The bard over there in the corner? Is she special?~ + aran_1malepc_sheri /* PC is not a bard, Aran is not a bard : male  */
  + ~Gender(Player1,FEMALE) Class(Player1,BARD_ALL) Class("c-aran",BARD_ALL)~ + ~[PC] The bard over there in the corner? Is she special?~ + fempcbard_aranbard   /* PC is a bard, Aran is a bard : female  */
  + ~Gender(Player1,FEMALE) Class(Player1,BARD_ALL) !Class("c-aran",BARD_ALL)~ + ~[PC] The bard over there in the corner? Is she special?~ + fempcbard_arannotbard /* PC is a bard, Aran is not a bard : female */
  + ~Gender(Player1,FEMALE) !Class(Player1,BARD_ALL) Class("c-aran",BARD_ALL)~ + ~[PC] The bard over there in the corner? Is she special?~ + fempcnotbard_aranbard /* PC is not a bard, Aran is a bard : female */
  + ~Gender(Player1,FEMALE) !Class(Player1,BARD_ALL) !Class("c-aran",BARD_ALL)~ + ~[PC] The bard over there in the corner? Is she special?~ + aran_1femalepc_sheri /* PC is not a bard, Aran is not a bard : female */
  ++ ~[PC] Let me guess. You made a clumsy pass at her and ended up insulting her.~ + aran_charged_sheri
  ++ ~[PC] I do not usually waste my time talking to insignificant people.~ + aran_worth_sheri
  ++ ~[PC] I will take that under consideration. Perhaps I will go listen to her.~ + aran_worth_sheri
  + ~!Class(Player1,BARD_ALL)~ + ~[PC] I... I do not usually wander up to strangers and talk to them. Even bards and storytellers.~ + aran_worth_sheri
  + ~Class(Player1,BARD_ALL)~ + ~[PC] I do not usually wander up to strangers and talk to them. Even other bards and storytellers. I usually listen without interacting with them.~ + aran_worth_sheri
END

IF ~~ aran_charged_sheri
  SAY ~[ARAN] Aye, guilty as charged.~
  + ~Gender(Player1,MALE) Class(Player1,BARD_ALL) Class("c-aran",BARD_ALL)~ + ~[PC] Is she special?~ + pcbard_aranbard  /* PC is a bard, Aran is a bard : male */
  + ~Gender(Player1,MALE) Class(Player1,BARD_ALL) !Class("c-aran",BARD_ALL)~ + ~[PC] Is she special?~ + pcbard_arannotbard /* PC is a bard, Aran is not a bard : male */
  + ~Gender(Player1,MALE) !Class(Player1,BARD_ALL) Class("c-aran",BARD_ALL)~ + ~[PC] Is she special?~ + pcnotbard_aranbard /* PC is not a bard, Aran is a bard : male */
  + ~Gender(Player1,MALE) !Class(Player1,BARD_ALL) !Class("c-aran",BARD_ALL)~ + ~[PC] Is she special?~ + aran_1malepc_sheri /* PC is not a bard, Aran is not a bard : male  */
  + ~Gender(Player1,FEMALE) Class(Player1,BARD_ALL) Class("c-aran",BARD_ALL)~ + ~[PC] Is she special?~ + fempcbard_aranbard   /* PC is a bard, Aran is a bard : female  */
  + ~Gender(Player1,FEMALE) Class(Player1,BARD_ALL) !Class("c-aran",BARD_ALL)~ + ~[PC] Is she special?~ + fempcbard_arannotbard /* PC is a bard, Aran is not a bard : female */
  + ~Gender(Player1,FEMALE) !Class(Player1,BARD_ALL) Class("c-aran",BARD_ALL)~ + ~[PC] Is she special?~ + fempcnotbard_aranbard /* PC is not a bard, Aran is a bard : female */
  + ~Gender(Player1,FEMALE) !Class(Player1,BARD_ALL) !Class("c-aran",BARD_ALL)~ + ~[PC] Is she special?~ + aran_1femalepc_sheri /* PC is not a bard, Aran is not a bard : female */
  ++ ~[PC] Fine. If we do go  listen to her, you stay back.~ + aran_worth_sheri
  ++ ~[PC] This habit of offending women you meet... you are working on fixing that, right?~ + aran_ayeexit_sheri
  ++ ~[PC] So, to cut a long story short, you think she is worth hearing, but you should avoid her, right?~ + aran_ayeexit_sheri
END
 
IF ~~ pcbard_aranbard
  SAY ~[ARAN] There be no accountin' on whether she be better than you nor I on th' vocal front, as to some th' sopranos run, some th' tenors, an' baritones or bass be solid for all sorts o' songs. But she be a far sight better trained than either o' us blighted bastards.~
  ++ ~[PC] A coloratura. Wait... she just... that high a range with little or no effort. A Spinto?~ + not_spinto_aran
  ++ ~[PC] So... you really like her voice. ~ + aran_1malepc_sheri
  ++ ~[PC] You have no idea how insulting you just were, do you. I have extensive training.~ + not_spinto_aran
  ++ ~[PC] Do not compare my skills to yours. You can barely speak, let alone sing.~ + aran_true_enough
  ++ ~[PC] I would rather not spend my time listening to the competition.~ + aran_worth_sheri
END
 
IF ~~ not_spinto_aran
  SAY ~[ARAN] Well, just listen. Notes into th' upper octave as clear as a bell. Diction clean without heavy handed plosives. Th' way she just controlled her dynamics on that last line to throw th' pathos... musical line...~
  = ~[ARAN] Hells. you did th' trainin' same as I. You *know* how blighted rare it be for a true acuto sfogato soprano t' be playin' bit places an' bars. She should be in Waterdeep, at th' Masked Court.~
  ++ ~[PC] I disagree. That upper range is too dark and covered to be a true sfogato. But I can see that you truly love her voice.~ + aran_1malepc_sheri
  ++ ~[PC] Sopranos get all the attention. We have to work twice as hard to get noticed. I take it she did not want a singing partner...~ + aran_1malepc_sheri
  ++ ~[PC] I would rather not spend my time listening to the competition.~ + aran_worth_sheri
  ++ ~[PC] Let me guess. You made a clumsy pass at her and ended up insulting her.~ + aran_crockery_sheri
  ++ ~[PC] Fine. You stay back. Perhaps I will go see what she can sing.~ + aran_worth_sheri
END

IF ~~ pcbard_arannotbard
  SAY ~[ARAN] You be th' judge, on account o' you have th' right trainin', eh? But to my untrained ear, she sounds like a blighted Avatar o' Sune made flesh an' blood.~
  ++ ~[PC] I would rather not spend my time listening to the competition.~ + aran_worth_sheri
  ++ ~[PC] Let me guess. You made a clumsy pass at her and ended up insulting her.~ + aran_crockery_sheri  
  ++ ~[PC] This habit of offending women you meet... you are working on fixing that, right?~ + aran_ayeexit_sheri
  ++ ~[PC] So, to cut a long story short, you think she is worth hearing, but you should avoid her, right?~ + aran_ayeexit_sheri
  ++ ~[PC] Fine. You stay back. Perhaps I will go see what she can sing.~ + aran_worth_sheri
END
 
IF ~~ pcnotbard_aranbard
  SAY ~[ARAN] Well, she be a fully trained vocalist, an' her upper register be absolutely clear, wi' no forced notes or improper placement in th' headvoice.... ah, there I go, talkin' shop. Yes. She is blighted good.~
  ++ ~[PC] Let me guess. You made a clumsy pass at her and ended up insulting her.~ + aran_crockery_sheri  
  ++ ~[PC] This habit of offending women you meet... you are working on fixing that, right?~ + aran_ayeexit_sheri
  ++ ~[PC] So, to cut a long story short, you think she is worth hearing, but you should avoid her, right?~ + aran_ayeexit_sheri
  ++ ~[PC] Fine. You stay back. Perhaps I will go see what she can sing.~ + aran_worth_sheri
  ++ ~[PC] Right now, I need a drink. Perhaps later.~ + aran_worth_sheri
END
 
IF ~~ fempcbard_aranbard
  SAY ~[ARAN] Well, just listen. Notes into th' upper octave as clear as a bell. Diction clean without heavy handed plosives. Th' way she just controlled her dynamics on that last line to throw th' pathos... musical line...~
  = ~[ARAN] Hells. you did th' trainin' same as I. You *know* how blighted rare it be for a true acuto sfogato soprano t' be playin' bit places an' bars. She should be in Waterdeep, at th' Masked Court.~
  ++ ~[PC] Is she a better vocalist than I am?~ + ara_notsofast_check
  ++ ~[PC] She... I can hear it. She has a better voice than I do.~ + ara_notsofast_check
  ++ ~[PC] I disagree. That last passage, she clipped two notes, and her breath support is... lacking. If she bends or scoops one more note, I shall have to throw something at her.~ + aran_jealousy
  ++ ~[PC] Well, perhaps I should evaluate her. I can always use a careful analysis to better my own craft.~ + aran_worth_sheri
  ++ ~[PC] So... you really like her voice.~ + aran_1femalepc_sheri
END

IF ~~ fempcbard_arannotbard
  SAY ~[ARAN] Well, just listen to her, an' mayhap a trained bardess like you can explain to me why she can turn a tune t' make a man weep or laugh as easy as I can flick a blade from left to right. She certainly do catch my ear.~
  ++ ~[PC] She... I can hear it. She has a better voice than I do.~ + ara_notsofast_check
  ++ ~[PC] I do not know... That last passage, she clipped two notes, and her breath support is lacking. If she bends or scoops one more note, I shall have to throw something at her.~ + aran_jealousy
  ++ ~[PC] Well, perhaps we should evaluate her. I can always use a careful analysis to better my own craft.~ + aran_worth_sheri
  ++ ~[PC] So... you really like her voice.~ + aran_1femalepc_sheri
  ++ ~[PC] Let me guess. You made a clumsy pass at her and ended up insulting her.~ + aran_crockery_sheri
  ++ ~[PC] Fine. You stay back. Perhaps I will go see what she can sing.~ + aran_worth_sheri
END

IF ~~ aran_jealousy
  SAY ~[ARAN] Well, I defer to your better judgement, on account o' I hold your opinion in high regard, I do.~
  IF ~~ THEN EXIT
END

IF ~~ ara_notsofast_check
  SAY ~[ARAN] Now, that be a bad idea. There be strengths an' weaknesses in any what follow th' craft. You know full well what you are capable of. She may be rare, but you be just as strong.~
  IF ~~ THEN EXIT
END

IF ~~ fempcnotbard_aranbard
  SAY ~[ARAN] Aye, somethin' seriously special, an' rare. She be a true acuto sfogato soprano, wi' a range higher than most o' th' coloratura sopranos... err... there I go, talkin' shop. Yes. She is blighted good.~
  IF ~~ THEN GOTO aran_1femalepc_sheri
END

/* males: craptalk */
IF ~~ aran_1malepc_sheri
SAY ~[ARAN] Aye. No interest in me, more be th' pity. Mayhap she be frightened off by th' brilliance o' my manly charms. Either that, or she has been talkin' to Erika at Th' Broken Sword.~
  ++ ~[PC] So... you and Erika...~ + aran_2_sheri
  ++ ~[PC] You have that bad a reputation?~ + aran_3_sheri
  ++ ~[PC] You seem to have a very high opinion of yourself.~ + aran_4_sheri
  ++ ~[PC] I do not usually waste my time talking to insignificant people.~ + aran_worth_sheri
  ++ ~[PC] So, to cut a long story short, you think she is worth hearing, but you should avoid her, right?~ + aran_ayeexit_sheri
END

/* females; have to account for potential time in party if PC visits late game instead of immediately */
/* With Apologies to Annie Get Your Gun */
IF ~~ aran_1femalepc_sheri
SAY ~[ARAN] I love th' sound o' her voice, an' that be for sure.~
  + ~!Global("c-aranrom","GLOBAL",2)~ + ~[PC] Is that all you love?~ + hells_no_my_mistake
  + ~Global("c-aranrom","GLOBAL",2)~ + ~[PC] Is that all you love?~ + of_course_dear
  ++ ~[PC] Let me guess. You made a clumsy pass at her and ended up insulting her.~ + aran_crockery_sheri  
  ++ ~[PC] Anything she can do, I can do better.~ + aran_true_enough
  ++ ~[PC] Anything she can sing, I can sing higher.~ + aran_true_enough
  ++ ~[PC] You know, I think I should see this... singer.~ + aran_worth_sheri
  + ~!Class(Player1,BARD_ALL)~ + ~[PC] I... I do not usually wander up to strangers and talk to them. Even bards and storytellers.~ + aran_worth_sheri
  + ~Class(Player1,BARD_ALL)~ + ~[PC] I do not usually wander up to strangers and talk to them. Even other bards and storytellers. I usually listen without interacting with them.~ + aran_worth_sheri
END

IF ~~ hells_no_my_mistake
  SAY ~[ARAN] Hells, no! Th' way her eyes sparkle, it be right nice to see. An' when she takes in a right solid breath...~
  = ~[ARAN] Err...~
  = ~[ARAN] Yes. That be all I love about her. That be my story, an' naught can shake me from it. But it don't matter for naught either way. She didn't find my sparkin' to her taste.~
  IF ~~ THEN GOTO aran_5_sheri
END

IF ~~ of_course_dear
  SAY ~[ARAN] Aye. That voice... it caught me right away. But then I had to go an' be a jackass, an' try to spark a bit wi' her. It were before I met you.~
  IF ~~ THEN GOTO aran_5_sheri
END

IF ~~ aran_2_sheri
  SAY ~[ARAN] There be no deal between us at all. I am not likely to be makin' serious passes at Erika. She has a great sense o' humor, an' I needs be keepin' in good graces wi' Orrin an' Teldra as well. Fun teasin' her, is all.~
  IF ~~ THEN GOTO aran_4_sheri
END

IF ~~ aran_3_sheri
SAY ~[ARAN] Well, I mayhap be a bit forward wi' th' ladies. But most o' th' time it be just talk. No harm in that.~
 IF ~Gender(Player1,MALE)~ THEN GOTO aran_4_sheri
 IF ~Gender(Player1,FEMALE)~ THEN GOTO aran_5_sheri
END

IF ~~ aran_true_enough
  SAY ~[ARAN] Mayhap you be right. But I think that calls for a bit o' a contest later on to decide, eh?~
  IF ~Gender(Player1,MALE)~ THEN GOTO aran_4_sheri
  IF ~Gender(Player1,FEMALE)~ THEN GOTO aran_5_sheri
END

IF ~~ aran_4_sheri
  SAY ~[ARAN] I be right confident in my abilities, to be sure. But I know my limits. Sheri, she be as far out o' my reach as th' nearest star.~
  ++ ~[PC] Perhaps she will find me interesting.~ + aran_end1_sheri
  ++ ~[PC] I do not usually waste my time talking to insignificant people.~ + aran_worth_sheri
  ++ ~[PC] Well, perhaps I should pay her a visit.~ + aran_worth_sheri
  + ~!Class(Player1,BARD_ALL)~ + ~[PC] I... I do not usually wander up to strangers and talk to them. Even bards and storytellers.~ + aran_worth_sheri
  + ~Class(Player1,BARD_ALL)~ + ~[PC] I do not usually wander up to strangers and talk to them. Even other bards and storytellers. I usually listen without interacting with them.~ + aran_worth_sheri
  ++ ~[PC] This is a distraction. Go make yourself useful. Go fix the gear, or sharpen something.~ + aran_ayeexit_sheri
END

IF ~~ aran_5_sheri
  SAY ~[ARAN] I like all sorts o' songs. But when it be Sheri, some sets she sings be on th' bawdy side.~
  ++ ~[PC] Does she do more than... sing that kind of song?~ + aran_end1_sheri
  ++ ~[PC] Perhaps she will find me interesting.~ + aran_end1_sheri
  ++ ~[PC] Well, perhaps I should pay her a visit.~ + aran_worth_sheri
  + ~!Class(Player1,BARD_ALL)~ + ~[PC] I... I do not usually wander up to strangers and talk to them. Even bards and storytellers.~ + aran_worth_sheri
  + ~Class(Player1,BARD_ALL)~ + ~[PC] I do not usually wander up to strangers and talk to them. Even other bards and storytellers. I usually listen without interacting with them.~ + aran_worth_sheri
  ++ ~[PC] This is a distraction. Go make yourself useful. Go fix the gear, or sharpen something.~ + aran_ayeexit_sheri
END

IF ~~ aran_longago_sheri SAY ~[ARAN] About a tenday before I met up wi' you, if I rightly recall.~ IF ~~ THEN GOTO aran_crockery_sheri END

IF ~~ aran_crockery_sheri
  SAY ~[ARAN] Busy day, that one. I had to dodge my way out right quick. Great voice, an' a sight better aim wi' crockery than I'd have guessed. But I deserved th' cuts an' bruises she dealt, I did, every last one.~
  IF ~~ THEN EXIT
END

IF ~~ aran_end1_sheri
  SAY ~[ARAN] Aye, mayhap. So far, wi' anyone I done seen talk to her, she seems friendly enough. Which kind o' fits wi' th' whole "relatin' to people" thing bards an' bardesses seem to be right good at.~
  IF ~~ THEN EXIT
END

IF ~~ aran_worth_sheri SAY ~[ARAN] I think you would enjoy th' time spent. Her voice... it be an experience.~ IF ~~ THEN EXIT END
IF ~~ aran_ayeexit_sheri SAY @3601 IF ~~ THEN EXIT END // @3601 = ~[ARAN] Aye.~

/* END TEST */
 

 

Minor pathway fixes integrated; major idiocy like missing tildes and forgetting to direct state nubers repaired.

 

Tested against no-RE-is-installed and yes-RE-is-installed conditions on BG2:EE.


Edited by cmorgan, 01 July 2015 - 06:54 AM.

I love deadlines. I love the whooshing noise they make as they go by. - Douglas Adams

#2 cmorgan

cmorgan

    journeyman investigator

  • Gibberlings
  • 7097 posts
  • Gender:Male
  • Location:Glencoe, IL, USA

Posted 30 June 2015 - 06:01 PM

Heh. I am out of practice. AR0709 not Mithrest Inn... showed up to the wrong concert. Plus, typofest. Will clean up and update tomorrow.

 

The BG2:EE interface is definitely cutting off more than the regular BG2 one. i forgot that. Hmmm.


I love deadlines. I love the whooshing noise they make as they go by. - Douglas Adams

#3 cmorgan

cmorgan

    journeyman investigator

  • Gibberlings
  • 7097 posts
  • Gender:Male
  • Location:Glencoe, IL, USA

Posted 01 July 2015 - 05:31 AM

Aaaaand... it has been so long since I played it that I have forgotten that Sheri shows up in MITHREST. not VALES. Though I did just get a nice kiss from an actress *ahem* female actor  named Cheri or something like thast for helping run lines - nice stuff, Thimblerig.

 

So, an easier fix - change the PID line to indicate that she might not be there/has moved on to Trademeet, and add the reaction to the area where she actually spawns.

 

Changes to script -

 

make it play on entry to the are no matter what, then leverage the fact that dialog allows !Exists("something_that_is_not_valid_resource_in_this_game") without crashing.

That gives a color dialog in Vales, and a potential color dialog in the Mithrest, whether RE is installed or not.


I love deadlines. I love the whooshing noise they make as they go by. - Douglas Adams

#4 Thimblerig

Thimblerig
  • Modders
  • 1380 posts
  • Gender:Female
  • Location:New Zealand

Posted 01 July 2015 - 05:41 AM

I think you mean Chandra, by Western Paladin - and yes, that's a very sweet encounter.



#5 cmorgan

cmorgan

    journeyman investigator

  • Gibberlings
  • 7097 posts
  • Gender:Male
  • Location:Glencoe, IL, USA

Posted 01 July 2015 - 05:54 AM

Heh! I need COOOFFFFFEEEEEE....

 

Starting over!

 

(Sorry, Thimblerig!)

 

1. Mithrest Inn. AR0704. Not Vales. AR0709.

2. Western Paladin. Cool encounter.

3. Why am I making the mistake of adding "color" (Aran got the place wrong) when I can fix the line? So none of this "She Must Have Moved On" stuff that may confuse players. Fix line, add block anmd talk to AR0704, test on BG2:EE with RE installed and not installed, done.

 

After I get a second cup of coffee.


I love deadlines. I love the whooshing noise they make as they go by. - Douglas Adams

#6 cmorgan

cmorgan

    journeyman investigator

  • Gibberlings
  • 7097 posts
  • Gender:Male
  • Location:Glencoe, IL, USA

Posted 01 July 2015 - 06:51 AM

OK, cleaned up, simplified, and tested. Works like a charm whether or not RE is installed.

 

Playing through Sheri again after all these years, I wish wish wish I had thought of getting harp or lute soundtracks for the traditional songs in that component - nowadays, with the download abilities of most folks, that sort of thing would have worked. Tough to justify doing that back then. And I am a brass player, not a guitarist/lutenist.

 

Just gotta .tra it and integrate it.

 

Note to Self - the sweet spot for full use of the standard BG2:EE panel on my machine is using the largest dialog box, having no more that a 3 line wrap of Aran's text, and having 5 dialog responses.

 

BUT.

 

Not much point in dealing with this, as BG2:EE is released on multiple devices, and I expect gui scaling on iPads and touch devices will be different. No way to deal with it. Price to pay when you try to add to a game that really was designed around short text lines, 3 responses.


Edited by cmorgan, 01 July 2015 - 06:59 AM.

I love deadlines. I love the whooshing noise they make as they go by. - Douglas Adams

#7 cmorgan

cmorgan

    journeyman investigator

  • Gibberlings
  • 7097 posts
  • Gender:Male
  • Location:Glencoe, IL, USA

Posted 01 July 2015 - 12:04 PM

...aaaand traified, tested on bg2 with and without RE, rechecked once on BG2ee without RE installed - ready for GitHub. "Final" code:

 

temporarily leaving most of Aran's SAY lines for quick discovery when troubleshooting.

/* SoA Scenery: Acknowledging Sheri from Romantic Encounters */

/* Do we see her as existing or not? */
IF ~Global("c-aranRE_Sheri","GLOBAL",1)~ a5146
  SAY @13472 /* [ARAN] Now, I be listenin'... */
  IF ~InMyArea("RE_Sheri")~ THEN DO ~SetGlobal("c-aranRE_Sheri","GLOBAL",2)~ GOTO a5147
  IF ~!InMyArea("RE_Sheri")~ THEN DO ~SetGlobal("c-aranRE_Sheri","GLOBAL",2)~ GOTO a5148
END

/* Let's make sure there is an excuse not to be directly involved in the I_C_Ts, for immersion/consistency */
/* start here if she is not around or not installed: if the area script is slow to process, no harm done, because we introduce *why* Aran is not in the interjections... so if it evaluates later, no inconsistency */
IF ~~ a5148
  SAY @13473 /* [ARAN] Well, no Sheri tonight, it seems. An' that be a pity, too. She sings th' kind o' songs I like. */
  = @13474 /* [ARAN] Mayhap if we drop by again an' she be here, you do th' talkin', eh? On account o' I think I might have ticked her off proper last time I tried to get friendly wi' her. */
  ++ @13475 + a5149
  ++ @13476 + a5168
  ++ @13477 + a5171
  ++ @13478 + a5167
  + ~!Class(Player1,BARD_ALL)~ + @13479 + a5171
  + ~Class(Player1,BARD_ALL)~ + @13480 + a5171
END  

/* Start here if she is around  */
IF ~~ a5147
  SAY @13481 /* [ARAN] Aye, she be in right fine form tonight. An any night, for that matter. */
  = @13482 /* [ARAN] But mayhap you should do th' talkin'. I did not do so well on th' communication front last time we spoke. In fact, I mayhap be better off standin' a ways back an' just listenin'. */
  + ~Gender(Player1,MALE) Class(Player1,BARD_ALL) Class("c-aran",BARD_ALL)~ + @13483 + a5150  /* PC is a bard, Aran is a bard : male */
  + ~Gender(Player1,MALE) Class(Player1,BARD_ALL) !Class("c-aran",BARD_ALL)~ + @13483 + a5152 /* PC is a bard, Aran is not a bard : male */
  + ~Gender(Player1,MALE) !Class(Player1,BARD_ALL) Class("c-aran",BARD_ALL)~ + @13483 + a5153 /* PC is not a bard, Aran is a bard : male */
  + ~Gender(Player1,MALE) !Class(Player1,BARD_ALL) !Class("c-aran",BARD_ALL)~ + @13483 + a5159 /* PC is not a bard, Aran is not a bard : male  */
  + ~Gender(Player1,FEMALE) Class(Player1,BARD_ALL) Class("c-aran",BARD_ALL)~ + @13483 + a5154   /* PC is a bard, Aran is a bard : female  */
  + ~Gender(Player1,FEMALE) Class(Player1,BARD_ALL) !Class("c-aran",BARD_ALL)~ + @13483 + a5155 /* PC is a bard, Aran is not a bard : female */
  + ~Gender(Player1,FEMALE) !Class(Player1,BARD_ALL) Class("c-aran",BARD_ALL)~ + @13483 + a5158 /* PC is not a bard, Aran is a bard : female */
  + ~Gender(Player1,FEMALE) !Class(Player1,BARD_ALL) !Class("c-aran",BARD_ALL)~ + @13483 + a5160 /* PC is not a bard, Aran is not a bard : female */
  ++ @13475 + a5149
  ++ @13484 + a5171
  ++ @13485 + a5171
  + ~!Class(Player1,BARD_ALL)~ + @13479 + a5171
  + ~Class(Player1,BARD_ALL)~ + @13480 + a5171
END

IF ~~ a5149
  SAY @13486 /* [ARAN] Aye, guilty as charged. */
  + ~Gender(Player1,MALE) Class(Player1,BARD_ALL) Class("c-aran",BARD_ALL)~ + @13487 + a5150  /* PC is a bard, Aran is a bard : male */
  + ~Gender(Player1,MALE) Class(Player1,BARD_ALL) !Class("c-aran",BARD_ALL)~ + @13487 + a5152 /* PC is a bard, Aran is not a bard : male */
  + ~Gender(Player1,MALE) !Class(Player1,BARD_ALL) Class("c-aran",BARD_ALL)~ + @13487 + a5153 /* PC is not a bard, Aran is a bard : male */
  + ~Gender(Player1,MALE) !Class(Player1,BARD_ALL) !Class("c-aran",BARD_ALL)~ + @13487 + a5159 /* PC is not a bard, Aran is not a bard : male  */
  + ~Gender(Player1,FEMALE) Class(Player1,BARD_ALL) Class("c-aran",BARD_ALL)~ + @13487 + a5154   /* PC is a bard, Aran is a bard : female  */
  + ~Gender(Player1,FEMALE) Class(Player1,BARD_ALL) !Class("c-aran",BARD_ALL)~ + @13487 + a5155 /* PC is a bard, Aran is not a bard : female */
  + ~Gender(Player1,FEMALE) !Class(Player1,BARD_ALL) Class("c-aran",BARD_ALL)~ + @13487 + a5158 /* PC is not a bard, Aran is a bard : female */
  + ~Gender(Player1,FEMALE) !Class(Player1,BARD_ALL) !Class("c-aran",BARD_ALL)~ + @13487 + a5160 /* PC is not a bard, Aran is not a bard : female */
  ++ @13488 + a5171
  ++ @13489 + a5172
  ++ @13490 + a5172
END
 
IF ~~ a5150
  SAY @13491 /* [ARAN] There be no accountin' on whether she be better than you nor I on th' vocal front, as to some th' sopranos run, some th' tenors, an' baritones or bass be solid for all sorts o' songs. But she be a far sight better trained than either o' us blighted bastards. */
  ++ @13492 + a5151
  ++ @13493 + a5159
  ++ @13494 + a5151
  ++ @13495 + a5165
  ++ @13496 + a5171
END
 
IF ~~ a5151
  SAY @13497 /* [ARAN] Well, just listen. Notes into th' upper octave as clear as a bell. Diction clean without heavy handed plosives. Th' way she just controlled her dynamics on that last line to throw th' pathos... musical line... */
  = @13498 /* [ARAN] Hells. you did th' trainin' same as I. You *know* how blighted rare it be for a true acuto sfogato soprano t' be playin' bit places an' bars. She should be in Waterdeep, at th' Masked Court. */
  ++ @13499 + a5159
  ++ @13500 + a5159
  ++ @13496 + a5171
  ++ @13475 + a5169
  ++ @13501 + a5171
END

IF ~~ a5152
  SAY @13502 /* [ARAN] You be th' judge, on account o' you have th' right trainin', eh? But to my untrained ear, she sounds like a blighted Avatar o' Sune made flesh an' blood. */
  ++ @13496 + a5171
  ++ @13475 + a5169  
  ++ @13489 + a5172
  ++ @13490 + a5172
  ++ @13501 + a5171
END
 
IF ~~ a5153
  SAY @13503 /* [ARAN] Well, she be a fully trained vocalist, an' her upper register be absolutely clear, wi' no forced notes or improper placement in th' headvoice.... ah, there I go, talkin' shop. Yes. She is blighted good. */
  ++ @13475 + a5169  
  ++ @13489 + a5172
  ++ @13490 + a5172
  ++ @13501 + a5171
  ++ @13504 + a5171
END
 
IF ~~ a5154
  SAY @13497 /* [ARAN] Well, just listen. Notes into th' upper octave as clear as a bell. Diction clean without heavy handed plosives. Th' way she just controlled her dynamics on that last line to throw th' pathos... musical line... */
  = @13498 /* [ARAN] Hells. you did th' trainin' same as I. You *know* how blighted rare it be for a true acuto sfogato soprano t' be playin' bit places an' bars. She should be in Waterdeep, at th' Masked Court. */
  ++ @13505 + a5157
  ++ @13506 + a5157
  ++ @13507 + a5156
  ++ @13508 + a5171
  ++ @13509 + a5160
END

IF ~~ a5155
  SAY @13510 /* [ARAN] Well, just listen to her, an' mayhap a trained bardess like you can explain to me why she can turn a tune t' make a man weep or laugh as easy as I can flick a blade from left to right. She certainly do catch my ear. */
  ++ @13506 + a5157
  ++ @13511 + a5156
  ++ @13512 + a5171
  ++ @13509 + a5160
  ++ @13475 + a5169
  ++ @13501 + a5171
END

IF ~~ a5156
  SAY @13513 /* [ARAN] Well, I defer to your better judgement, on account o' I hold your opinion in high regard, I do. */
  IF ~~ THEN EXIT
END

IF ~~ a5157
  SAY @13514 /* [ARAN] Now, that be a bad idea. There be strengths an' weaknesses in any what follow th' craft. You know full well what you are capable of. She may be rare, but you be just as strong. */
  IF ~~ THEN EXIT
END

IF ~~ a5158
  SAY @13515 /* [ARAN] Aye, somethin' seriously special, an' rare. She be a true acuto sfogato soprano, wi' a range higher than most o' th' coloratura sopranos... err... there I go, talkin' shop. Yes. She is blighted good. */
  IF ~~ THEN GOTO a5160
END

/* males: craptalk */
IF ~~ a5159
SAY @13516 /* [ARAN] Aye. No interest in me, more be th' pity. Mayhap she be frightened off by th' brilliance o' my manly charms. Either that, or she has been talkin' to Erika at Th' Broken Sword. */
  ++ @13517 + a5163
  ++ @13518 + a5164
  ++ @13519 + a5166
  ++ @13484 + a5171
  ++ @13490 + a5172
END

/* females; have to account for potential time in party if PC visits late game instead of immediately */
/* With Apologies to Annie Get Your Gun */
IF ~~ a5160
SAY @13520 /* [ARAN] I love th' sound o' her voice, an' that be for sure. */
  + ~!Global("c-aranrom","GLOBAL",2)~ + @13521 + a5161
  + ~Global("c-aranrom","GLOBAL",2)~ + @13521 + a5162
  ++ @13475 + a5169  
  ++ @13522 + a5165
  ++ @13523 + a5165
  ++ @13524 + a5171
  + ~!Class(Player1,BARD_ALL)~ + @13479 + a5171
  + ~Class(Player1,BARD_ALL)~ + @13480 + a5171
END

IF ~~ a5161
  SAY @13525 /* [ARAN] Hells, no! Th' way her eyes sparkle, it be right nice to see. An' when she takes in a right solid breath... */
  = @13526 /* [ARAN] Err... */
  = @13527 /* [ARAN] Yes. That be all I love about her. That be my story, an' naught can shake me from it. But it don't matter for naught either way. She didn't find my sparkin' to her taste. */
  IF ~~ THEN GOTO a5167
END

IF ~~ a5162
  SAY @13528 /* [ARAN] Aye. That voice... it caught me right away. But then I had to go an' be a jackass, an' try to spark a bit wi' her. It were before I met you. */
  IF ~~ THEN GOTO a5167
END

IF ~~ a5163
  SAY @13529 /* [ARAN] There be no deal between us at all. I am not likely to be makin' serious passes at Erika. She has a great sense o' humor, an' I needs be keepin' in good graces wi' Orrin an' Teldra as well. Fun teasin' her, is all. */
  IF ~~ THEN GOTO a5166
END

IF ~~ a5164
SAY @13530 /* [ARAN] Well, I mayhap be a bit forward wi' th' ladies. But most o' th' time it be just talk. No harm in that. */
 IF ~Gender(Player1,MALE)~ THEN GOTO a5166
 IF ~Gender(Player1,FEMALE)~ THEN GOTO a5167
END

IF ~~ a5165
  SAY @13531 /* [ARAN] Mayhap you be right. But I think that calls for a bit o' a contest later on to decide, eh? */
  IF ~Gender(Player1,MALE)~ THEN GOTO a5166
  IF ~Gender(Player1,FEMALE)~ THEN GOTO a5167
END

IF ~~ a5166
  SAY @13532 /* [ARAN] I be right confident in my abilities, to be sure. But I know my limits. Sheri, she be as far out o' my reach as th' nearest star. */
  ++ @13533 + a5170
  ++ @13484 + a5171
  ++ @13534 + a5171
  + ~!Class(Player1,BARD_ALL)~ + @13479  + a5171
  + ~Class(Player1,BARD_ALL)~ + @13480 + a5171
  ++ @13535 + a5172
END

IF ~~ a5167
  SAY @13536
  ++ @13537 + a5170
  ++ @13533 + a5170
  ++ @13534 + a5171
  + ~!Class(Player1,BARD_ALL)~ + @13479 + a5171
  + ~Class(Player1,BARD_ALL)~ + @13480 + a5171
  ++ @13535 + a5172
END

IF ~~ a5168 SAY @13538 IF ~~ THEN GOTO a5169 END
IF ~~ a5169 SAY @13539 IF ~~ THEN EXIT END
IF ~~ a5170 SAY @13540 IF ~~ THEN EXIT END
IF ~~ a5171 SAY @13541 IF ~~ THEN EXIT END
IF ~~ a5172 SAY @3601 IF ~~ THEN EXIT END

https://github.com/c...ad1018e37ce348e


Edited by cmorgan, 01 July 2015 - 12:34 PM.

I love deadlines. I love the whooshing noise they make as they go by. - Douglas Adams



Reply to this topic



  



Also tagged with one or more of these keywords: crossmod, coding, soa, romantic encounters, BG2, aranw

1 user(s) are reading this topic

0 members, 1 guests, 0 anonymous users