Jump to content

Recommended Posts

Bogstandard BioWare™ copying for the setup, but then we go slightly off the usual track for the cutscene and talk. For your own research, check LOVEDONE .d's, and HGWRA01's jumping around between all the possibles.

 

CODE

/* Master Wraith Talk. */

 

/* At top of c-arantobdialog.d, */

BEGIN C-ARWRTH

 

 

 

Reminder to self - beg/bribe Peachplums for another picture... spectral fighter.

CODE

/* In .tp2, creature C-ARWRTH */

 

COPY ~aranw/portraits/peachplums_deadman.bmp~ ~override/c-aw01p3.bmp~ // Dead Mercenary portrait (Peachplums)

COPY_EXISTING ~kpchap01.cre~ ~override/c-aw01p3.cre~

SAY NAME1 ~Stedd~

SAY NAME2 ~Stedd~

LAUNCH_PATCH_MACRO ~support_cre_cleanup~

*/

 

in c-arantobdialog.d,

CODE

/* break in and set up the talk if in a romance */

EXTEND_BOTTOM HGWRA01 18

IF ~Global("c-aranrom","GLOBAL",2) InParty("c-aran") InMyArea("c-aran") !StateCheck("c-aran",CD_STATE_NOTVALID)~ THEN DO ~SetGlobal("c-aranlovedone","GLOBAL",6)~ EXTERN HGWRA01 c_wraith_trashtalk

END

 

/* Create the EXTERN, as we want only one of these to play */

CHAIN HGWRA01 c_wraith_trashtalk

~What of the inevitable pain you must cause to the one you love? This man, the one whom you call "Aran".~

== C-ARN25J ~[ARAN] What in Cyric's Blighted Breath do this windbag be talkin' about? You be in control o' th' bloodurges...~

EXTERN HGWRA01 24

 

/* draw off the romance-triggered sob stories to a new one */

EXTEND_BOTTOM HGWRA01 24

IF ~Global("c-aranrom","GLOBAL",2)~ DO ~ClearAllActions() StartCutSceneMode() StartCutScene("C-ACT218")~ EXIT

END

 

/* start the waterworks */

CHAIN IF ~NumTimesTalkedTo(0)~ THEN C-ARWRTH c_start_wraith_talk

~[C-ARWRTH] Aran? Whitehand, light a torch or somethin'. It is as dark as hells here...~ [C-ARW001]

== C-ARN25J ~[ARAN] What in th' nine hells... you be dead an' buried. Someone get me some holy water right quick, eh? You were no good when you was alive, an' I don't rightly want to see you now you be dead.~ [ARAN_SOUND_HERE]

== C-ARWRTH ~[C-ARWRTH] You have come up in th' world. Who is th' wench?~ [C-ARW002]

== C-ARN25J ~[ARAN] Keep a guard on your tongue, bastard.~ [ARAN_SOUND_HERE]

== C-ARWRTH ~[C-ARWRTH] Oho, a new lover? Stedd sees all now, Whitehand. You sorry weakling, you actually think you can keep her? Does she know?~ [C-ARW003]

== C-ARN25J ~[ARAN] Shut your filthy mouth.~ [ARAN_SOUND_HERE]

== C-ARWRTH ~[C-ARWRTH] Hah! She doesn't know! You remember, don't you? Th' smell of flesh burnin', th' screams of th' children...~ [C-ARW004]

== C-ARN25J ~[ARAN] I did what you ordered. Bane Blight your soul, I didn't know.~ [ARAN_SOUND_HERE]

== C-ARWRTH ~[C-ARWRTH] You lie, you piece of dung. You acted so high an' mighty, and then you go blindly followin' without a care or thought in th' world. Th' blood's on your hands, and those screams will haunt you past death's door. Think you will keep her precious lips close to you now, mercenary?~ [C-ARW005]

== C-ARN25J ~[ARAN] Gods...~ [ARAN_SOUND_HERE]

== C-ARWRTH ~[C-ARWRTH] Murderers all, we happy few. And you with th' weak stomach cryin' like a baby, battin' at the flames while your comrades died. Twice murderous, bastard. Charred flesh was not about to rise, an' we died because you had no stomach for th' collateral damage. Are you cryin' now?~ [C-ARW006]

END

++ ~[PC] Don't say those things to Aran! He did what he had to!~ EXTERN HGWRA01 25

++ ~[PC] I... I knew you had done some difficult things in your past, but you never told me about this, Aran.~ EXTERN C-ARN25J c_wraith_below_belt

++ ~[PC] Stop tormenting Aran, spirit! ~ EXTERN HGWRA01 25

++ ~[PC] Gorion, stop this! I won't let this go any further!~ EXTERN HGWRA01 25

+ ~CheckStatGT(Player1,16,WIS)~ + ~[PC] Aran, this isn't real. Don't listen to it!~ EXTERN C-ARN25J c_wraith_below_belt

 

APPEND C-ARN25J

 

IF ~~ c_wraith_below_belt

SAY ~[ARAN] By Ilmater's Tears, that don't help th' feelin's this bastard be slappin' me with. For th' sake o' mercy, can we shut him th' blighted hells up?~

IF ~~ THEN EXTERN HGWRA01 25

END

 

END

 

 

in c-arn25.baf

[code]

/* Master Wraith Post-Traumatic Stress Disorder Amelioration Talk */

IF

Global("c-aranpostwraith","GLOBAL",0)

GlobalGT("WraithPunish","GLOBAL",0)

Global("c-aranlovedone","GLOBAL",6)

InParty(Myself)

InMyArea(Player1)

!StateCheck(Player1,CD_STATE_NOTVALID)

!StateCheck(Myself,CD_STATE_NOTVALID)

CombatCounter(0)

!See([ENEMY])

THEN

RESPONSE #100

SetGlobal("c-aranpostwraith","GLOBAL",1)

END

 

IF

Global("c-aranpostwraith","GLOBAL",1)

InParty(Myself)

!StateCheck(Myself,CD_STATE_NOTVALID)

InMyArea(Player1)

!StateCheck(Player1,CD_STATE_NOTVALID)

THEN

RESPONSE #100

PlaySong(0)

PlaySound("C-ARANS")

StartDialogueNoSet(Player1)

END

 

 

in c-arantobdialog.d, in APPEND to C-ARN25J,

CODE

/* ToB Plot Talk : Post Wraith Talk™ */

IF ~Global("c-aranpostwraith","GLOBAL",1)~ c_post_wraith_talk_starts

SAY ~[ARAN] Gods.~

++ ~[PC] They had a little to do with it, I think. But not much. We survived through our own strength.~ DO ~SetGlobal("c-aranpostwraith","GLOBAL",2)~ + c_survived_it

++ ~[PC] Was... was what that ...thing... said. Was it true?~ DO ~SetGlobal("c-aranpostwraith","GLOBAL",2)~ + c_was_it_true

++ ~[PC] Are you crying?~ DO ~SetGlobal("c-aranpostwraith","GLOBAL",2)~ + c_arms_wrap

++ ~[PC] (Throw yourself into his arms and press your face against his chest.)~ DO ~SetGlobal("c-aranpostwraith","GLOBAL",2)~ + c_arms_wrap

++ ~[PC] I don't know what to say.~ + c_survived_it

++ ~[PC] So, a little history lesson for both of us?~ DO ~SetGlobal("c-aranpostwraith","GLOBAL",2)~ + c_survived_it

END

 

IF ~~ c_arms_wrap

SAY ~[ARAN] (His arms crush you close, his face hidden from your sight.)~

IF ~~ THEN GOTO c_survived_it

END

 

IF ~~ c_survived_it

SAY ~[ARAN] That thing... it might have been only a powerful spirit, a reflection. But... It spoke o' things we have not talked about.~

++ ~[PC] It spoke twisted lies to hurt and confuse us, and to separate us.~ + c_tell_the_truth

++ ~[PC] I don't want to hear any more. The past is the past. For both of us, the past is the past.~ + c_tell_the_truth

+ ~Alignment(Player1,MASK_EVIL)~ + ~[PC] If it spoke only a little truth, then you have more strength in you than I thought.~ + c_evil_strength

+ ~Alignment(Player1,MASK_GOOD)~ + ~[PC] If it spoke only a little truth, then you have more strength in you than I thought.~ + c_good_strength

+ ~!Alignment(Player1,MASK_GOOD) !!Alignment(Player1,MASK_GOOD)~ + ~[PC] If it spoke only a little truth, then you have more strength in you than I thought.~ + c_neutral_strength

++ ~[PC] Aran, look at me... Look into my eyes. I love you.~ + c_tell_the_truth

++ ~[PC] You heard a twisted view of my life. I heard a twisted view of yours. It is over, and I never want to discuss it ever again. We need to move on, now. Pick up your gear, and help me get things back in order.~ + c_aye_can_do

END

 

IF ~~ c_tell_the_truth

SAY ~[ARAN] Truth be th' only way to really clear this burden. What that abomination said, it were true, to a point.~

= ~[ARAN] There be times when you know an order be just plain wrong, an' you have to make a choice. I chose to follow.~

= ~[ARAN] Th' details don't rightly matter, but th' result be an ugly truth. Good men can do horrible evil, just by followin' instead o' thinkin'.~

+ ~Alignment(Player1,MASK_EVIL)~ + ~[PC] Then you have more strength in you than I thought.~ + c_evil_strength

+ ~Alignment(Player1,MASK_GOOD)~ + ~[PC] Then you have more strength in you than I thought.~ + c_good_strength

+ ~!Alignment(Player1,MASK_GOOD) !!Alignment(Player1,MASK_GOOD)~ + ~[PC] Then you have more strength in you than I thought.~ + c_neutral_strength

++ ~[PC] I don't want to hear any more. The past is the past. For both of us, the past is the past.~ + c_tell_the_truth

++ ~[PC] You really burned innocent children alive, and broke down in battle?~ + c_can_you_handle_the_truth

END

 

IF ~~ c_can_you_handle_the_truth

SAY ~[ARAN] I'd say it different. I'd say I followed th' orders to set th' village afire. I'd say I thought there might be some innocents there, an' mayhap th' enemy was shieldin' themselves. I'd say that when I saw th' sight an' heard th' screams, I ran to see if I could undo what had been done...~

= ~[ARAN] What I had done.~

= ~[ARAN] But when it be th' truth between my soul an' you, yes. I did.~

++ ~[PC] Get. away. from. me.~ + c_no_longer_welcome

+ ~Alignment(Player1,MASK_EVIL)~ + ~[PC] Then you have more strength in you than I thought.~ + c_evil_strength

+ ~Alignment(Player1,MASK_GOOD)~ + ~[PC] Then you have more strength in you than I thought.~ + c_good_strength

+ ~!Alignment(Player1,MASK_GOOD) !!Alignment(Player1,MASK_GOOD)~ + ~[PC] Then you have more strength in you than I thought.~ + c_neutral_strength

++ ~[PC] You had no choice. An order is an order. You could not have been sure. It was not your place to make that choice.~ + c_we_all_have_choices

++ ~[PC] Why have you not told me this before now?~ + c_how_can_you_tell

++ ~[PC] I could say that everything that has happened to us is my fault. That would not be truth. It would be self-pity.~ + c_self_pity

END

 

IF ~~ c_self_pity

SAY ~[ARAN] You could say that it be self pity. But there be a difference in my case. You didn't choose your blood or th' things what followed. Me, I could say I had no choices...~

IF ~~ THEN GOTO c_we_all_have_choices

END

 

IF ~~ c_evil_strength

SAY ~[ARAN] What do you mean?~

++ ~[PC] You knew I would see this as an opportunity, a weakness in your character that I could exploit. You held it from me, even while showing me how much you care for me. That kind of inner strength, I can respect. Can you understand that?~ + c_aye_can_do

++ ~[PC] You followed orders, even when you felt that they were wrong. You may have regretted doing so, but you followed. I know now that you will do anything for me, even if it goes against your very soul to do so. That is the kind of control I crave. Can you understand that?~ + c_aye_can_do

++ ~[PC] I do not see things the same way you do, Aran. I know you are hurting, and I hurt because you hurt... but in my eyes, you are blameless. War destroys all it touches, which is why we wield it very carefully. Can you understand that?~ + c_aye_can_do

++ ~[PC] You knew even I have limits on what I am willing to do to further my own ends, and you sought to hide something I would never condone so that you could be with me. I don't like that, but I respect that. Can you understand that?~ + c_aye_can_do

++ ~[PC] You risked everything to tell me the truth. If that is not love, then I do not know what love really is. Can you understand that?~ + c_aye_can_do

END

 

IF ~~ c_good_strength

SAY ~[ARAN] What do you mean?~

++ ~[PC] You knew I would not be able to handle the burden of your feelings and my own guilt and frustration. You held this burden away from me. That takes strength.~ + c_mayhap_stronger

++ ~[PC] You risked everything to tell me the truth. If that is not love, then I do not know what love really is. Do you understand what I am saying to you?~ + c_aye_can_do

++ ~[PC] I do not see things the same way you do, Aran. I know you are hurting, and I hurt because you hurt... but in my eyes, you are blameless. War destroys all it touches, which is why we wield it very carefully. Can you understand that?~ + c_aye_can_do

++ ~[PC] I try to do the right thing. But my hands are stained with innocent blood too; there can be no mortal way of stopping the consequences of violent action. But the pain you feel, the guilt, shows a strong conscience. I can love a man who takes responsibility for his actions.~ + c_mayhap_stronger

++ ~[PC] You managed to lie to me every day that we have known each other. You know, I do not need your twisting and hiding the truth. You should leave.~ + c_no_longer_welcome

END

 

IF ~~ c_neutral_strength

SAY ~[ARAN] What do you mean?~

++ ~[PC] You knew I would not be able to handle the burden of your feelings and my own guilt and frustration. You held this burden away from me. That takes strength.~ + c_mayhap_stronger

++ ~[PC] I do not see things the same way you do, Aran. I know you are hurting, and I hurt because you hurt... but in my eyes, you are blameless. War destroys all it touches, which is why we wield it very carefully. Can you understand that?~ + c_aye_can_do

++ ~[PC] There is no right or wrong in these things, Aran. The same hand that sweeps away a Tyrant kills innocents. Balance, chaos, order... all of those are a part of life on Faerun. We just have to make sense of this for ourselves, and remember we are just passengers on this plane of existence. Do you understand?~ + c_mayhap_stronger

++ ~[PC] Strength of character. You decided when to tell me what you are capable of. I can love a man who shows that kind of restraint.~ + c_mayhap_stronger

++ ~[PC] You managed to lie to me every day that we have known each other. You know, I do not need your twisting and hiding the truth. You should leave.~ + c_no_longer_welcome

END

 

IF ~~ c_we_all_have_choices

SAY ~[ARAN] That be a lie. We all have choices, every second o' every day. An' when we make th' wrong ones, we with death in our hands an' blood in our hearts... we kill people. We make that choice.~

++ ~[PC] Would you ever have told me?~ + c_ever_told

++ ~[PC] Then I am making a choice right now. I think you should leave.~ + c_no_longer_welcome

++ ~[PC] Then I make a choice every minute of every day. I chose to love you.~ + c_i_love_you

++ ~[PC] Aran... You and I know you are not the only person in my life. But I keep choosing to be with you. That should tell you that I can handle both the good and the bad in you. I love you.~ + c_i_love_you

++ ~[PC] I have done worse things than you could ever imagine. War claims all in its path as victims. As I see it, you have no more need of self-recrimination than I need apologize for being the child of a dead god. I can live with that. Can you?~ + c_aye_can_do

END

 

IF ~~ c_how_can_you_tell

SAY ~[ARAN] I have told no one. Never. Until now.~

++ ~[PC] Would you ever have told me?~ + c_ever_told

++ ~[PC] And you say you love me. You really think I am that weak.~ + c_that_weak

++ ~[PC] Thank you for telling me the truth. I understand... there are things in all of our pasts that we want buried forever. Do you love me?~ + c_of_course_i_do

++ ~[PC] Aran... You and I know you are not the only person in my life. But I keep choosing to be with you. That should tell you that I can handle both the good and the bad in you. I love you.~ + c_i_love_you

END

 

IF ~~ c_that_weak

SAY ~[ARAN] Now, hold on, I was tryin' to keep th' guilt off of...~

++ ~[PC] I can handle guilt. I can handle blood. I was born to it. What I can't handle is someone who claims to love me, but will hide things from me. You should leave. Now.~ + c_no_longer_welcome

++ ~[PC] I... I understand. You did not think I was strong enough. I don't think you realize how strong a woman can be for the man she loves.~ + c_mayhap_stronger

++ ~[PC] Don't you love me?~ + c_of_course_i_do

++ ~[PC] I have held things back from you, too. Did you know that I envied Imoen? That I hated Gorion for keeping me away from a life outside the library? That I have killed without remorse, tricked and lied my way through life, and that in spite of it all I can't stop loving a silly do-gooder who can't seem to see exactly how wrong I am for him? Love stinks, doesn't it.~ + c_mayhap_stronger

++ ~[PC] No, you misunderstand me. I am that weak. I... I can see myself, and I hate that woman. I needed to think you were different. Perhaps it is time I grew up, and realized that we all carry burdens. I... I just need your help, sharing the weight between the two of us.~ + c_mayhap_stronger

END

 

IF ~~ c_ever_told

SAY ~[ARAN] Told you wi' out all this? On th' truth an' respect I have for you... no. I would not.~

++ ~[PC] Don't you love me?~ + c_of_course_i_do

++ ~[PC] You were wise. I can't have the blood and guilt you bring added to my burdens. You need to find your own path.~ + c_no_longer_welcome

++ ~[PC] I can handle guilt. I can handle blood. I was born to it. What I can't handle is someone who claims to love me, but will hide things from me. You should leave. Now.~ + c_no_longer_welcome

++ ~[PC] I... I understand. You did not think I was strong enough. I don't think you realize how strong a woman can be for the man she loves.~ + c_mayhap_stronger

++ ~[PC] I have held things back from you, too. Did you know that I envied Imoen? That I hated Gorion for keeping me away from a life outside the library? That I have killed without remorse, tricked and lied my way through life, and that in spite of it all I can't stop loving a silly do-gooder who can't seem to see exactly how wrong I am for him? Love stinks, doesn't it.~ + c_mayhap_stronger

END

 

IF ~~ c_of_course_i_do

SAY ~[ARAN] O' course I do.~

++ ~[PC] Then trust me. No secrets. I am a Child of Murder. If I can handle that truth, then I can handle your truth.~ + c_mayhap_stronger

++ ~[PC] Then say no more about this. What is past is past, and we have a future to plan. Don't let old blood drown a new life together.~ + c_mayhap_stronger

++ ~[PC] Then... I need you to leave. I have the weight of my own guilt to carry. I can't handle both yours and mine.~ + c_no_longer_welcome

++ ~[PC] Then kiss me, and forget the past. We have to focus on what is ahead of us, not what is behind us.~ + c_mayhap_stronger

END

 

IF ~~ c_no_longer_welcome

SAY ~[ARAN] I... ~

= ~[ARAN] ... ~

IF ~~ THEN DO ~SetGlobal("c-aranrom","GLOBAL",3) GivePartyAllEquipment() LeaveParty() EscapeAreaDestroy()~ EXIT

END

 

IF ~~ c_mayhap_stronger

SAY ~[ARAN] Mayhap you be right. I learn somethin' new about you almost every day.~

IF ~~ THEN GOTO c_i_love_you

END

 

IF ~~ c_i_love_you

SAY ~[ARAN] I don't think I say this right strong enough, or often enough.~

= ~[ARAN] I love you.~

IF ~~ THEN EXIT

END

 

IF ~~ c_aye_can_do

SAY ~[ARAN] Aye.~

IF ~~ THEN EXIT

END

 

 

As always, commentary welcome!

Link to comment

You cheap sack of treehugging drama, you said there'd be Xtreme violence found inside when there is none! :thumbsup:

 

~!Alignment(Player1,MASK_GOOD) !!Alignment(Player1,MASK_GOOD)~
Huh? You probably meant ~Alignment(Player1,MASK_GENEUTRAL)~.

 

~[PC] Get. away. from. me.~
Should they not begin with capitals?

 

IF ~~ c_survived_it
Doesn't seem enough 'truth' to have been said here, making ~You risked everything to tell me the truth.~ in 'c_*_strength's to sound a bit weird.

 

IF ~~ c_tell_the_truth
4th transition, infinite loop.

 

IF ~~ c_no_longer_welcome
I'd ask PC if she's real certain about him leaving.
Link to comment

I thought the reference to burning children alive and wartime killing of innocents was pretty extreme, but then again, I hide my eyes during Jurrasic Park!

 

(Perhaps I should remove the warning...)

 

Taking a look through the others (thank you) - edits forthcoming

Link to comment

OK, adjustments -

 

Good point on the whole "truth" thing, so I set things "downstream" one talk. Added a reference point for the crying. I think I am going to use

 

~!Alignment(PC,M_G) !Alignment(PC,M_G)~

 

as I think GENEUTRAL contains NG,NE,N - what I need is for the M_G to cover all forms of good, M_E to cover all forms of evil -

 

errr..

 

I bet that is LCNEUTRAL.

 

 

 

in c-arantobdialog.d, in APPEND to C-ARN25J,

/* ToB Plot Talk : Post Wraith Talk(tm)  */
IF ~Global("c-aranpostwraith","GLOBAL",1)~ c_post_wraith_talk_starts
 SAY ~[ARAN] Gods.~
 ++ ~[PC] They had a little to do with it, I think. But not much. We survived through our own strength.~ DO ~SetGlobal("c-aranpostwraith","GLOBAL",2)~ + c_survived_it
 ++ ~[PC] Was... was what that ...thing... what it said. Was it true?~ DO ~SetGlobal("c-aranpostwraith","GLOBAL",2)~ + c_was_it_true
 ++ ~[PC] Are you crying?~ DO ~SetGlobal("c-aranpostwraith","GLOBAL",2)~ + c_crying_about_it
 ++ ~[PC] (Throw yourself into his arms and press your face against his chest.)~ DO ~SetGlobal("c-aranpostwraith","GLOBAL",2)~ + c_arms_wrap
 ++ ~[PC] I don't know what to say.~ DO ~SetGlobal("c-aranpostwraith","GLOBAL",2)~ + c_survived_it
 ++ ~[PC] So, a little history lesson for both of us?~ DO ~SetGlobal("c-aranpostwraith","GLOBAL",2)~ + c_survived_it
END

IF ~~ c_crying_about_it
 SAY ~[ARAN] Th' sounds... gods.~
 ++ ~[PC] You *are* crying. You let it get to you.~ + c_survived_it
 ++ ~[PC] (Throw yourself into his arms and press your face against his chest.)~  + c_arms_wrap
 ++ ~[PC] It was so real. An illusion, but so real. I could hear Gorion, and it sounded just like him. See, I am crying, too.~ + c_arms_wrap
 ++ ~[PC] Stop. There is no point in letting the shades of our pasts hurt us like this.~ + c_survived_it
 ++ ~[PC] Don't... don't cry. I can't hold things together when you cry.~ + c_arms_wrap
END

IF ~~ c_arms_wrap
 SAY ~[ARAN] (His arms crush you close, his face hidden from your sight.)~ 
 IF ~~ THEN GOTO c_survived_it
END

IF ~~ c_survived_it
 SAY ~[ARAN] That thing... it might have been only a powerful spirit, a reflection. But... It spoke o' things we have not talked about.~
 ++ ~[PC] It spoke twisted lies to hurt and confuse us, and to separate us.~ + c_tell_the_truth
 ++ ~[PC] I don't want to hear any more. The past is the past. For both of us, the past is the past.~ + c_tell_the_truth
 ++ ~[PC] (Look into his eyes.)~ + c_tell_the_truth
 ++ ~[PC] Aran, look at me... Look into my eyes. I love you.~ + c_tell_the_truth
 ++ ~[PC] You heard a twisted view of my life. I heard a twisted view of yours. It is over, and I never want to discuss it ever again. We need to move on, now. Pick up your gear, and help me get things back in order.~ + c_aye_can_do
END

IF ~~ c_tell_the_truth
 SAY ~[ARAN] Truth be th' only way to really clear this burden. What that abomination said, it were true, to a point.~
 = ~[ARAN] There be times when you know an order be just plain wrong, an' you have to make a choice. I chose to follow.~
 = ~[ARAN] Th' details don't rightly matter, but th' result be an ugly truth. Good men can do horrible evil, just by followin' instead o' thinkin'.~
 + ~Alignment(Player1,MASK_EVIL)~ + ~[PC] Then you have more strength in you than I thought.~ + c_evil_strength
 + ~Alignment(Player1,MASK_GOOD)~ + ~[PC] Then you have more strength in you than I thought.~ + c_good_strength
 + ~!Alignment(Player1,MASK_EVIL) !Alignment(Player1,MASK_GOOD)~ + ~[PC] Then you have more strength in you than I thought.~ + c_neutral_strength
 ++ ~[PC] I don't want to hear any more. The past is the past. For both of us, the past is the past. Can we stop discussing this?~ + c_aye_can_do
 ++ ~[PC] You really burned innocent children alive, and broke down in battle?~ + c_can_you_handle_the_truth
END

IF ~~ c_can_you_handle_the_truth
 SAY ~[ARAN] I'd say it different. I'd say I followed th' orders to set th' village afire. I'd say I thought there might be some innocents there, an' mayhap th' enemy was shieldin' themselves. I'd say that when I saw th' sight an' heard th' screams, I ran to see if I could undo what had been done...~
 = ~[ARAN] What I had done.~
 = ~[ARAN] But when it be th' truth between my soul an' you, yes. I did.~
 ++ ~[PC] Get. Away. From. Me.~ + c_no_longer_welcome
 + ~Alignment(Player1,MASK_EVIL)~ + ~[PC] Then you have more strength in you than I thought.~ + c_evil_strength
 + ~Alignment(Player1,MASK_GOOD)~ + ~[PC] Then you have more strength in you than I thought.~ + c_good_strength
 + ~!Alignment(Player1,MASK_EVIL) !Alignment(Player1,MASK_GOOD)~ + ~[PC] Then you have more strength in you than I thought.~ + c_neutral_strength
 ++ ~[PC] You had no choice. An order is an order. You could not have been sure. It was not your place to make that choice.~ + c_we_all_have_choices
 ++ ~[PC] Why have you not told me this before now?~ + c_how_can_you_tell
 ++ ~[PC] I could say that everything that has happened to us is my fault. That would not be truth. It would be self-pity.~ + c_self_pity
END

IF ~~ c_self_pity
 SAY ~[ARAN] You could say that it be self pity. But there be a difference in my case. You didn't choose your blood or th' things what followed. Me, I could say I had no choices...~
 IF ~~ THEN GOTO c_we_all_have_choices
END

IF ~~ c_evil_strength
 SAY ~[ARAN] What do you mean?~
 ++ ~[PC] You knew I would see this as an opportunity, a weakness in your character that I could exploit. You held it from me, even while showing me how much you care for me. That kind of inner strength, I can respect. Can you understand that?~ + c_aye_can_do
 ++ ~[PC] You followed orders, even when you felt that they were wrong. You may have regretted doing so, but you followed. I know now that you will do anything for me, even if it goes against your very soul to do so. That is the kind of control I crave.  Can you understand that?~ + c_aye_can_do
 ++ ~[PC] I do not see things the same way you do, Aran. I know you are hurting, and I hurt because you hurt... but in my eyes, you are blameless. War destroys all it touches, which is why we wield it very carefully. Can you understand that?~ + c_aye_can_do
 ++ ~[PC] You knew even I have limits on what I am willing to do to further my own ends, and you sought to hide something I would never condone so that you could be with me. I don't like that, but I respect that.  Can you understand that?~ + c_aye_can_do
 ++ ~[PC] You risked everything to tell me the truth. If that is not love, then I do not know what love really is.  Can you understand that?~ + c_aye_can_do
END

IF ~~ c_good_strength
 SAY ~[ARAN] What do you mean?~
 ++ ~[PC] You knew I would not be able to handle the burden of your feelings and my own guilt and frustration. You held this burden away from me. That takes strength.~ + c_mayhap_stronger
 ++ ~[PC] You risked everything to tell me the truth. If that is not love, then I do not know what love really is. Do you understand what I am saying to you?~ + c_aye_can_do
 ++ ~[PC] I do not see things the same way you do, Aran. I know you are hurting, and I hurt because you hurt... but in my eyes, you are blameless. War destroys all it touches, which is why we wield it very carefully. Can you understand that?~ + c_aye_can_do
 ++ ~[PC] I try to do the right thing. But my hands are stained with innocent blood too; there can be no mortal way of stopping the consequences of violent action. But the pain you feel, the guilt, shows a strong conscience. I can love a man who takes responsibility for his actions.~ + c_mayhap_stronger
 ++ ~[PC] You managed to lie to me every day that we have known each other. You know, I do not need your twisting and hiding the truth. You should leave.~ + c_no_longer_welcome
END

IF ~~ c_neutral_strength
 SAY ~[ARAN] What do you mean?~
 ++ ~[PC] You knew I would not be able to handle the burden of your feelings and my own guilt and frustration. You held this burden away from me. That takes strength.~ + c_mayhap_stronger
 ++ ~[PC] I do not see things the same way you do, Aran. I know you are hurting, and I hurt because you hurt... but in my eyes, you are blameless. War destroys all it touches, which is why we wield it very carefully. Can you understand that?~ + c_aye_can_do
 ++ ~[PC] There is no right or wrong in these things, Aran. The same hand that sweeps away a Tyrant kills innocents. Balance, chaos, order... all of those are a part of life on Faerun. We just have to make sense of this for ourselves, and remember we are just passengers on this plane of existence. Do you understand?~ + c_mayhap_stronger
 ++ ~[PC] Strength of character. You decided when to tell me what you are capable of. I can love a man who shows that kind of restraint.~ + c_mayhap_stronger
 ++ ~[PC] You managed to lie to me every day that we have known each other. You know, I do not need your twisting and hiding the truth. You should leave.~ + c_no_longer_welcome
END

IF ~~ c_we_all_have_choices
 SAY ~[ARAN] That be a lie. We all have choices, every second o' every day. An' when we make th' wrong ones, we with death in our hands an' blood in our hearts... we kill people. We make that choice.~
 ++ ~[PC] Would you ever have told me?~ + c_ever_told
 ++ ~[PC] Then I am making a choice right now. I think you should leave.~ + c_no_longer_welcome
 ++ ~[PC] Then I make a choice every minute of every day. I chose to love you.~ + c_i_love_you
 ++ ~[PC] Aran... You and I know you are not the only person in my life. But I keep choosing to be with you. That should tell you that I can handle both the good and the bad in you. I love you.~ + c_i_love_you
 ++ ~[PC] I have done worse things than you could ever imagine. War claims all in its path as victims. As I see it, you have no more need of self-recrimination than I need apologize for being the child of a dead god. I can live with that. Can you?~ + c_aye_can_do
END

IF ~~ c_how_can_you_tell
 SAY ~[ARAN] I have told no one. Never. Until now.~
 ++ ~[PC] Would you ever have told me?~ + c_ever_told
 ++ ~[PC] And you say you love me. You really think I am that weak.~ + c_that_weak
 ++ ~[PC] Thank you for telling me the truth. I understand... there are things in all of our pasts that we want buried forever. Do you love me?~ + c_of_course_i_do
 ++ ~[PC] Aran... You and I know you are not the only person in my life. But I keep choosing to be with you. That should tell you that I can handle both the good and the bad in you. I love you.~ + c_i_love_you
END

IF ~~ c_that_weak
 SAY ~[ARAN] Now, hold on, I was tryin' to keep th' guilt off of...~
 ++ ~[PC] I can handle guilt. I can handle blood. I was born to it. What I can't handle is someone who claims to love me, but will hide things from me. You should leave. Now.~ + c_no_longer_welcome
 ++ ~[PC] I... I understand. You did not think I was strong enough. I don't think you realize how strong a woman can be for the man she loves.~ + c_mayhap_stronger
 ++ ~[PC] Don't you love me?~ + c_of_course_i_do
 ++ ~[PC] I have held things back from you, too. Did you know that I envied Imoen? That I hated Gorion for keeping me away from a life outside the library? That I have killed without remorse, tricked and lied my way through life, and that in spite of it all I can't stop loving a silly do-gooder who can't seem to see exactly how wrong I am for him? Love stinks, doesn't it.~ + c_mayhap_stronger
 ++ ~[PC] No, you misunderstand me. I am that weak. I... I can see myself, and I hate that woman. I needed to think you were different. Perhaps it is time I grew up, and realized that we all carry burdens. I... I just need your help, sharing  the weight between the two of us.~ + c_mayhap_stronger
END

IF ~~ c_ever_told
 SAY ~[ARAN] Told you wi' out all this? On th' truth an' respect I have for you... no. I would not.~
 ++ ~[PC] Don't you love me?~ + c_of_course_i_do
 ++ ~[PC] You were wise. I can't have the blood and guilt you bring added to my burdens. You need to find your own path.~ + c_no_longer_welcome
 ++ ~[PC] I can handle guilt. I can handle blood. I was born to it. What I can't handle is someone who claims to love me, but will hide things from me. You should leave. Now.~ + c_no_longer_welcome
 ++ ~[PC] I... I understand. You did not think I was strong enough. I don't think you realize how strong a woman can be for the man she loves.~ + c_mayhap_stronger
 ++ ~[PC] I have held things back from you, too. Did you know that I envied Imoen? That I hated Gorion for keeping me away from a life outside the library? That I have killed without remorse, tricked and lied my way through life, and that in spite of it all I can't stop loving a silly do-gooder who can't seem to see exactly how wrong I am for him? Love stinks, doesn't it.~ + c_mayhap_stronger
END

IF ~~ c_of_course_i_do
 SAY ~[ARAN] O' course I do.~
 ++ ~[PC] Then trust me. No secrets. I am a Child of Murder. If I can handle that truth, then I can handle your truth.~ + c_mayhap_stronger
 ++ ~[PC] Then say no more about this. What is past is past, and we have a future to plan. Don't let old blood drown a new life together.~ + c_mayhap_stronger
 ++ ~[PC] Then... I need you to leave. I have the weight of my own guilt to carry. I can't handle both yours and mine.~ + c_no_longer_welcome
 ++ ~[PC] Then kiss me, and forget the past. We have to focus on what is ahead of us, not what is behind us.~ DO ~SetGlobal("c-aranintimate","GLOBAL",1)~ + c_mayhap_stronger
END

IF ~~ c_no_longer_welcome
 SAY ~[ARAN] I... ~
 = ~[ARAN] ... ~
 = ~[ARAN] You want me to go.~
 ++ ~[PC] (Turn your back to him, walking away silently.)~ DO ~SetGlobal("c-aranflirtstop","GLOBAL",1) SetGlobal("c-aranfight","GLOBAL",0) SetGlobal("c-aranrom","GLOBAL",3) ActionOverride("c-aran",GivePartyAllEquipment()) ActionOverride("c-aran",LeaveParty()) ActionOverride("c-aran",EscapeAreaDestroy())~ EXIT
 ++ ~[PC] Leave.~ DO ~SetGlobal("c-aranflirtstop","GLOBAL",1) SetGlobal("c-aranfight","GLOBAL",0) SetGlobal("c-aranrom","GLOBAL",3) ActionOverride("c-aran",GivePartyAllEquipment()) ActionOverride("c-aran",LeaveParty()) ActionOverride("c-aran",EscapeAreaDestroy())~ EXIT
 ++ ~[PC] No. Stay with the party. But stay away from me.~ DO ~SetGlobal("c-aranflirtstop","GLOBAL",1) SetGlobal("c-aranfight","GLOBAL",0) SetGlobal("c-aranrom","GLOBAL",3)~ + c_aye_can_do
 ++ ~[PC] I need time to understand what you did. Just leave me alone for awhile, while I think.~ DO ~SetGlobal("c-aranflirtstop","GLOBAL",1) SetGlobal("c-aranfight","GLOBAL",0) SetGlobal("c-aranpostwraith","GLOBAL",3) SetGlobalTimer("c-aranwraithink","GLOBAL",FOUR_DAYS)~ + c_aye_can_do // don't want a fight to kick this into gear. Needs follow up talk, probably.
END

IF ~~ c_mayhap_stronger
 SAY ~[ARAN] Mayhap you be right. I learn somethin' new about you almost every day.~
 IF ~~ THEN GOTO c_i_love_you
END

IF ~~ c_i_love_you
 SAY ~[ARAN] I don't think I say this right strong enough, or often enough.~
 = ~[ARAN] I love you.~
 IF ~~ THEN EXIT
END

IF ~~ c_aye_can_do
 SAY ~[ARAN] Aye.~
 IF ~~ THEN EXIT
END


/* for followup: BCS
Global("c-aranpostwraith","GLOBAL",3)
GlobalTimerExpired("c-aranwraithink","GLOBAL",FOUR_DAYS)
SetGlobal("c-aranpostwraith","GLOBAL",4)

IF ~Global("c-aranpostwraith","GLOBAL",4)~ c_are_we_on_or_are_we_done
*/

Link to comment

Well, I finally found out how the darned game handles the summoned "lovedone" after the talk is over - I should have just researched using other folk's mods, but I had enough trouble keeping everything in my head that this one I tracked through manually. Slow as molasses sometimes, I am. Yoda speak today, I guess.

 

So, the way vanilla handles getting rid of the summoned lovedone.cre, which in this case would be C-ARWRTH, is to have a bunch of blocks in cut218g.baf:

IF
True()
THEN
RESPONSE #100
	CutSceneId(Player1)
	CreateVisualEffect("ICFIRSDI",[1573.1342])
	CreateVisualEffect("ICFIRSDI",[1514.1491])
	Wait(1)
	CreateCreature("HGWRA03",[1454.1398],0) // Devil Shade
	CreateCreature("HGMIS01",[1454.1398],0) // Vampiric Wraith
	CreateCreature("HGMIS02",[1454.1398],0) // Swamp Horror
	CreateCreature("HGWRA03",[1514.1491],0) // Devil Shade
	CreateCreature("HGMIS01",[1514.1491],0) // Vampiric Wraith
	CreateCreature("HGMIS02",[1514.1491],0) // Swamp Horror
	EndCutSceneMode()
END

IF
True()
THEN
RESPONSE #100
	CutSceneId("hgwra01")
	CreateVisualEffectObject("SPFLESHS",Myself)
	Wait(1)
	SetName(70034) // Master Wraith
	ChangeAlignment(Myself,LAWFUL_EVIL)
	Enemy()
END

IF
True()
THEN
RESPONSE #100
	CutSceneId("loveone1")
	CreateVisualEffectObject("SPFLESHS",Myself)
	Wait(1)
	ChangeAnimation("HGWRA02") // Devil Shade
END

IF
True()
THEN
RESPONSE #100
	CutSceneId("loveone2")
	CreateVisualEffectObject("SPFLESHS",Myself)
	Wait(1)
	ChangeAnimation("HGWRA02") // Devil Shade
END

IF
True()
THEN
RESPONSE #100
	CutSceneId("loveone3")
	CreateVisualEffectObject("SPFLESHS",Myself)
	Wait(1)
	ChangeAnimation("HGWRA02") // Devil Shade
END

IF
True()
THEN
RESPONSE #100
	CutSceneId("loveone4")
	CreateVisualEffectObject("SPFLESHS",Myself)
	Wait(1)
	ChangeAnimation("HGWRA02") // Devil Shade
END

 

So, if we want to match the transformation of the former loved one/angsty attack drone targetting our NPC into something that looks like a devil Shade, to be summarily dispatched by the adventuring party, we copy the format of the loveone blocks above and then EXTEND_BOTTOM on the cutscene:

/* change animation so we can get rid of the .cre in the combat at the end of the encounter during cutscene cut218g */
IF
True()
THEN
RESPONSE #100
	CutSceneId("C-ARWRTH")
	CreateVisualEffectObject("SPFLESHS",Myself)
	Wait(1)
	ChangeAnimation("HGWRA02") // Devil Shade
END

 

Follow for recheck - what scripts do the loveone4.cre et al carry, letting them go hostile?

Link to comment

Archived

This topic is now archived and is closed to further replies.

×
×
  • Create New...