Jump to content

The 'Various FriendTalks In No Particular Order' Thread


cmorgan

Recommended Posts

OK, because I am falling behind and delaying for a comprehensive list of non-canonical non-BioWare™ crossmod references for a full tutorialization of the various dialog files and their usages, a Monday posting of a Friend Talk that has been stewing for awhile. Since it is FT 8, it might need some sprucing up to allow for an active romance.

 

If you are reading along for coding ideas, remember that the eventual order is

 

BEGIN ~dialogfile~

 

all I_C_T[2,3,4]

 

all APPEND s

 

all CHAIN s

 

 

This is not in that particular order yet, as it is easier for me to check dialog flow visually when it is in this order. Some coding things to think about:

1. the big reminds us that WeiDU line counting works best if you indent code and if you leave a carriage return at the end of the file. Windows folks sometimes forget those things. He has tried to compensate for it in later WeiDU versions, but since it is good practice anyways...

2. Usually friend talks are basic 1 - on - 1 banters between PC and NPC. I am choosing to see friendtalks as group discussions, but still - a little goes a long, long way. If everyone comments everywhere, ther can be troubles, especially as each group banter entry involves the modder making assumptions abut the characterization of the BioWare™ NPC. So while I want to digress into a side banter of Korgan and Aran trying to out-swear eachother, that realy belongs as a floater banter rather than sidelining a friendtalk.

3. The trend in many NPCs is to tackle a set of questions. I am running more topical/scenic on my attempts here, but this one realy does ave a question: Why do you swear so much, Aran? The coding challenge/author fun is figuring out how to tailor the response to accont for PC class and Aran's possible Cleric class. I am making the assumption that as a general non-kitted neutral good Cleric, Tymora will be Aran's choice. This means if someone makes him a Loremaster of Ogma, well - "conceptual incompatibility". Here, I am going to not go crazy over it. Perhaps later there will be a way of swapping in kitspecific stuff, but right now I will just make things as general as possible.

 

/* BG2 FriendTalk 8 c-aranfriendbg2 = 15 */
/* "Bhallspawn, Shmallspawn. Meh.", or, Gods and Monsters. */

CHAIN IF ~Global("c-aranfriendbg2","GLOBAL",15)~ THEN ~C-ARANJ~ c-aranft8
~[ARAN] Tempus' Shield, that tears it. That is the last time I get leatherwork cut rate. This blighted bootlace is parting. Anyone got a spare?~
DO ~SetGlobal("c-aranfriendbg2","GLOBAL",16) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_ROM)~
== ~JAHEIRAJ~ IF ~InParty("Jaheira") InMyArea("Jaheira") !StateCheck("Jaheira",CD_STATE_NOTVALID)~ THEN ~[JAHEIRA] You should be better prepared. Think ahead next time, Aran.~
== ~AERIEJ~ IF ~InParty("Aerie") InMyArea("Aerie") !StateCheck("Aerie",CD_STATE_NOTVALID)~ THEN ~[AERIE] I - I'm sorry, I don't have anything extra.~
== ~KORGANJ~ IF ~InParty("Korgan") InMyArea("Korgan") !StateCheck("Korgan",CD_STATE_NOTVALID)~ THEN ~[KORGAN] It will cost you a trade bar.~
== ~EDWINJ~ IF ~InParty("Edwin") InMyArea("Edwin") !StateCheck("Edwin",CD_STATE_NOTVALID)~ THEN ~[EDWIN] (Idiot.) Perhaps we would move faster if you held still while I carved a new one from your hide.~
== ~MINSCJ~ IF ~InParty("Minsc") InMyArea("Minsc") !StateCheck("Minsc",CD_STATE_NOTVALID)~ THEN ~[MINSC] Here, Aran, I have a bootlace!~
== ~C-ARANJ~ IF ~InParty("Minsc") InMyArea("Minsc") !StateCheck("Minsc",CD_STATE_NOTVALID)~ THEN  ~[ARAN] By the fire giant's gods, whomever they are... Minsc, you are a big, big boy. Thanks. I'll take a third o' that length.~
== ~CERNDJ~ IF ~InParty("Cernd") InMyArea("Cernd") !StateCheck("Cernd",CD_STATE_NOTVALID)~ THEN ~[CERND] You do not need leather to bind that. Nature provides many alternatives with similar strength, and the avoidance of killing an animal.~
== ~C-ARANJ~ IF ~InParty("Cernd") InMyArea("Cernd") !StateCheck("Cernd",CD_STATE_NOTVALID)~ THEN ~[ARAN] Mystra's Magnificent Mouth, Cernd... given the choice between my feet in battle an' the animal, I am considerin' the animal a distant second.~
END
+ ~!Class(Player1,CLERIC_ALL)~ + ~For the god's sake, slow down with the swearing, will you?~ EXTERN ~C-ARANJ~ c-aranft8general
+ ~OR(2) Class(Player1,PALADIN) Class(Player1,CLERIC_ALL) !Kit(Player1,GODTALOS) !Kit(Player1,GODHELM) !Kit(Player1,GODLATHANDER)~ EXTERN ~C-ARANJ~ ~Why are you blaspheming over something so minor, Aran?~ + c-aranft8specific
+ ~Class(Player1,CLERIC_ALL) Kit(Player1,GODHELM)~ + ~Here. But why are you blaspheming over something so minor, Aran?~ EXTERN ~C-ARANJ~ c-aranft8helm
+ ~Class(Player1,CLERIC_ALL) Kit(Player1,GODLATHANDER)~ + ~Here. But why are you blaspheming over something so minor, Aran?~ EXTERN ~C-ARANJ~ c-aranft8lathander
+ ~Class(Player1,CLERIC_ALL) Kit(Player1,GODTALOS)~ + ~Here. But why are you blaspheming over something so minor, Aran?~ EXTERN ~C-ARANJ~ c-aranft8talos
+ ~OR(2) Class(Player1,RANGER) Class(Player1,DRUID)~ + ~Here. But why are you blaspheming over something so minor, Aran?~ EXTERN ~C-ARANJ~ c-aranft8nature
++ ~You take every opportunity to swear, don't you, Aran.~ EXTERN ~C-ARANJ~ c-aranft8general
+ ~RandNum(5,1)~ + ~Alright, move along, everyone. The sellsword is having troubles again. Catch up fast, Aran.~ EXTERN ~C-ARANJ~ c-aranshutup1
+ ~RandNum(5,2)~ + ~Alright, move along, everyone. The sellsword is having troubles again. Catch up fast, Aran.~ EXTERN ~C-ARANJ~ c-aranshutup2
+ ~RandNum(5,3)~ + ~Alright, move along, everyone. The sellsword is having troubles again. Catch up fast, Aran.~ EXTERN ~C-ARANJ~ c-aranshutup3
+ ~RandNum(5,4)~ + ~Alright, move along, everyone. The sellsword is having troubles again. Catch up fast, Aran.~ EXTERN ~C-ARANJ~ c-aranshutup4
+ ~RandNum(5,5)~ + ~Alright, move along, everyone. The sellsword is having troubles again. Catch up fast, Aran.~ EXTERN ~C-ARANJ~ c-aranshutup5

/* Thought-Check: This chain will end up with 3 PC responses for non-clerics, druids, rangers; 4 for druids and rangers; 3 for clerics; 4 for paladins */

CHAIN ~C-ARANJ~ c-aranft8general
~[ARAN] Three things you shouldn't take from a man, <CHARNAME>... his swearin', his drink, and his weapon.~
== ~HAERDAJ~ IF ~InParty("HaerDalis") InMyArea("HaerDalis") !StateCheck("HaerDalis",CD_STATE_NOTVALID)~ THEN ~[HAERDALIS] Ah, fair fledgeling, I think you should simply say 'his voice'. And of course, no man or woman should ever lose that. ~
== ~KELDORJ~ IF ~InParty("Keldorn") InMyArea("Keldorn") !StateCheck("Keldorn",CD_STATE_NOTVALID)~ THEN ~[KELDORN] Invoking the gods is a natural stress release, Aran. But as you grow more powerful, the gods tend to listen more closely. They may take exception to having their name used so freely.~
== ~MAZZYJ~ IF ~InParty("Mazzy") InMyArea("Mazzy") !StateCheck("Mazzy",CD_STATE_NOTVALID)~ THEN ~[MAZZY] My mother often told me that swearing was not to be taken lightly, for it speaks to your soul as well as the gods.~
== ~NALIAJ~ IF ~InParty("Nalia") InMyArea("Nalia") !StateCheck("Nalia",CD_STATE_NOTVALID)~ THEN ~[NALIA] Swearing is both vulgar and common. A gentleman does not use such language.~
== ~C-ARANJ~ IF ~InParty("Nalia") InMyArea("Nalia") !StateCheck("Nalia",CD_STATE_NOTVALID)~ THEN ~[ARAN] I thought you were into helpin' th' 'common man', there, Nalia. I never claimed to be no gentleman.~
== ~NALIAJ~ IF ~InParty("Nalia") InMyArea("Nalia") !StateCheck("Nalia",CD_STATE_NOTVALID)~ THEN ~[NALIA] Teaching the commoners respect for the gods goes along with teaching respect for themselves, Aran.~
== ~VALYGARJ~ IF ~InParty("Valygar") InMyArea("Valygar") !StateCheck("Valygar",CD_STATE_NOTVALID)~ THEN ~[VALYGAR] Why risk the gods wrath?~
== ~VICONIJ~ IF ~InParty("Viconia") InMyArea("Viconia") !StateCheck("Viconia",CD_STATE_NOTVALID)~ THEN ~[VICONIA] Speak your words loudly, sellsword. I want to see your face just before an Avatar destroys you.~
== ~ANOMENJ~ IF ~InParty("Anomen") InMyArea("Anomen") !StateCheck("Anomen",CD_STATE_NOTVALID)~ THEN ~[ANOMEN] Your language offends me. Then again, your presence in general offends me.~
== ~C-ARANJ~ IF ~InParty("Anomen") InMyArea("Anomen") !StateCheck("Anomen",CD_STATE_NOTVALID)~ THEN ~[ARAN] Bugger off, jackass. Come talk wi' me when you got somethin' more than the foul smell o' breakin' wind from your mouth.~
== ~KORGANJ~ IF ~InParty("Korgan") InMyArea("Korgan") !StateCheck("Korgan",CD_STATE_NOTVALID)~ THEN ~[KORGAN] Let the sorry bastard say his piece.~
END
++ ~Don't you ever worry about the gods hearing your talk? Don't you ever expect help or advice or something to come of your call?~ EXTERN ~C-ARANJ~ c-aranft8attention
++ ~Hey, it is your business if you go around haphazardly calling random gods. But when one answers, you had better be prepared for the surprise.~ EXTERN ~C-ARANJ~ c-aranft8attention
++ ~Without faith, you are nothing. ~ EXTERN ~C-ARANJ~ c-aranft8attention
+ ~Class("c-aran",CLERIC_ALL)~ I thought you were a cleric, Aran. That should mean you only swear by your own god.~ EXTERN ~C-ARANJ~ c-aranft8arancleric
++ ~I didn't intend that to be a request. I don't want the attention drawn to us.~ EXTERN ~C-ARANJ~ c-aranft8attention
++ ~I am not taking any of those, Aran. Just settle down and choose one god or goddess, will you?~ EXTERN ~C-ARANJ~ c-aranft8attention

APPEND ~C-ARANJ~

IF ~~ c-aranft8specific
 SAY ~[ARAN] I know you are faithful to your god, <CHARNAME>... but I figure a few words in the air won't hurt anythin'.~
 ++ ~Don't you ever worry about the gods hearing your talk? Don't you ever expect help or advice or something to come of your call?~ + c-aranft8faith
 ++ ~Haphazardly calling random gods is dangerous to your soul.  IF you do not call on one god, who will claim you from Kelemvor's judgement?~ + c-aranft8faith
 ++ ~Without faith, you are nothing. Literally. As in abandoned from the Great Wheel.  IF you would like, we can pray together, and perhaps it will help you decide.~ + c-aranft8faith
 ++ ~I didn't intend that to be a request. I don't want the attention drawn to us.~ + c-aranft8faith
END

IF ~~ c-aranft8helm
 SAY ~[ARAN] Helm is a tough god, <CHARNAME>... a fine soldierin' one at that. But there's times where he doesn't quite cover it. I figure a few words in the air won't hurt anythin'. ~
 ++ ~You should worry about the gods hearing your talk. Do you not expect help or advice or something to come of your call?~ + c-aranft8faith
 ++ ~Haphazardly calling random gods is dangerous to your soul.  IF you do not call a just and fair god like Helm, who will claim you from Kelemvor's judgement?~ + c-aranft8faith
 ++ ~Without faith, you are nothing. Literally. As in abandoned from the Great Wheel.  IF you would like, we can pray together, and perhaps Helm with bear you up on his shield.~ + c-aranft8faith
 ++ ~I didn't intend that to be a request, Aran. I don't want the attention drawn to us.~ + c-aranft8faith
END

IF ~~ c-aranft8lathander
 SAY ~[ARAN] Lathander is a gentle god, <CHARNAME>... a fine one for new beginnings. And the gods know I need some new beginnings. But there's times where he doesn't quite cover it. I figure a few words in the air won't hurt anythin'.~
 ++ ~Don't you ever worry about the gods hearing your talk? Don't you ever expect help or advice or something to come of your call?~ + c-aranft8faith
 ++ ~Haphazardly calling random gods is dangerous to your soul.  IF you do not call a gentle and strong god like Lathander, who will claim you from Kelemvor's judgement?~ + c-aranft8faith
 ++ ~Without faith, you are nothing. Literally. As in abandoned from the Great Wheel.  If you would like, we can pray together, and perhaps Lathander will grant you a new beginning.~ + c-aranft8faith
 ++ ~I didn't intend that to be a request, Aran. I don't want the attention drawn to us.~ + c-aranft8faith
END

IF ~~ c-aranft8talos
 SAY ~[ARAN] Talos is a wild god, <CHARNAME>... one for power an' strength. Good to call on in battle. I figure a few words in the air won't hurt anythin'. ~
 ++ ~You are a fool to chatter on so. The gods will hear your talk. ~ + c-aranft8faith
 ++ ~Haphazardly calling random gods is dangerous to your soul.  IF you do not call a powerful god like Talos, no god will claim you from Kelemvor's judgement.~ + c-aranft8faith
 ++ ~Without faith, you are nothing. Literally. As in abandoned from the Great Wheel. Pray to Talos with me, sellsword. Perhaps you will weather this storm we call 'life.'~ + c-aranft8faith
 ++ ~I didn't intend that to be a request, sellsword. I don't want the attention drawn to us.~ + c-aranft8faith
END

IF ~~ c-aranft8nature
 SAY ~[ARAN] All you tree huggers do is talk about the balance and such. But you are good folks to watch a friend's back in battle that's for sure. I figure a few words in the air won't hurt the great balance, or whatever. ~
 ++ ~Tree hugger, eh? Thanks alot. Don't you ever worry about the gods hearing your talk? Don't you ever expect help or advice or something to come of your call?~ + c-aranft8faith
 ++ ~True balance requires choice, Aran. Haphazardly calling random gods is dangerous to your soul. ~ + c-aranft8faith
 ++ ~Without faith in Nature and her balance, you are nothing. Literally. As in abandoned from the Great Wheel.  If you would like, we can meditate together, and perhaps you will find some peace.~ + c-aranft8faith
 ++ ~I didn't intend that to be a request, sellsword. I don't want the attention drawn to us.~ + c-aranft8faith
END

IF ~~ c-aranft8faith
 SAY ~[ARAN] Look, I don't mean nothin'. I have faith in the gods. No offense, but I favor Tymora the most, an' I figure she would like the gamble. It's a soldier's perogative to swear, and I may take advantage a bit, but I don't mean you no harm. But I have to ask, why do you choose service your god? Seems like all they do is play with us mortals like toys. ~
 ++ ~I serve my chosen deity as I have always done. My faith grants me the ability to help others see the true path...~ + c-aranft8help
 ++ ~I serve my chosen deity as I have always done. My faith grants me discipline and control over myself.~ + c-aranft8control
 ++ ~I serve my chosen deity as I have always done. My faith grants me dominion over others and glories in my eventual rise to master of all.~ + c-aranft8ascend
 ++ ~I serve my chosen deity as I have always done. My faith grants me great power.~ + c-aranft8power
 ++ ~I serve my chosen deity for now. My faith in myself will be enough someday, and perhaps I will become a god.~ + c-aranft8ascend
 ++ ~I am not sure if you are ready to hear about my faith.~ + c-aranft8nothear
END

IF ~~ c-aranft8arancleric
 SAY ~[ARAN] Look, I don't mean nothin'. No offense to you, but I favor Tymora the most, an' I figure she likes the gamble. She sends me down some powers, so she can't be that angry about it. It's a soldier's perogative to swear, and I may take advantage a bit, but I don't mean you no harm. By the way, you ever considered followin' Tymora?~
 + ~ReputationLT(Player1,11)~  + ~I might be interested. What does Tymora offer me?~ + c-aranft8actionevil
 + ~ReputationGT(Player1,10) ReputationLT(Player1,15)~  + ~I might be interested. What does Tymora offer me?~ + c-aranft8actionneutral
 + ~ReputationGT(Player1,14)~  + ~I might be interested. What does Tymora offer me?~ + c-aranft8actiongood
 ++ ~Hey, that is getting a little personal. Do not try to sway my soul from its destined path, Aran. ~ + c-aranft8nosway
 ++ ~I serve my chosen deity for now. My faith in myself will be enough, and perhaps someday I will become a god myself.~ + c-aranft8ascend
 ++ ~I am not sure if you are ready to hear about my faith.~ + c-aranft8nothear
END

IF ~~ c-aranft8actionevil
 SAY ~[ARAN] You are playin' wi' me now, <CHARNAME>. Tymora might offer somethin', but she judges by actions. Right now, looks like you don't give decent odds on her investment. You'd have to clean up the way you are goin' and move more towards bright gold rather than deep shadow. But, if you ever do move in that direction, I'm right here to help out a bit.~
 IF ~~ THEN GOTO c-aranft8final
END

IF ~~ c-aranft8actionneutral
 SAY ~[ARAN] Well, she can offer some decent odds on fair gambles, <CHARNAME>.  IF you are really interested, then it might be a good move for you. She don't hold with extremes, except for takin' risks. You seem like th' sort to take a risk now an' then. Hey, you brought me along - that counts double!~
 IF ~~ THEN GOTO c-aranft8final
END

IF ~~ c-aranft8actiongood
 SAY ~[ARAN] Well now, Tymora does like a good bet, an' you have the 'good' part down, at least as far as your actions are speakin'. She don't hold with extremes, though, except for takin' risks. So, come talk sometime.~
 IF ~~ THEN GOTO c-aranft8final
END

IF ~~ c-aranft8nosway
 SAY ~[ARAN] Aye, I did jump too quick now, didn't I. I guess I have a bit to learn about the whole preachin' thing. I didn't mean nothin'.~
 IF ~~ THEN GOTO c-aranft8final
END

IF ~~ c-aranft8help
 SAY ~[ARAN] Tymorra's Coin, that is a fine idea. I like helpin' folks. Just I get the idea most clerics think that involves changin' gods.~
 IF ~~ THEN GOTO c-aranft8final
END

IF ~~ c-aranft8control
 SAY ~[ARAN] Tymorra's Coin, that is a strange proposition. I prefer to let things hang out a bit. More fun that way.~
 IF ~~ THEN GOTO c-aranft8final
END

IF ~~ c-aranft8ascend
 SAY ~[ARAN] Tymorra's Coin, and I thought *I* was the one with th' loose lacing.~
 IF ~~ THEN GOTO c-aranft8final
END

IF ~~ c-aranft8power
 SAY ~[ARAN] Tymorra's Coin, you better be careful. Seems to me gods have a tendency to give folks power and just to see if they have the sense not to use it.~
 IF ~~ THEN GOTO c-aranft8final
END

IF ~~ c-aranft8nothear
 SAY ~[ARAN] Fair enough. There's always other times to speak on this kind o' thing.~
 IF ~~ THEN GOTO c-aranft8final
END

IF ~~ c-aranft8attention
 SAY ~[ARAN] Clerics get all th' attention, far as I can see. Plus, I favor Tymora the most. I figure she would like the gamble.~
 IF ~~ THEN GOTO c-aranft8final
END

IF ~~ c-aranft8final
 SAY ~[ARAN] Besides, I am all done up. Give me a hand up, eh? We better get movin'.~
 IF ~~ THEN EXIT
END

END // of append block
Link to comment
== ~MAZZYJ~ IF ~InParty("Mazzy") InMyArea("Mazzy") !StateCheck("Mazzy",CD_STATE_NOTVALID)~ THEN ~[MAZZY] My mother often told me that swearing was not to be taken lightly, for it speaks to your soul as well as the gods.~

 

== ~C-ARANJ~ IF ~InParty("Anomen") InMyArea("Anomen") !StateCheck("Anomen",CD_STATE_NOTVALID)~ THEN ~[ARAN] Bugger off, jackass. Come talk wi' me when you got somethin' more than the foul smell o' breakin' wind from your mouth.~

 

++ ~Hey, it is your business if you go around haphazardly calling random gods. But when one answers, you had better be prepared for the surprise.~ EXTERN ~C-ARANJ~ c-aranft8attention

 

Also, there are several fully-capitalized IFs in the actual talk. :)

Link to comment

Neato!

 

Say, maybe Valygar can go with something a bit more colorful, given that he is a Faithless?

 

'Why risk the gods' wrath? It's at least as bad for a man as the gods' love' or something to that regard?

 

And seeing I am obsessed with the MotB's Wall of the Faithless, perhaps a special mocking gods answer for a Faithless PC? :p

Link to comment

Kelemvor started life as a human man. He was rewarded for the deeds of his life with immortality. His impartiality made him a good choice for god of the dead. His priests bring solace to the dying, and ensure that their mortal remains are treated with respect.

 

Because he was human before he was a god, perhaps, he brought some of his humanity to the afterlife. He tried to "do the right thing." He was probaby lawful good at this point.

 

The question about what to do with the godless had long been a problem. Because Kelemvor was merciful, he consigned mostly good souls to hang out in a nether-plane with other mostly good souls, and mostly evil souls to spend eternity with mostly evil ones. If a faithless man died, he'd go to the grave content that in all probability, he'd be in good company.

 

Something happened, don't know what, and Kelemvor was forced to reassess his beliefs. He came to realize that he could cling to his humanity no longer, as a god. It was not that he did not want to do so. It was just that his responsibilities were greater than his human mind could comprehend, and his judgment was compromised. So, with some reluctance, perhaps, he abandoned the last shred of his former self and became an unfailingly just, but merciless, god.

 

He dismantled the metaphorical meadhalls of good and evil and consigned all souls, regardless of past deeds or good intent, to a living wall, the Wall of the Faithless. At first, perhaps, captivity would drive the souls mad, but then, like the sailors on Davey Jone's ship in the Pirates of the Carribean movies, the souls dissolved into the Wall, losing all sense of self, all will. They ceased to be.

 

Unless one is a cleric, paladin, druid, or some other cleric derivative, outward religious observation is not necessary. It is enough to claim a god. Most people in Faerun venerate all gods, in some way or another. Even clerics might say a prayer to Auril, if they had to go up into the Spine of the World, for example, or they might make a special offering to Chauntea if a farmer friend needed a good harvest to recover from a setback, or they might appeal to Ilmater if they were suffering, or to Tyr if they were being treated unfairly. They might do all four in the same afternoon, though that would probably involve some pretty unlikely circumstances. In any case, even a cleric doing this would not lose favor with his god. All it takes to avoid godlessness is to claim a god, a patron. Conversely, there is nothing that says a godless person cannot pray. All that means is that they have no patron.

 

When a man dies, his soul goes to the Fugue Plane, governed by Kelemvor. There, like baggage on an airport conveyor belt, it goes around and around until it is claimed by the representative of its patron. Presumably, these avatars know the luggage tags on their gods' own souls. At the end of the shift, all unclaimed bags... er... souls get packed off to the landfill that is the Wall. There, unlike a real landfill, they rot, dissolving into the Wall.

Link to comment

Still thinking on the Valygar thing - first one is up now, though:

 

APPEND ~C-ARANJ~

/* BG2 Friendship Talks */

/* BG2 Friendship Talk 1 */
IF ~Global("c-aranfriendbg2","GLOBAL",1)~ THEN BEGIN c-aranfriendbg2one
 SAY ~[ARAN] Aye, that is strange.~
 ++ ~What is strange?~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",2) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranfriendbg2one1
 + ~Class(Player1,CLERIC_ALL)~ + ~Do you find my choice of god strange, Aran, or are you just randomly commenting on our scenery?~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",2) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranfriendbg2oneclass
 + ~Class(Player1,MAGE_ALL)~ + ~What is strange, Aran - are you concerned about one of my spell components? Is something spilling out, or are you just randomly commenting on our scenery?~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",2) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranfriendbg2oneclass
 + ~Class(Player1,FIGHTER_ALL)~ + ~What, is my gear slipping? What is catching your eye?~  DO ~SetGlobal("c-aranfriendbg2","GLOBAL",2) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranfriendbg2oneclass
 + ~Class(Player1,SORCEROR)~ + ~I am used to be called "strange", Aran, but not usually to my face. Or are you just randomly commenting on our scenery?~  DO ~SetGlobal("c-aranfriendbg2","GLOBAL",2) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranfriendbg2oneclass
 + ~Class(Player1,MONK)~ + ~There is infinite strangeness in all things, Aran. Are we discussing something particular, or  are you just randomly commenting on our scenery?~  DO ~SetGlobal("c-aranfriendbg2","GLOBAL",2) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranfriendbg2oneclass
 + ~Class(Player1,THIEF_ALL)~ + ~What is strange? I have been watching the whole area... or are you just randomly commenting on the universe?~  DO ~SetGlobal("c-aranfriendbg2","GLOBAL",2) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranfriendbg2oneclass
 + ~RandNum(5,1)~ + ~It is not a great time to talk right now, Aran.~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",2) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranshutup1
 + ~RandNum(5,2)~ + ~It is not a great time to talk right now, Aran.~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",2) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranshutup3
 + ~RandNum(5,3)~ + ~It is not a great time to talk right now, Aran.~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",2) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranshutup5
 + ~RandNum(5,4)~ + ~It is not a great time to talk right now, Aran.~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",2) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranshutup7
 + ~RandNum(5,5)~ + ~It is not a great time to talk right now, Aran.~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",2) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranshutup9
END

IF ~~ c-aranfriendbg2oneclass
 SAY ~[ARAN] No, no, nothin' like that. I was just observin' is all. I did notice, though...~
 IF ~~ GOTO c-aranfriendbg2one1
END

END

CHAIN ~C-ARANJ~ c-aranfriendbg2one1
~[ARAN] This is not exactly an ordinary Company, is it.~
== ~CERNDJ~ IF ~InParty("Cernd") InMyArea("Cernd") !StateCheck("Cernd",CD_STATE_NOTVALID)~ THEN ~[CERND] There are no ordinary Companies, only collections of different abilities. Like the snow falling from the sky, there are only individuals.~
== ~EDWINJ~ IF ~InParty("Edwin") InMyArea("Edwin") !StateCheck("Edwin",CD_STATE_NOTVALID)~ THEN ~[EDWIN] The rest of these lackeys are ordinary. But you are correct. With my presence, this group becomes extraordinary.~ 
== ~JAHEIRAJ~ IF ~InParty("Jaheira") InMyArea("Jaheira") !StateCheck("Jaheira",CD_STATE_NOTVALID)~ THEN ~[JAHEIRA]  What do you think is 'ordinary'?~
== ~MINSCJ~ IF ~InParty("Minsc") InMyArea("Minsc") !StateCheck("Minsc",CD_STATE_NOTVALID)~ THEN ~[MINSC]  We are not ordinary! We have Boo!~ 
== ~VICONIJ~ IF ~InParty("Viconia") InMyArea("Viconia") !StateCheck("Viconia",CD_STATE_NOTVALID)~ THEN ~[VICONIA] If you have a difficulty with my presence, jaluk, spit it out.~ 
== ~C-ARANJ~ IF ~InParty("Viconia") InMyArea("Viconia") !StateCheck("Viconia",CD_STATE_NOTVALID)~ THEN ~[ARAN] Hey, drowess, I was talkin' to <CHARNAME>. I can work with most anybody. Though this is the first time I have seen your kind on this side of the shield wall, so to speak.~
== ~YOSHJ~ IF ~InParty("Yoshimo") InMyArea("Yoshimo") !StateCheck("Yoshimo",CD_STATE_NOTVALID)~ THEN ~[YOSHIMO] Indeed, what do you consider ordinary, my friend?~
== ~C-ARANJ~ ~[ARAN] An 'ordinary' Adventurin' Company is close to a Merchant's Guild Fist. Sword, Knife, Stave, Wand, and Pen, all working together. And they don't usually carry such powerful gear.~
END
++ ~Well, that's colorful. Some definitions? Because I really didn't understand you.~ EXTERN ~C-ARANJ~ c-aranF1understand
++ ~No, this is not an ordinary group. But you will fit in fine, I am sure.~ EXTERN ~C-ARANJ~ c-aranF1fitin
++ ~Curiousity killed the cat. Keep your comments to yourself, Aran.~ EXTERN ~C-ARANJ~ c-aranshutup15

APPEND ~C-ARANJ~

IF ~~ c-aranF1understand
 SAY ~[ARAN] Sorry. Tradespeak. What do you want to know?~
 + ~Global("c-aranSword","GLOBAL",0)~ + ~What is a 'sword', the way you used the word?~ DO ~SetGlobal("c-aranSword","GLOBAL",1)~ + c-aranF1sword
 + ~Global("c-aranKnife","GLOBAL",0)~ + ~What is a 'knife', the way you used the word?~ DO ~SetGlobal("c-aranKnife","GLOBAL",1)~ + c-aranF1knife
 + ~Global("c-aranStave","GLOBAL",0)~ + ~What is a 'stave', the way you used the word?~ DO ~SetGlobal("c-aranStave","GLOBAL",1)~ + c-aranF1stave
 + ~Global("c-aranWand","GLOBAL",0)~ + ~What is a 'wand' the way you used the word?~ DO ~SetGlobal("c-aranWand","GLOBAL",1)~ + c-aranF1wand
 + ~Global("c-aranPen","GLOBAL",0)~ + ~What is a 'pen', the way you used the word?~ DO ~SetGlobal("c-aranPen","GLOBAL",1)~ + c-aranF1pen
 + ~Global("c-aranFist","GLOBAL",0)~ + ~What is a 'fist', the way you used the word?~ DO ~SetGlobal("c-aranFist","GLOBAL",1)~ + c-aranF1fist
 ++ ~You know, I don't think I want to talk on and on about this. I'll figure it out as we go.~ + c-aranF1gettingout
 ++ ~Got it. I have enough information to figure out what you are saying.~ + c-aranF1gettingout
END

IF ~~~ c-aranF1middle
 SAY ~[ARAN] Anythin' else you want to clear up? Gotta know the folks you are fightin' along side, to be safe.~
 ++ ~Yes. I still don't quite get all the terms you just used. I want to ask about another one.~ + c-aranF1understand
 + ~Gender(Player1,MALE)~ + ~Do you always start conversations this way? I would think that you were more of the tall, dark, handsome, and silent type.~ + c-aranF1malecute
 + ~Gender(Player1,FEMALE)~ + ~Do you always start conversations this way? I would think that you were more of the tall, dark, handsome, and silent type.~ + c-aranF1femalecute
 ++ ~It seems like you talk alot.~ + c-aranF1gettingout
END

IF ~~ c-aranF1gettingout
 SAY ~[ARAN] Got it. I've a bit o' a habit o' ramblin' on an' on, you know. Sorry. Fills time, it does.~
 + ~Gender(Player1,MALE)~ + ~I prefer less talk and more action, Aran.~ + c-aranF1malecute
 + ~Gender(Player1,MALE)~ + ~Do you always start conversations this way? I would think that you were more of the tall, dark, handsome, and silent type.~ + c-aranF1malecute
 + ~Gender(Player1,FEMALE)~ + ~I prefer less talk and more action, Aran.~ + c-aranF1femalecute
 + ~Gender(Player1,FEMALE)~ + ~Do you always start conversations this way? I would think that you were more of the tall, dark, handsome, and silent type.~ + c-aranF1femalecute
END

IF ~~ c-aranF1fitin
 SAY ~[ARAN] Well, I never did have no trouble before. 'Cept one time. I don't rightly hold with slavery. That one's a deal-breaker. Just thought I oughta let you know.~
 ++ ~I didn't quite get all the terms you just used. I want to ask about... what was it? Pen? Sword, Knife? Something like that?~ + c-aranF1understand  
 + ~Gender(Player1,MALE)~ + ~I preferless talk and more action, Aran.~ + c-aranF1malecute
 + ~Gender(Player1,MALE)~ + ~Do you always start conversations this way? I would think that you were more of the tall, dark, handsome, and silent type.~ + c-aranF1malecute
 + ~Gender(Player1,FEMALE)~ + ~I preferless talk and more action, Aran.~ + c-aranF1femalecute
 + ~Gender(Player1,FEMALE)~ + ~Do you always start conversations this way? I would think that you were more of the tall, dark, handsome, and silent type.~ + c-aranF1femalecute
END

IF ~~ c-aranF1malecute
 SAY ~[ARAN] Well, I like to break up the boredom a bit. But I'm no bard. An' just so's we are on the same page, <CHARNAME>, you are right good lookin', but I prefer the ladies.~
 ++ ~Well, perhaps I can change your mind about that.~ EXIT
 ++ ~Fair enough. So the 'look but don't touch' rule applies.~ EXIT
 ++ ~You used some terms back there I didn't get. Some definitions? Because I really didn't understand you.~ + c-aranF1understand
 ++ ~A pity. But then again, it really isn't a choice type of thing, is it. At least we can hit the bars together and not be poaching eachother's territory.~ EXIT
 ++ ~You are a bit full of yourself, aren't you?~ + c-aranshutup19
 ++ ~Watch it, sellsword - you made a big assumption there.~ + c-aranshutup20
END

IF ~~ c-aranF1femalecute
 SAY ~[ARAN] Most times, I keep to myself. And you are not so bad yourself, <CHARNAME>. Kinda easy on the eyes.~
 ++ ~Let's keep the eyes on the road, and the hands away from me, boyo. Don't get ahead of yourself.~ + c-aranF1full
 ++ ~You used some terms back there I didn't get. Some definitions? Because I really didn't understand you.~ + c-aranF1understand
 ++ ~I'm flattered. I think.~ EXIT
 ++ ~You are no so bad yourself.~ EXIT
 ++ ~You are a bit full of yourself, aren't you?~ + c-aranF1full
 ++ ~Keep it professional, Aran. I didn't hire you as eye-candy. And if that was an attempt at flirting, you are on dangerous ground.~ + c-aranF1full
 ++ ~Watch it, sellsword. I have killed men for saying less.~ + c-aranshutup20
END

IF ~~ c-aranF1fist
 SAY ~[ARAN] Well, now, a Fist is what you want when you be "punchin' to Calmport" . You know, travelin' to your next tradin' destination. You want to have all your bases covered, right, on account o' not knowin' what Faerun is goin' to throw at you, or what th' gods are goin' to send your way. So you get all set up wi' all your needs filled - Sword, Knife, Stave, Wand, an' Pen. You miss a finger, an' your Fist is likely as not to end up in a mite bit o' trouble.~
 IF ~~ GOTO c-aranF1middle
END

IF ~~ c-aranF1sword
 SAY ~[ARAN] Fighters, muscle, shield wall, th' whole physical group. What I do. Look for new things, meet 'em, and usually kill 'em.~
 IF ~!Class(Player1,FIGHTER_ALL)~ + ~Ah. I might just fit into that category myself.~ + c-aranF1middle
 IF ~Class(Player1,FIGHTER_ALL)~ GOTO c-aranF1middle
END

IF ~~ c-aranF1knife
 SAY ~[ARAN] Someone to look for traps an' scout ahead. You have to watch Knives, though. Most o' the ones I know are Guild, an' they won't steal from you while on the trail. But in town, a mark's a mark.~
 IF ~!Class(Player1,THIEF_ALL)~ + ~Ah. I might just fit into that category myself.~ + c-aranF1middle
 IF ~Class(Player1,THIEF_ALL)~ GOTO c-aranF1middle
END

IF ~~ c-aranF1stave
 SAY ~[ARAN] Clerics, healers, do-gooders or sometimes do-badders that can back you up an' heal your wounds. I've known some right good ones in my time, for sure.~
 IF ~!Class(Player1,CLERIC_ALL)~ + ~Ah. I might just fit into that category myself.~ + c-aranF1middle
 IF ~Class(Player1,CLERIC_ALL)~ GOTO c-aranF1middle
END

IF ~~ c-aranF1wand
 SAY ~[ARAN] Spellslingers, casters, magicians, illusionists. The ones Swords have to protect first, last, an' foremost.~
 IF ~!Class(Player1,MAGE_ALL)~ + ~Ah. I might just fit into that category myself.~ + c-aranF1middle
 IF ~Class(Player1,MAGE_ALL)~ GOTO c-aranF1middle
END

IF ~~ c-aranF1pen
 SAY ~[ARAN] Scribes, to write up the contracts, do the accounts, run the numbers, keep track o' things. I do that, too. Makes me useful, as I cover two positions on the Coster expeditions; three if you count wagon driver.~
 IF ~~ THEN GOTO c-aranF1middle
END

IF ~~ c-aranF1full
 SAY ~[ARAN] (flushes burgundy) Aye, then. Didn't mean to be so forward. Shutting up.~
 IF ~~ THEN EXIT
END

END // of append
Link to comment
/* BG2 FriendTalk 6 c-aranfriendbg2 = 11 */
/* "Alternate Paths to Sun Tsu", or, tactics are fun, but sometimes you just gotta whack 'em. */
IF ~Global("c-aranfriendbg2","GLOBAL",11)~ THEN BEGIN c-aranft6
 SAY ~[ARAN] You ever study tactics an' such?~
 ++ ~[PC] Yes, I have. Is there something wrong with what I am doing in combat?~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",12) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranft6.1
 ++ ~[PC] No, I have never studied tactics. I am learning as I go along.~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",12) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranft6.2
 + ~RandomNum(3,1)~ + ~[PC] Aran... to borrow one of your colorful phrases, "Cyric's Black Heart, shut the nine hells up".~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",12) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranshutup13
 + ~RandomNum(3,2)~ + ~[PC] Aran... to borrow one of your colorful phrases, "Cyric's Black Heart, shut the nine hells up".~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",12) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranshutup14
 + ~RandomNum(3,3)~ + ~[PC] Aran... to borrow one of your colorful phrases, "Cyric's Black Heart, shut the nine hells up".~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",12) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranshutup15
 ++ ~[PC] Why study, when I have you to stand in front of me and act as a meat shield?~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",12) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranft6.3
 ++ ~[PC] Tactics and strategy, planning and plotting... all useless. I just dive into each fight and see if we survive.~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",12) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranft6.2
END

IF ~~ c-aranft6.1
 SAY ~[ARAN] Why, no, not that I have seen. It's just interestin' to ask, is all. I have done a mite o' readin' myself. An' then there's always battle orders to scribe. Those teach a thing or two, sometimes by example, an' sometimes as one o' those "how to get everyone killed" examples.~
 ++ ~[PC] You plan before a fight?~ + c-aranft6.4
 ++ ~[PC] I do not find it easy to plan before combat.~ + c-aranft6.5
 ++ ~[PC] So you have studied all of this?~ + c-aranft6.6
 ++ ~[PC] I plan carefully, but even the best plan needs flexibility.~ + c-aranft6.5
 ++ ~[PC] No plan survives contact with the enemy.~ + c-aranft6.6
END

IF ~~ c-aranft6.2
 SAY ~[ARAN] Well, to each <PRO_HISHER> own, I suppose. But me, I prefer some kind o' plan.~
 ++ ~[PC] You plan before a fight?~ + c-aranft6.4
 ++ ~[PC] I do not find it easy to plan before combat.~ + c-aranft6.5
 ++ ~[PC] So you have studied all of this?~ + c-aranft6.6
 ++ ~[PC] I plan carefully, but even the best plan needs flexibility.~ + c-aranft6.5
 ++ ~[PC] No plan survives contact with the enemy.~ + c-aranft6.6
END

IF ~~ c-aranft6.3
 SAY ~[ARAN] Sure thing. I stand in as a shield, you do whatever it is you do, an' the opponent falls afore us. I'd like to think I was more'n a livin' shield, though.~
 IF ~~ THEN GOTO c-aranft6.5
END

IF ~~ c-aranft6.4
 SAY ~[ARAN] I do a full check o' gear, an' then I lay down a quick set o' ideas in my head. I used to follow a real solid order, you know, back when I was just a sellsword. I'd check th' other fighters, an' guess thier style. Then I'd go through th' priority order...~
 = ~[ARAN] Block attacks on the magic types, Check. Protect the healers, Check. Follow th' most disciplined warrior's lead and orders, Check. Relax my arms, Check. Keep silent, Check. Kill things... Well, then I'd just wait for th' "check".~
 ++ ~[PC] That sounds a little too predictable.~ + c-aranft6.5
 ++ ~[PC] So you have studied all of this?~ + c-aranft6.6
 ++ ~[PC] I plan carefully, but even the best plan needs flexibility.~ + c-aranft6.5
 ++ ~[PC] No plan survives contact with the enemy.~ + c-aranft6.6
END

CHAIN ~c-aranj~ c-aranft6.5
~[ARAN] Look, combat is right easy to work through. You have to know your opponent, an' make plans quick, but it gets to be a habit. Say I'm workin' wi' an elven ranger, a wizard, an' a  light-fingered halfling. The elven ranger can probably fight and cast, and she is likely used to working solo, so give her room to move. The wizard has spells what probably can hurt both friend an' foe alike, so get to a position to cover him from arrows but stay out from between him and whatever he is looking at, or you are serious toast, crisped to a fault, m'boy. The halfling rogue is goin' to play hide an' seek, so that side is uncovered - play along, an' don't protect that side, an' probably some foll will take h' bait an' open up to a quick backstab.~
== ~BAERIE~ IF ~InParty("Aerie") InMyArea("Aerie") !StateCheck("Aerie",CD_STATE_NOTVALID)~ THEN ~[AERIE]  I had little enough time to study such things. Among the Avariel, the warriors handled protecting us all. And at the Circus, Uncle Quayle taught me how to survive, not how to plan a fight.~ 
== ~BANOMEN~ IF ~InParty("Anomen") InMyArea("Anomen") !StateCheck("Anomen",CD_STATE_NOTVALID)~ THEN ~[ANOMEN]  The studies of tactics are important to those seeking knighthood and service. I doubt many sellswords think beyond their next meal.~ 
== ~BCERND~ IF ~InParty("Cernd") InMyArea("Cernd") !StateCheck("Cernd",CD_STATE_NOTVALID)~ THEN ~[CERND] Nature provides both instinct and agression for self protection, and often allows intellect for planning. Not for gibberlings and some other swarming creactures, but for much of nature.~ 
== ~BEDWIN~ IF ~InParty("Edwin") InMyArea("Edwin") !StateCheck("Edwin",CD_STATE_NOTVALID)~ THEN ~[EDWIN]  The most efficient tactic is to place you between the enemy and the more intelligent members of the party. (The simian may need to be prompted to recognise my superior intellect. He shows little sign of independent thought.)~ 
== ~BJAHEIR~ IF ~InParty("Jaheira") InMyArea("Jaheira") !StateCheck("Jaheira",CD_STATE_NOTVALID)~ THEN ~[JAHEIRA] Sometimes habits of thoght are useful. I find that messy thoughts end up in messy actions. Aran, straighten your legging, it is catching on the ground again.~ 
== ~BKELDOR~ IF ~InParty("Keldorn") InMyArea("Keldorn") !StateCheck("Keldorn",CD_STATE_NOTVALID)~ THEN ~[KELDORN] I am afraid that experience shows there is need for more flexibility. Having a plan is important, but how you react canot become instinctive, or your enemy will use your own predictability against you.~ 
== ~BKORGAN~ IF ~InParty("Korgan") InMyArea("Korgan") !StateCheck("Korgan",CD_STATE_NOTVALID)~ THEN ~[KORGAN] You think too much.~ 
== ~BVALYGA~ IF ~InParty("Valygar") InMyArea("Valygar") !StateCheck("Valygar",CD_STATE_NOTVALID)~ THEN ~[VALYGAR] I prefer to observe first, then decide on the correct course of action.~
== ~BVICONI~ IF ~InParty("Viconia") InMyArea("Viconia") !StateCheck("Viconia",CD_STATE_NOTVALID)~ THEN ~[VICONIA] With such simplistic strategies, I am suprised you have surived so long, riivil.~ 
== ~BYOSHIM~ IF ~InParty("Yoshimo") InMyArea("Yoshimo") !StateCheck("Yoshimo",CD_STATE_NOTVALID)~ THEN ~[YOSHIMO] There are many different ways of preparing, it seems. In my homeland, lightweight armour and well-crafted katanas blend with magic. Here the armour is often heavier, and I have even seen what you would call "twin swords" style put to use. Each require different methods for use.~ 
== ~C-ARANJ~ IF ~OR(3) Class("c-aran",CLERIC_ALL) Class("c-aran",MAGE_ALL) Class("c-aran",SORCEROR) OR(3) Class(Player1,CLERIC_ALL) Class(Player1,MAGE_ALL) Class(Player1,SORCEROR)~ THEN ~[ARAN] Now, <CHARNAME>, you an' I both know there's a mite o' help to be had wi' our spells, castin' wards an' blastin' things apart. But I did find one thing that trumps most o' that, taught in some o' the far reaches o' Faerun.~
== ~C-ARANJ~ IF ~!Class("c-aran",CLERIC_ALL) !Class("c-aran",MAGE_ALL) !Class("c-aran",SORCEROR) !Class(Player1,CLERIC_ALL) !Class(Player1,MAGE_ALL) !Class(Player1,SORCEROR)~ [ARAN] Now, <CHARNAME>, you an' I both know there's a mite o' help to be had wi' support from mages an' clerics added to us, castin' wards an' blastin' things apart. But I did find one thing that trumps most o' that, taught in some o' the far reaches o' Faerun.~
END
++ ~[PC] What is that?~ + c-aranft6.8
++ ~[PC] Go on.~ + c-aranft6.8
++ ~[PC] I don't think I want to know.~ + c-aranft6.7


CHAIN ~~ c-aranft6.6
~[ARAN] Well there's all sorts o' fancy tactical writin's an' trainin' to be had, an' there's plenty o' different ideas on what counters what.~
== ~BAERIE~ IF ~InParty("Aerie") InMyArea("Aerie") !StateCheck("Aerie",CD_STATE_NOTVALID)~ THEN ~[AERIE]  I had little enough time to study such things. Among the Avariel, the warriors handled protecting us all. And at the Circus, Uncle Quayle taught me how to survive, not how to plan a fight.~ 
== ~BANOMEN~ IF ~InParty("Anomen") InMyArea("Anomen") !StateCheck("Anomen",CD_STATE_NOTVALID)~ THEN ~[ANOMEN]  The studies of tactics are important to those seeking knighthood and service. I doubt many sellswords think beyond their next meal.~ 
== ~BCERND~ IF ~InParty("Cernd") InMyArea("Cernd") !StateCheck("Cernd",CD_STATE_NOTVALID)~ THEN ~[CERND] Nature provides both instinct and agression for self protection, and often allows intellect for planning. Not for gibberlings and some other swarming creactures, but for much of nature.~ 
== ~BEDWIN~ IF ~InParty("Edwin") InMyArea("Edwin") !StateCheck("Edwin",CD_STATE_NOTVALID)~ THEN ~[EDWIN]  The most efficient tactic is to place you between the enemy and the more intelligent members of the party. (The simian may need to be prompted to recognise my superior intellect. He shows little sign of independent thought.)~ 
== ~BJAHEIR~ IF ~InParty("Jaheira") InMyArea("Jaheira") !StateCheck("Jaheira",CD_STATE_NOTVALID)~ THEN ~[JAHEIRA] Sometimes habits of thoght are useful. I find that messy thoughts end up in messy actions. Aran, straighten your legging, it is catching on the ground again.~ 
== ~BKELDOR~ IF ~InParty("Keldorn") InMyArea("Keldorn") !StateCheck("Keldorn",CD_STATE_NOTVALID)~ THEN ~[KELDORN] I am afraid that experience shows there is need for more flexibility. Having a plan is important, but how you react canot become instinctive, or your enemy will use your own predictability against you.~ 
== ~BKORGAN~ IF ~InParty("Korgan") InMyArea("Korgan") !StateCheck("Korgan",CD_STATE_NOTVALID)~ THEN ~[KORGAN] You think too much.~ 
== ~BVALYGA~ IF ~InParty("Valygar") InMyArea("Valygar") !StateCheck("Valygar",CD_STATE_NOTVALID)~ THEN ~[VALYGAR] I prefer to observe first, then decide on the correct course of action.~
== ~BVICONI~ IF ~InParty("Viconia") InMyArea("Viconia") !StateCheck("Viconia",CD_STATE_NOTVALID)~ THEN ~[VICONIA] With such simplistic strategies, I am suprised you have surived so long, riivil.~ 
== ~BYOSHIM~ IF ~InParty("Yoshimo") InMyArea("Yoshimo") !StateCheck("Yoshimo",CD_STATE_NOTVALID)~ THEN ~[YOSHIMO] There are many different ways of preparing, it seems. In my homeland, lightweight armour and well-crafted katanas blend with magic. Here the armour is often heavier, and I have even seen what you would call "twin swords" style put to use. Each require different methods for use.~ 
== ~C-ARANJ~ IF ~OR(3) Class("c-aran",CLERIC_ALL) Class("c-aran",MAGE_ALL) Class("c-aran",SORCEROR) OR(3) Class(Player1,CLERIC_ALL) Class(Player1,MAGE_ALL) Class(Player1,SORCEROR)~ THEN ~[ARAN] Now, <CHARNAME>, you an' I both know there's a mite o' help to be had wi' our spells, castin' wards an' blastin' things apart. But I did find one thing that trumps most o' that, taught in some o' the far reaches o' Faerun.~
== ~C-ARANJ~ IF ~!Class("c-aran",CLERIC_ALL) !Class("c-aran",MAGE_ALL) !Class("c-aran",SORCEROR) !Class(Player1,CLERIC_ALL) !Class(Player1,MAGE_ALL) !Class(Player1,SORCEROR)~ [ARAN] Now, <CHARNAME>, you an' I both know there's a mite o' help to be had wi' support from mages an' clerics added to us, castin' wards an' blastin' things apart. But I did find one thing that trumps most o' that, taught in some o' the far reaches o' Faerun.~
END
++ ~[PC] What is that?~ + c-aranft6.8
++ ~[PC] Go on.~ + c-aranft6.8
++ ~[PC] I don't think I want to know.~ + c-aranft6.7

IF ~~ c-aranft6.7
 SAY ~[ARAN] Suit yourself. An' I had a good punchline, an' all. I talk a mite more'n I should, anyhow.~
 IF ~~ THEN EXIT
END

IF ~~ c-aranft6.8
 SAY ~[ARAN] Bugger tactics, get in close, an' just whack th' bastards 'til they stop movin'.~
 IF ~~ THEN EXIT
END

Link to comment

Faculty meetings stink. But at least something got accomplished. Domi, I extended that Valygar faithless talk a little and put in two Faithless PC responses (one with Valygar InParty() and one without) - hope it is strong enough for you :crazyeyes: . Added in FT

 

/* BG2 FriendTalk 8 c-aranfriendbg2 = 15 */
/* "Bhallspawn, Shmallspawn. Meh.", or, Gods and Monsters. */

// a177, a178 are chains

IF ~~ a179
SAY ~[ARAN] I know you are faithful to your god, <CHARNAME>... but I figure a few words in the air won't hurt anythin'.~
++ ~[PC] Don't you ever worry about the gods hearing your talk? Don't you ever expect help or advice or something to come of your call?~ + a187
++ ~[PC] Haphazardly calling random gods is dangerous to your soul. If you do not call on one god, who will claim you from Kelemvor's judgement?~ + a187
++ ~[PC] Without faith, you are nothing. Literally. As in abandoned from the Great Wheel. If you would like, we can pray together, and perhaps it will help you decide.~ + a187
++ ~[PC] I didn't intend that to be a request. I don't want the attention drawn to us.~ + a187
END

IF ~~ a180
SAY ~[ARAN] Helm is a tough god, <CHARNAME>... a fine soldierin' one at that. But there's times where he doesn't quite cover it. I figure a few words in the air won't hurt anythin'. ~
++ ~[PC] You should worry about the gods hearing your talk. Do you not expect help or advice or something to come of your call?~ + a187
++ ~[PC] Haphazardly calling random gods is dangerous to your soul. If you do not call a just and fair god like Helm, who will claim you from Kelemvor's judgement?~ + a187
++ ~[PC] Without faith, you are nothing. Literally. As in abandoned from the Great Wheel. If you would like, we can pray together, and perhaps Helm with bear you up on his shield.~ + a187
++ ~[PC] I didn't intend that to be a request, Aran. I don't want the attention drawn to us.~ + a187
END

IF ~~ a181
SAY ~[ARAN] Lathander is a gentle god, <CHARNAME>... a fine one for new beginnings. And the gods know I need some new beginnings. But there's times where he doesn't quite cover it. I figure a few words in the air won't hurt anythin'.~
++ ~[PC] Don't you ever worry about the gods hearing your talk? Don't you ever expect help or advice or something to come of your call?~ + a187
++ ~[PC] Haphazardly calling random gods is dangerous to your soul. If you do not call a gentle and strong god like Lathander, who will claim you from Kelemvor's judgement?~ + a187
++ ~[PC] Without faith, you are nothing. Literally. As in abandoned from the Great Wheel. If you would like, we can pray together, and perhaps Lathander will grant you a new beginning.~ + a187
++ ~[PC] I didn't intend that to be a request, Aran. I don't want the attention drawn to us.~ + a187
END

IF ~~ a182
SAY ~[ARAN] Talos is a wild god, <CHARNAME>... one for power an' strength. Good to call on in battle. I figure a few words in the air won't hurt anythin'. ~
++ ~[PC] You are a fool to chatter on so. The gods will hear your talk. ~ + a187
++ ~[PC] Haphazardly calling random gods is dangerous to your soul. If you do not call a powerful god like Talos, no god will claim you from Kelemvor's judgement.~ + a187
++ ~[PC] Without faith, you are nothing. Literally. As in abandoned from the Great Wheel. Pray to Talos with me, sellsword. Perhaps you will weather this storm we call 'life.'~ + a187
++ ~[PC] I didn't intend that to be a request, sellsword. I don't want the attention drawn to us.~ + a187
END

IF ~~ a183
SAY ~[ARAN] All you tree huggers do is talk about the balance and such. But you are good folks to watch a friend's back in battle that's for sure. I figure a few words in the air won't hurt the great balance, or whatever. ~
++ ~[PC] Tree hugger, eh? Thanks a lot. Don't you ever worry about the gods hearing your talk? Don't you ever expect help or advice or something to come of your call?~ + a187
++ ~[PC] True balance requires choice, Aran. Haphazardly calling random gods is dangerous to your soul. ~ + a187
++ ~[PC] Without faith in Nature and her balance, you are nothing. Literally. As in abandoned from the Great Wheel. If you would like, we can meditate together, and perhaps you will find some peace.~ + a187
++ ~[PC] I didn't intend that to be a request, sellsword. I don't want the attention drawn to us.~ + a187
END

IF ~~ a184
SAY ~[ARAN] Clerics get all th' attention, far as I can see. Plus, I favor Tymora the most. I figure she would like the gamble.~
IF ~~ THEN GOTO a197
END

IF ~~ a185
SAY ~[ARAN] Look, I don't mean nothin'. No offense to you, but I favor Tymora the most, an' I figure she likes the gamble. She sends me down some powers, so she can't be that angry about it. It's a soldier's perogative to swear, and I may take advantage a bit, but I don't mean you no harm. By the way, you ever considered followin' Tymora?~
+ ~[PC] ReputationLT(Player1,11)~ + ~I might be interested. What does Tymora offer me?~ + a188
+ ~[PC] ReputationGT(Player1,10) ReputationLT(Player1,15)~ + ~I might be interested. What does Tymora offer me?~ + a189
+ ~[PC] ReputationGT(Player1,14)~ + ~I might be interested. What does Tymora offer me?~ + a190
++ ~[PC] Hey, that is getting a little personal. Do not try to sway my soul from its destined path, Aran. ~ + a191
++ ~[PC] I serve my chosen deity for now. My faith in myself will be enough, and perhaps someday I will become a god myself.~ + a192
++ ~[PC] I am not sure if you are ready to hear about my faith.~ + a193
END

IF ~~ a186
 SAY ~[ARAN] Either you be jokin', or you be th' scariest <PRO_MANWOMAN> I ever did meet, <CHARNAME>. Messin' with those forces is like stickin' your head down a firedrake's throuat an' ticklin' him.~
 IF ~~ THEN EXIT
END

IF ~~ a187
SAY ~[ARAN] Look, I don't mean nothin'. I have faith in the gods. No offense, but I favor Tymora the most, an' I figure she would like the gamble. It's a soldier's perogative to swear, and I may take advantage a bit, but I don't mean you no harm. But I have to ask, why do you choose service your god? Seems like all they do is play with us mortals like toys. ~
++ ~[PC] I serve my chosen deity as I have always done. My faith grants me the ability to help others see the true path...~ + a194
++ ~[PC] I serve my chosen deity as I have always done. My faith grants me discipline and control over myself.~ + a195
++ ~[PC] I serve my chosen deity as I have always done. My faith grants me dominion over others and glories in my eventual rise to master of all.~ + a192
++ ~[PC] I serve my chosen deity as I have always done. My faith grants me great power.~ + a196
++ ~[PC] I serve my chosen deity for now. My faith in myself will be enough someday, and perhaps I will become a god.~ + a192
++ ~[PC] I am not sure if you are ready to hear about my faith.~ + a193
END

IF ~~ a188
SAY ~[ARAN] You are playin' wi' me now, <CHARNAME>. Tymora might offer somethin', but she judges by actions. Right now, looks like you don't give decent odds on her investment. You'd have to clean up the way you are goin' and move more towards bright gold rather than deep shadow. But, if you ever do move in that direction, I'm right here to help out a bit.~
IF ~~ THEN GOTO a197
END

IF ~~ a189
SAY ~[ARAN] Well, she can offer some decent odds on fair gambles, <CHARNAME>. IF you are really interested, then it might be a good move for you. She don't hold with extremes, except for takin' risks. You seem like th' sort to take a risk now an' then. Hey, you brought me along - that counts double!~
IF ~~ THEN GOTO a197
END

IF ~~ a190
SAY ~[ARAN] Well now, Tymora does like a good bet, an' you have the 'good' part down, at least as far as your actions are speakin'. She don't hold with extremes, though, except for takin' risks. So, come talk sometime.~
IF ~~ THEN GOTO a197
END

IF ~~ a191
SAY ~[ARAN] Aye, I did jump too quick now, didn't I. I guess I have a bit to learn about the whole preachin' thing. I didn't mean nothin'.~
IF ~~ THEN GOTO a197
END

IF ~~ a192
SAY ~[ARAN] Tymora's Coin, and I thought *I* was the one with th' loose lacing.~
IF ~~ THEN GOTO a197
END

IF ~~ a193
SAY ~[ARAN] Fair enough. There's always other times to speak on this kind o' thing.~
IF ~~ THEN GOTO a197
END

IF ~~ a194
SAY ~[ARAN] Tymora's Coin, that is a fine idea. I like helpin' folks. Just I get the idea most clerics think that involves changin' gods.~
IF ~~ THEN GOTO a197
END

IF ~~ a195
SAY ~[ARAN] Tymora's Coin, that is a strange proposition. I prefer to let things hang out a bit. More fun that way.~
IF ~~ THEN GOTO a197
END

IF ~~ a196
SAY ~[ARAN] Tymora's Coin, you better be careful. Seems to me gods have a tendency to give folks power and just to see if they have the sense not to use it.~
IF ~~ THEN GOTO a197
END

IF ~~ a197
SAY ~[ARAN] Besides, I am all done up. Give me a hand up, eh? We better get movin'.~
IF ~~ THEN EXIT
END

END // of APPEND

/* ft8 chains */

CHAIN IF ~Global("c-aranfriendbg2","GLOBAL",15)~ THEN ~C-ARANJ~ a177
~[ARAN] Tempus' Toasty Toes, that tears it. That be the last time I get leatherwork done cut rate. This blighted bootlace is breakin'. Anyone got a spare?~
DO ~SetGlobal("c-aranfriendbg2","GLOBAL",16) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~
== ~JAHEIRAJ~ IF ~InParty("Jaheira") InMyArea("Jaheira") !StateCheck("Jaheira",CD_STATE_NOTVALID)~ THEN ~[JAHEIRA] You should be better prepared. Think ahead next time, Aran.~
== ~AERIEJ~ IF ~InParty("Aerie") InMyArea("Aerie") !StateCheck("Aerie",CD_STATE_NOTVALID)~ THEN ~[AERIE] I - I'm sorry, I don't have anything extra.~
== ~KORGANJ~ IF ~InParty("Korgan") InMyArea("Korgan") !StateCheck("Korgan",CD_STATE_NOTVALID)~ THEN ~[KORGAN] It will cost you a trade bar.~
== ~EDWINJ~ IF ~InParty("Edwin") InMyArea("Edwin") !StateCheck("Edwin",CD_STATE_NOTVALID)~ THEN ~[EDWIN] (Idiot.) Perhaps we would move faster if you held still while I carved a new one from your hide.~
== ~MINSCJ~ IF ~InParty("Minsc") InMyArea("Minsc") !StateCheck("Minsc",CD_STATE_NOTVALID)~ THEN ~[MINSC] Here, Aran, I have a bootlace!~
== ~C-ARANJ~ IF ~InParty("Minsc") InMyArea("Minsc") !StateCheck("Minsc",CD_STATE_NOTVALID)~ THEN ~[ARAN] By the fire giant's gods, whomever they are... Minsc, you are a big, big boy. Thanks. I'll take a third o' that length.~
== ~CERNDJ~ IF ~InParty("Cernd") InMyArea("Cernd") !StateCheck("Cernd",CD_STATE_NOTVALID)~ THEN ~[CERND] You do not need leather to bind that. Nature provides many alternatives with similar strength, and the avoidance of killing an animal.~
== ~C-ARANJ~ IF ~InParty("Cernd") InMyArea("Cernd") !StateCheck("Cernd",CD_STATE_NOTVALID)~ THEN ~[ARAN] Mystra's Magnificent Mouth, Cernd... given the choice between my feet in battle an' the animal, I am considerin' the animal a distant second.~
END
+ ~!Class(Player1,CLERIC_ALL)~ + ~[PC] For the god's sake, slow down with the swearing, will you?~ EXTERN ~C-ARANJ~ a178
+ ~OR(2) Class(Player1,PALADIN) Class(Player1,CLERIC_ALL) !Kit(Player1,GODTALOS) !Kit(Player1,GODHELM) !Kit(Player1,GODLATHANDER)~ EXTERN ~C-ARANJ~ ~[PC] Why are you blaspheming over something so minor, Aran?~ + a179
+ ~Class(Player1,CLERIC_ALL) Kit(Player1,GODHELM)~ + ~[PC] Here. But why are you blaspheming over something so minor, Aran?~ EXTERN ~C-ARANJ~ a180
+ ~Class(Player1,CLERIC_ALL) Kit(Player1,GODLATHANDER)~ + ~[PC] Here. But why are you blaspheming over something so minor, Aran?~ EXTERN ~C-ARANJ~ a181
+ ~Class(Player1,CLERIC_ALL) Kit(Player1,GODTALOS)~ + ~[PC] Here. But why are you blaspheming over something so minor, Aran?~ EXTERN ~C-ARANJ~ a182
+ ~OR(2) Class(Player1,RANGER) Class(Player1,DRUID)~ + ~[PC] Here. But why are you blaspheming over something so minor, Aran?~ EXTERN ~C-ARANJ~ a183
++ ~[PC] You take every opportunity to swear, don't you, Aran.~ EXTERN ~C-ARANJ~ a178
++ ~[PC] Alright, move along, everyone. The sellsword is having troubles again. Catch up fast, Aran.~ EXTERN ~C-ARANJ~ c-aranshutup1

CHAIN ~C-ARANJ~ a178
~[ARAN] Three things you shouldn't take from a man, <CHARNAME>... his swearin', his drink, and his weapon.~
== ~HAERDAJ~ IF ~InParty("HaerDalis") InMyArea("HaerDalis") !StateCheck("HaerDalis",CD_STATE_NOTVALID)~ THEN ~[HAERDALIS] Ah, fair fledgeling, I think you should simply say 'his voice'. And of course, no man or woman should ever lose that. ~
== ~KELDORJ~ IF ~InParty("Keldorn") InMyArea("Keldorn") !StateCheck("Keldorn",CD_STATE_NOTVALID)~ THEN ~[KELDORN] Invoking the gods is a natural stress release, Aran. But as you grow more powerful, the gods tend to listen more closely. They may take exception to having their name used so freely.~
== ~MAZZYJ~ IF ~InParty("Mazzy") InMyArea("Mazzy") !StateCheck("Mazzy",CD_STATE_NOTVALID)~ THEN ~[MAZZY] My mother often told me that swearing was not to be taken lightly, for it speaks to your soul as well as the gods.~
== ~NALIAJ~ IF ~InParty("Nalia") InMyArea("Nalia") !StateCheck("Nalia",CD_STATE_NOTVALID)~ THEN ~[NALIA] Swearing is both vulgar and common. A gentleman does not use such language.~
== ~C-ARANJ~ IF ~InParty("Nalia") InMyArea("Nalia") !StateCheck("Nalia",CD_STATE_NOTVALID)~ THEN ~[ARAN] I thought you were into helpin' th' 'common man', there, Nalia. I never claimed to be no gentleman.~
== ~NALIAJ~ IF ~InParty("Nalia") InMyArea("Nalia") !StateCheck("Nalia",CD_STATE_NOTVALID)~ THEN ~[NALIA] Teaching the commoners respect for the gods goes along with teaching respect for themselves, Aran.~
== ~VICONIJ~ IF ~InParty("Viconia") InMyArea("Viconia") !StateCheck("Viconia",CD_STATE_NOTVALID)~ THEN ~[VICONIA] Speak your words loudly, sellsword. I want to see your face just before an Avatar destroys you.~
== ~ANOMENJ~ IF ~InParty("Anomen") InMyArea("Anomen") !StateCheck("Anomen",CD_STATE_NOTVALID)~ THEN ~[ANOMEN] Your language offends me. Then again, your presence in general offends me.~
== ~C-ARANJ~ IF ~InParty("Anomen") InMyArea("Anomen") !StateCheck("Anomen",CD_STATE_NOTVALID)~ THEN ~[ARAN] Bugger off, jackass. Come talk wi' me when you got somethin' more than the foul smell o' breakin' wind from your mouth.~
== ~KORGANJ~ IF ~InParty("Korgan") InMyArea("Korgan") !StateCheck("Korgan",CD_STATE_NOTVALID)~ THEN ~[KORGAN] Let the sorry bastard say his piece.~
END
++ ~[PC] Don't you ever worry about the gods hearing your talk? Don't you ever expect help or advice or something to come of your call?~ EXTERN ~C-ARANJ~ a184
++ ~[PC] Hey, it is your business if you go around haphazardly calling random gods. But when one answers, you had better be prepared for the surprise.~ EXTERN ~C-ARANJ~ a184
++ ~[PC] Without faith, you are nothing. ~ EXTERN ~C-ARANJ~ a184
+ ~Class("c-aran",CLERIC_ALL)~ + ~[PC] I thought you were a cleric, Aran. That should mean you only swear by your own god.~ EXTERN ~C-ARANJ~ a185
++ ~[PC] I didn't intend that to be a request. I don't want the attention drawn to us.~ EXTERN ~C-ARANJ~ a184
+ ~!Class("c-aran",CLERIC_ALL)~ + ~[PC] I am not taking any of those, Aran. Just settle down and choose one god or goddess, will you?~ EXTERN ~C-ARANJ~ a184
++ ~[PC] I was speaking of being less socially awkward. The theology does not interest me. There are no gods, just very powerful beings that demand worship and followers.~ EXTERN ~C-ARANJ~ a186
IF ~InParty("Valygar") InMyArea("Valygar") !StateCheck("Valygar",CD_STATE_NOTVALID)~ THEN EXTERN ~VALYGARJ~ c-aranvalywall

CHAIN ~VALYGARJ~ c-aranvalywall
~[VALYGAR] Why not risk the gods wrath? Their love or their displeasure amounts to the same thing.~
== ~C-ARANJ~ ~[ARAN] Aye, now, you can't rightly believe that, Valygar.~
== ~VALYGARJ~ ~[VALYGAR] I most certainly do. Praise them or curse them, praise by them and curse through them, it matters not.~
== ~C-ARANJ~ ~[ARAN] That is too far for my blood, friend. I claim Tymora as my favorite from time to time, an' swear usin' some other on other days, to be sure. But no faith in the gods is askin' for trouble I want no part of.~
== ~VALYGARJ~ ~[VALYGAR] I think it would be better to not discuss my feelings on the 'gods', and the damage done by believers everywhere.~
== ~C-ARANJ~ ~[ARAN] Aye, true enough. Didn't mean to offend you, now. It be right true that discussin' politics or religion is like standin' in the middle o' Athalka's Promenade an' practicin' magic without a license. Bound to attract trouble, eh?~
END
++ ~[PC] Don't you ever worry about the gods hearing your talk? Don't you ever expect help or advice or something to come of your call?~ EXTERN ~C-ARANJ~ a184
++ ~[PC] Hey, it is your business if you go around haphazardly calling random gods. But when one answers, you had better be prepared for the surprise.~ EXTERN ~C-ARANJ~ a184
++ ~[PC] Without faith, you are nothing. ~ EXTERN ~C-ARANJ~ a184
+ ~Class("c-aran",CLERIC_ALL)~ + ~[PC] I thought you were a cleric, Aran. That should mean you only swear by your own god.~ EXTERN ~C-ARANJ~ a185
++ ~[PC] I didn't intend that to be a request. I don't want the attention drawn to us.~ EXTERN ~C-ARANJ~ a184
+ ~!Class("c-aran",CLERIC_ALL)~ + ~[PC] I am not taking any of those, Aran. Just settle down and choose one god or goddess, will you?~ EXTERN ~C-ARANJ~ a184
++ ~[PC] True enough, Valygar. There are no gods, just very powerful beings that demand worship and followers.~ EXTERN ~C-ARANJ~ a186

 

and a new one, 7:

 

/* BG2 FriendTalk 7 c-aranfriendbg2 = 13 */
/* "Warning - Objects Are Closer Than They Appear", or, why you want to check carefully behind your target area before firing that arrow. */

IF ~Global("c-aranfriendbg2","GLOBAL",13)~ THEN BEGIN a161
 SAY ~[ARAN] There be a mite o' difference between chasin' around Faerun in pursuit o' treasure, fame, an' such, an' chasin' around Faerun close on th' tail o' adversaries what can call on th' powers this 'Irenicus' bastard can.~
 ++ ~[PC] Are you in this for fame, fortune, and riches beyond your wildest imagination?~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",14) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + a162
 + ~RandomNum(3,1)~ + ~[PC] You talk too much.~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",14) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranshutup16
 + ~RandomNum(3,2)~ + ~[PC] You talk too much.~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",14) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranshutup17
 + ~RandomNum(3,3)~ + ~[PC] You talk too much.~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",14) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranshutup18
 ++ ~[PC] Irenicus is a means to an end. To be more precise and borrow your quaint speech patterns, I means to end him.~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",14) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + a163
 ++ ~[PC] I do not have much choice in the matter.~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",14) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + a164
END

IF ~~ a162
 SAY ~[ARAN] I don't rightly know. I can imagine a pretty big amount o' treasure.~
 ++ ~[PC] Do you want me to accept your answer at face value and pretend that amuses me, or do you want me to explain why that makes you shallow and ugly?~ + a165
 ++ ~[PC] I have no problems with you chasing fame and fortune, but I am not doing all this for such rewards.~ + a166
 ++ ~[PC] Nothing compared to what I can imagine. Do not worry, Aran. When I rule the known world, I will make sure to name a small hamlet or village in your honor.~ + a167
 ++ ~[PC] Somehow I think your idea of treasure and mine differ. Your definition might include fine parchament, young redheaded half-elven girls, massive storehouses of alcohol, and warm baths.~ + a176
END

IF ~~ a163
 SAY ~[ARAN] Well, it seems like you be pretty serious about all that. I just think you ought to check your target right careful, an' see what's behind it.~
 ++ ~[PC] I do not understand. Why would I want to do that, when my focus should be centered on Irenicus?~ + a169
 ++ ~[PC] Serious? If I were serious, I would have told you about three miles back that your codpiece is not tied correctly, and you have been showing off the family jewels to all and sundry.~ + 168
 ++ ~[PC] You seem to be saying we should slow down, and wait for Irenicus, allowing him to prepare defenses and even send agents after us. That seems like you have a sincere wish for death.~ + 175 
END

IF ~~ a164
 SAY ~[ARAN] Bollux. That be a right heavy load o' crap. You are a powerful individual, <CHARNAME>. You could drop this whole thing, an' head somewhere else. Perhaps even set yourself up a stronghold someplace nice. I could even get together some lads an' lasses what can fight right proper, an' we could carve out a safe refuge from th' world.~
 ++ ~[PC] Using a sharp tongue with me does not mean you have a keen mind, Aran. What happens if you leave a powerful adversary unchallenged?~ + a171
 ++ ~[PC] What a good idea! Aran, you are a genius. I have an even better idea. Why don't we go ask Irenicus if he would like to drop by for tea, and mend our differences over a nice set of sandwiches. Then he could reform and be on our side, and we could go knit sweaters for destitute halfling children in Neverwinter together!~ + a168
 ++ ~[PC] That would be expedient, not right.~ + a170
 ++ ~[PC] I know what I am doing. You should trust me, and stop talking about things you do not understand.~ + c-aranshutup9
END

IF ~~ a165
 SAY ~[ARAN] Hey, now, that is a mite bit sharp! I was jokin', <CHARNAME>. To be right honest, danger attracts to you like bees to honey, eh? That be excitin'. Gives me a sense o' bein' part o' somethin' big.~
 ++ ~[PC] At least you did not say 'attracts danger like flies to manure'.~ + a171
 ++ ~[PC] I did not ask for this, but I intend to finish it.~ + a169
 ++ ~[PC] I was joking, too. Although if you play your cards right, there could be some fame and fortune to be had. You could be the first person to have a stretch Calimport sewer named after you!~ + a168
 ++ ~[PC] I may not know exactly what I am doing, but you should trust me.~ + c-aranshutup9
 ++ ~[PC] Great. A sellsword with a death wish. Just what I wanted.~ + 175
END

IF ~~ a166
 SAY ~[ARAN] I was jokin', <CHARNAME>. To be right honest, danger attracts to you like bees to honey, eh? That be excitin'. Gives me a sense o' bein' part o' somethin' big.~
 ++ ~[PC] At least you did not say 'attracts danger like flies to manure'.~ + a171
 ++ ~[PC] Then you are a fool. The only things that count in this life are power, wealth, and freedom to do as one wishes. Fame comes when you have enough of the other two.~ + a174
 ++ ~[PC] I did not ask for this, but I intend to finish it.~ + a169
 ++ ~[PC] I was joking, too. Although if you play your cards right, there could be some fame and fortune to be had. You could be the first person to have a stretch Calimport sewer named after you!~ + a168
 ++ ~[PC] I may not know exactly what I am doing, but you should trust me.~ + c-aranshutup9
END

IF ~~ a167
 SAY ~[ARAN] Well now, that be right kind o' you. I will be keepin' my eyes open for a village o' redheaded young lasses to retire to, an' you can name it after me. But to be fair, I was jokin', <CHARNAME>. Danger attracts to you like bees to honey, eh? That be excitin'. Gives me a sense o' bein' part o' somethin' big.~
 ++ ~[PC] At least you did not say 'attracts danger like flies to manure'.~ + a171
 ++ ~[PC] I did not ask for any of this, Aran. But I intend to finish it.~ + a169
 ++ ~[PC] Then you are a fool. The only things that count in this life are power, wealth, and freedom to do as one wishes. Fame comes when you have enough of the other two.~ + a174
 ++ ~[PC] I was joking, too. Although if you play your cards right, there could be some fame and fortune to be had. You could be the first person to have a stretch Calimport sewer named after you!~ + a168
END

IF ~~ a168
 SAY ~[ARAN] Funny. Right funny, there. You should look into gettin' a job tellin' jokes at th' Low Lantern. I bet you could make it work, if you stripped down to almost bare nekkid.~
 IF ~~ THEN EXIT
END

IF ~~ a169
 SAY ~[ARAN] When you pick a target as nasty as that slippery bastard, you might get an edge up if you look at th' whole target, not just what you are aimin' at, an' try to get ahead o' his game. Chasin' him around so he can lead you where he wants you be poor strategy.~
 ++ ~[PC] I know what I am doing. You should trust me, and stop talking about things you do not understand.~ + c-aranshutup9
 ++ ~[PC] You have a point. But for now, I do not see any alternatives. We are forced to play his game under his rules.~ + a172
 ++ ~[PC] You have a point. Do you have some specific suggestions?~ + a173
 ++ ~[PC] I may not know exactly what I am doing, but you should trust me.~ + c-aranshutup9
END

IF ~~ a170
 SAY ~[ARAN] An' you be bound an' determined to do what be right, come dragons or demons, eh? I figured as much. I think when you be pickin' a target as nasty as that slippery bastard, you might get an edge up if you look at th' whole target, not just what you are aimin' at, an' try to get ahead o' his game. Chasin' him around so he can lead you where he wants you be poor strategy.~
 ++ ~[PC] You think?~ + a168
 ++ ~[PC] I know what I am doing. You should trust me, and stop talking about things you do not understand.~ + c-aranshutup9
 ++ ~[PC] I may not know exactly what I am doing, but you should trust me.~ + c-aranshutup9
 ++ ~[PC] You have a point. But for now, I do not see any alternatives. We are forced to play his game under his rules.~ + a172
 ++ ~[PC] You have a point. Do you have some specific suggestions?~ + a173
END

IF ~~ a171
 SAY ~[ARAN] I thought about it, but somethin' told me you might not see that as rightly funny, eh? When you pick a target as nasty as that slippery bastard, you might get an edge up if you look at th' whole target, not just what you are aimin' at, an' try to get ahead o' his game. Chasin' him around so he can lead you where he wants you be poor strategy.~
 ++ ~[PC] Hey, I would find it funny. Just as long as I do not end up buried in manure, in over my head.~ EXIT
 ++ ~[PC] Good choice.~ EXIT
 ++ ~[PC] You have a point. But for now, I do not see any alternatives. We are forced to play his game under his rules.~ + a172
 ++ ~[PC] You have a point. Do you have some specific suggestions?~ + a173
END

IF ~~ a172
 SAY ~[ARAN] Last time I got myself into a game like that, me an' Grisa had to toss th' table over, an' fight our way out o' th' inn. We done almost made it, too. Good to be friends wi' a lass with orcish blood at times. If they had stuck to ten to one odds, no worries, but they got smart an' called in th' watch. Cost me over 300gp to clean up that mess.~
 IF ~~ THEN EXIT
END

IF ~~ a173
 SAY ~[ARAN] Sune's Rambunctious Rump, <PRO_BOYGIRL>, I wish I did. I should have been studyin' strategy instead o' tactics. Next time we see a LoreKeeper, I think I will have a mite o' a word on what tomes to study. Tactics you can learn piecemeal, but strategy, that be a tougher game.~
 IF ~~ THEN EXIT
END

IF ~~ a174
 SAY ~[ARAN] Grumbar's Clay Fist, <PRO_BOYGIRL>, you do have an odd way o' lookin' at things.  I wish I saw things as clear as you do. I just keep runnin' into some problems in my own head. Some fool cleric or other said it was on account o' havin' somethin' called a 'conscience'. But you been callin' the plays well enough, an' i should shut up an' soldier.~ EXIT
 IF ~~ THEN EXIT
END

IF ~~ a175
 SAY ~[ARAN] Now, I didn't rightly say that, now, did I. I be after th' 'near death' experience, an' th' excitement, but I don't rightly want to move on to the next level. There be a big world out there, and I have seen only a small part o' it.~ EXIT
 IF ~~ THEN EXIT
END

IF ~~ a176
 SAY ~[ARAN] Now, that sounds right beautiful! Riches beyond my wildest ideas, all summed up right proper! What more could I want, eh?~
 ++ ~[PC] You are incorrigible.~ EXIT
 ++ ~[PC] Mine would probably include getting you a speech tutor.~ + 168
 ++ ~[PC] Gold, platinum, gems, magic items, and wealth... and you chose wine, women, and writing. Amazing.~ EXIT
 ++ ~[PC] It is a good thing you are so easy to please, Aran. It will keep you alive and useful to me, because we just do not want the same things.~ EXIT
END

 

Not sure I can do much right now as RL is going crazy, but tagging at the edges during long pointless discussions is working out ok (albeit very, very slowly).

 

// oddity - in the text file, everything is indented correctly. in the copy/paste into forum post, it is not. Note to self - recheck tab vs spaces, and character encoding going between Mac TextWrangler and PC TextPad/ConTEXT/NotePad++. Something is probably off there.

Link to comment

Sorry to nit-pick (because I know it can be annoying :crazyeyes:), but I'm not sure about this:

 

== ~CERNDJ~ IF ~InParty("Cernd") InMyArea("Cernd") !StateCheck("Cernd",CD_STATE_NOTVALID)~ THEN ~[CERND] You do not need leather to bind that. Nature provides many alternatives with similar strength, and the avoidance of killing an animal.~

Cernd's a werewolf, so I have to assume he's a carnivore :) and I don't think he'd have much of a gripe with the killing of an animal for human use - in fact, I'd argue that he'd be pleased that the entire animal is being used instead of the skin being wasted. It might be more in character for him to say something along the thought of, "If you plan to kill an animal to lace your boots, I certainly hope you intend to put the entire creature to good use. It goes against Nature to waste her gifts." Just a thought. :)

Link to comment

Darned good point! I had not thought through the shapeshifter vs werewolf thing -

 

And by all means, pick nits. One of the strengths of putting all this out in the open is getting that feedback before it hits playtesting :crazyeyes:

 

How about

 

== ~CERNDJ~ IF ~InParty("Cernd") InMyArea("Cernd") !StateCheck("Cernd",CD_STATE_NOTVALID)~ THEN ~[CERND] If you use leather to bind that, I would hope that you use the rest of the animal to good purpose. As Nature herself demonstrates, nothing should be wasted.~

 

?

Link to comment

Situation-specific friend talk" - more like a reaction talk. Probably needs expansion, but this is what I had time for today:

 

/* Shadow Dragon Killed */
IF
 Global("c-arshaddrag","GLOBAL",0)
 AreaCheck("AR1402")
 Dead("ShaDra01")
 InParty(Myself)
 !StateCheck(Myself,CD_STATE_NOTVALID)
 InMyArea(Player1)
 !StateCheck(Player1,CD_STATE_NOTVALID) 
THEN
 RESPONSE #100
SetGlobal("c-arshaddrag","GLOBAL",1)
END

IF
 Global("c-arshaddrag","GLOBAL",1)
 InParty(Myself)
 !StateCheck(Myself,CD_STATE_NOTVALID)
 InMyArea(Player1)
 !StateCheck(Player1,CD_STATE_NOTVALID) 
THEN
 RESPONSE #100
StartDialogueNoSet(Player1)
END

/////////////

IF ~Global("c-arshaddrag","GLOBAL",1)~ [SHADDRAG_ONE]
 SAY ~[ARAN] Well, now. I thought I had seen everythin' possible in th' way o' dragons. Never did see one what was like that. Wasn't even sure how to kill th' Cyric-blighted thing.~
 ++ ~[PC] You really, really don't like dragons, do you.~ DO ~SetGlobal("c-arshaddrag","GLOBAL",2)~ + [SHADDRAG_ONE_1]
 ++ ~[PC] So, you have seen lots of different dragons?~ DO ~SetGlobal("c-arshaddrag","GLOBAL",2)~ + [SHADDRAG_ONE_2]
 ++ ~[PC] You are never sure of anything.~ DO ~SetGlobal("c-arshaddrag","GLOBAL",2)~ + [SHADDRAG_ONE_3]
 ++ ~[PC] Let me guess. You had friends headed for Cormyr to deal with those dragons going rogue and terrorizing the countryside.~ DO ~SetGlobal("c-arshaddrag","GLOBAL",2)~  + [SHADDRAG_ONE_CORMYR]
 ++ ~[PC] Oh, come on. That was not the worst we could have faced. I have heard stories of how the great ones fought their deaths: Aerihykloarara, Agoshyrvor, Agyrtclughwaur, Angkarasce...~ DO ~SetGlobal("c-arshaddrag","GLOBAL",2)~ + [SHADDRAG_ONE_4]
 ++ ~[PC] You have to get over this dragon thing, Aran. It is really getting tiresome.~ DO ~SetGlobal("c-arshaddrag","GLOBAL",2)~ + [SHADDRAG_EXIT]
END

IF ~~ [SHADDRAG_ONE_1]
 SAY ~[ARAN] I suppose there might be some out there what be o' a good sort. But no, on balance, I respect 'em. But I don't like 'em.~
 IF ~~ THEN GOTO [SHADDRAG_TWO]
END

IF ~~ [SHADDRAG_ONE_2]
 SAY ~[ARAN] Before I met you? Aye. One or two. But not to speak to, or call on socially. Usually it were th' type o' meetin' where you feel th' chill in th' air, see th' shadow as she swoops close to th' lines, an' then everyone finds cover before they become casualties.~
 IF ~~ THEN GOTO [SHADDRAG_TWO]
END

IF ~~ [SHADDRAG_ONE_3]
 SAY ~[ARAN] I be right sure o' not likin' takin' on great blighted huge things what can kill a man a tenday from Uktar.~ // seven ways from Sunday converted into FR... may not work.
 IF ~~ THEN GOTO [SHADDRAG_TWO]
END

IF ~~ [SHADDRAG_ONE_4]
 SAY ~[ARAN] Meilikki's Mercy, don't speak out those names! Th' common denominator in all those deaths be th' great losses they inflicted before expirin'.~
 IF ~~ THEN GOTO [SHADDRAG_TWO]
END

IF ~~ [SHADDRAG_ONE_CORMYR]
 SAY ~[ARAN] Tymora's Fickle Fingersnaps, no. There be naught o' my friends what would sign up for that kind o' adventure. None o' my crowd frequent Th' Moon an' Stars, hobnobbin' wi' Volo an' Zhents an' faerie an' such.~
 ++ ~[PC] And yet here you are, chasing Irenicus with me across most of Amn. I would think dragons would be safer.~ + [SHADDRAG_TWO]
 ++ ~[PC] You might not be admitted, but by now I would. Well, either that or I would blow the doors down and take the place by storm, though that seems overkill for a good meal.~ + [SHADDRAG_TWO]
 ++ ~[PC] I keep forgetting that you have friends that are smarter than you are. Then again, some trees are smarter than you are, so...~ + [SHADDRAG_TWO]
 ++ ~[PC] You have smart friends.~ + [SHADDRAG_TWO]
 ++ ~[PC] You have to get over this dragon thing, Aran. It is really getting tiresome.~ + [SHADDRAG_EXIT]
END

IF ~~ [SHADDRAG_TWO]
 SAY ~[ARAN] Mayhap next time we decide to go pokin' about we get Elminster's Bestiary along an' contemplate what we might be facin'.~
 ++ ~[PC] I thought you once said that sometimes the best tactic is to just get a big sword and whack until it is dead.~ + [SHADDRAG_TWO_1]
 ++ ~[PC] I thought you carried a copy around in all those scrolls and papers you keep shuffling about.~ + [SHADDRAG_TWO_2]
 ++ ~[PC] Perhaps we should invest in a copy.~ + [SHADDRAG_TWO_3]
 ++ ~[PC] Do you really think we would have any chance of guessing which entries to look up in advance?~ + [SHADDRAG_TWO_4]
 ++ ~[PC] You have to get over this dragon thing, Aran. It is really getting tiresome.~ + [SHADDRAG_EXIT]
END

IF ~~ [SHADDRAG_TWO_1]
 SAY ~[ARAN] Well, I did. An' I do. But when th' blighted things seem to be immune to anythin' reasonable, it makes generally whackin' a bit like kissin' a cousin, eh? It be all fun an' games, but it won't get you where you want to go.~
 IF ~~ THEN GOTO [SHADDRAG_END]
END

IF ~~ [SHADDRAG_TWO_2]
 SAY ~[ARAN] Me? Hells, no. I done read a copy or two, pokin' about in th' Temples o' Ogma, but I never did get a personal copy.~
 IF ~~ THEN GOTO [SHADDRAG_END]
END

IF ~~ [SHADDRAG_TWO_3]
 SAY ~[ARAN] Mayhap two, on account o' th' number o' opponents what blast lightnin', acid, flame, an' slime all over everythin'. Hard to read a charred, mangled, dissolvin' copy, eh?~
 IF ~~ THEN GOTO [SHADDRAG_END]
END

IF ~~ [SHADDRAG_TWO_4]
 SAY ~[ARAN] Well, it wouldn't rightly hurt to try, would it?~
 IF ~~ THEN GOTO [SHADDRAG_END]
END

IF ~~ [SHADDRAG_END]
 SAY ~[ARAN] Though if point comes to point, th' way we be goin', by th' time we look up what we be facin', we'll be doin' it from th' inside o' th' creature, I guess. Blighted hells. At times, it be makin' me wish I'd decided to keep accounts in one o' those steady, safe jobs, like Risin' Sun Coster in Baldur's Gate.~
 = ~[ARAN] Come to think o' it, then I'd o' had a bunch o' ravin' mad doppelgangers runnin' about tryin' to kill me, if th' stories be true. Guess we just can't escape danger.
 IF ~~ THEN EXIT
END

IF ~~ [SHADDRAG_EXIT]
 SAY ~[ARAN] Fine. Mayhap I will find somethin' that bothers you. Like great hairy poison spittin' spiders. Or tax collectors.~
 IF ~~ THEN EXIT
END

/////////

Link to comment

Archived

This topic is now archived and is closed to further replies.

×
×
  • Create New...