Jump to content

SoA or ToB: Followers Talk


cmorgan

Recommended Posts

Starting at "high" levels like 7, 8, 9 (remember, ancient D&D had a short level table set) characters got followers. Followers would not usually accompany characters on group adventures. They were considered elite troops and were drawn to the character's reputation once he built a stronghold. Characters could also hire Hirelings and Henchmen, some of whom could adventure, and some of whom were sent on independent missions. The ruleset allowed DMs to expand the campaign by fleshing out the world that surrounded a high-powered character, and even letting them become lords, rulers, or even Kingmakers if the campaign went in that direction.

 

LOGIC_CHECK: can't build a stronghold while adventuring.

 

IN_GAME_CHECK: PC gets a stronghold. With tweaks, PC can get and administer several strongholds. Kish's NPC Strongholds allows them to be used by class-appropriate in-party NPCs.

 

SOLUTION: followers build stronghold while character is adventuring.

 

HOOKS: can be used for storytelling, provide scenery dialog, could even act as another stronghold, like Kish's NPC Strongholds mod.

 

 

 

/* AD&D 1E, 2E - Followers for High Level Characters; Hirelings; Henchmen; Ftr L 9 Freehold */

IF ~CONDITION_VAR_SET~ THEN BEGIN followers_0
  SAY ~[ARAN] Heh. Apparently, I have been wanderin' wi' you so long that I have followers o' my own now.~
  = ~[ARAN] I do be guessin' that when a lad gets to a certain point, folks think he be worth backin' up. Just never thought I'd have that happen.~
  ++ ~[PC] Congratulations! How did this all happen?~ + followers_01
  ++ ~[PC] This is a distraction. We  need assistance here and now, not some long term plan.~ + followers_02
  ++ ~[PC] Aran Whitehand. Adventurer, Raconteur..... Landlord.~ + followers_03
  ++ ~[PC] Could any of them be useful to us right now?~ + followers_04
  ++ ~[PC] So you are leaving and starting your own project.~ + followers_05
  ++ ~[PC] I hope it works out for you. Now stop talking and move along.~ + followers_06
END

IF ~~ followers_01
  SAY ~[ARAN] Well, a few of th' lads an' lasses from some o' th' past guild work I were doin' heard what we were about, an' it seems they wanted to chip in an' help.~
  = ~[ARAN] I done told 'em that I weren't goin' to be around much, on account o' we be adventurin', but they would take naught but yes for an answer.~
  ++ ~[PC] Where are they settling?~ + followers_015
  ++ ~[PC] This is a very bad idea. You should not be sponsoring followers.~ + followers_025
  ++ ~[PC] Let me guess... they are all walking around trying to imitate your speech patterns, and swearing up a storm.~ + followers_035
  ++ ~[PC] It sounds as if they really look up to you.~ + followers_045
  ++ ~[PC] You fell for that hook, line, and sinker. Now they get to adventure on your coin and have no real oversight.~ + followers_055
  ++ ~[PC] I hope it works out for you. Now stop talking and move along.~ + followers_06
END

IF ~~ followers_02
  SAY ~[ARAN] Look, they have naught in th' way o' half th' experience we have. They would not survive th' first battle. They be a fair sight stronger than th' average mercenary, but nowhere near what we can do.~
  ++ ~[PC] Where are they settling?~ + followers_015
  ++ ~[PC] So they are not useful to us now, and they will take your coin and distract you from helping me.~ + followers_025
  ++ ~[PC] Some days I am not sure what we can do. And most days, I really don't know what YOU can do!~ + followers_035
  ++ ~[PC] It sounds like you are getting an independent reputation as someone who can get things done.~ + followers_045
  ++ ~[PC] How can you trust that they are really your followers, and not just taking your coin and having a great time at the local inn?~ + followers_055
  ++ ~[PC] I hope it works out for you. Now stop talking and move along.~ + followers_06
END

IF ~~ followers_03
  SAY ~[ARAN] Me. A landlord. An' in charge o' other people. It boggles th' mind, it do.~
  ++ ~[PC] Where are they settling?~ + followers_015
  ++ ~[PC] This is a very bad idea. You should not be sponsoring followers.~ + followers_025
  ++ ~[PC] Wait, back up... someone actually sees you as a... a... leader? Gods, they really do not know with whom they are dealing!~ + followers_035
  ++ ~[PC] It sounds like you are getting an independent reputation as someone who can get things done.~ + followers_045
  ++ ~[PC] How can you trust that they are really your followers, and not just taking your coin and having a great time at the local inn?~ + followers_055
  ++ ~[PC] I hope it works out for you. Now stop talking and move along.~ + followers_06
END

IF ~~ followers_04
  SAY ~[ARAN] I am not rightly sure. They have a bit more experience than th' average soldier, but most o' them are just lookin' to stop wanderin' around old ruins an' attemptin' to avoid a hideous death over a few coppers an a tradebar's worth o' figurines.~
  ++ ~[PC] Where are they settling?~ + followers_015
  ++ ~[PC] This is a very bad idea. You should not be sponsoring followers.~ + followers_025
  ++ ~[PC] Wait, back up... someone actually sees you as a... a... leader? Gods, they really do not know with whom they are dealing!~ + followers_035
  ++ ~[PC] It sounds like you are getting an independent reputation as someone who can get things done.~ + followers_045
  ++ ~[PC] How can you trust that they are really your followers, and not just taking your coin and having a great time at the local inn?~ + followers_055
  ++ ~[PC] I hope it works out for you. Now stop talking and move along.~ + followers_06
END

IF ~~ followers_05
  SAY ~[ARAN] Tyr's Eye, how could you be thinkin' that? They be perfectly self sufficient, except for some coin an' some basic directions. No call for me to go sit an' supervise.~
  ++ ~[PC] Where are they settling?~ + followers_015
  ++ ~[PC] You have no independent experience. You are not there in person. You have a habit of getting distracted. These are not positive indicators for this kind of venture.~ + followers_025
  ++ ~[PC] WWait, back up... someone actually sees you as a... a... leader? Gods, they really do not know with whom they are dealing!~ + followers_035
  ++ ~[PC] Where did you find them? Or did they just hear about you on the road, and decide to seek you out?~ + followers_045
  ++ ~[PC] How can you trust that they are really your followers, and not just taking your coin and having a great time at the local inn?~ + followers_055
  ++ ~[PC] I hope it works out for you. Now stop talking and move along.~ + followers_06
END

/* passthrough */
IF ~~ followers_015
  SAY ~[ARAN] Well, I have a little bit o' land my father traded for, up on th' Sword Coast. I figured wi' th' coin from adventurin', I'd set up a small tower an' tradin' port right on th' coast.~
  ++ ~[PC] A lighthouse? Or some sort of library tower? A shipbuilding operation might be very handy in that location.~ + followers_06
  ++ ~[PC] That is a dangerous area, and this project is most likely to end up like so many have in the past - yet another abandoned ruined tower cluttering the coastline.~ + followers_06
  ++ ~[PC] Trading wits? Words? Wait... you could capture the entire wolf pelt bounty. I think I have two people you will want to meet. Hmmm... what were those names... ~ + followers_06
  ++ ~[PC] I travelled the southern part of that area while dealing with the Iron Throne. It is a very dangerous area. Sirenes, pirates, hobgoblin tribes, orcs, gibberling hordes... but the opportunity is hard to pass up.~ + followers_06
  ++ ~[PC] If it were me, I would stick to the Trade Way and rebuild some of the destroyed travel towers. Perhaps even set up tolls. Perhaps you could expand the operation.~ + followers_06
  ++ ~[PC] I hope it works out for you. Now stop talking and move along.~ + followers_06
END

IF ~~ followers_025
  SAY ~[ARAN] Blighted hells. A lad gets somethin' special happenin' to him, gets a little piece o' the' glory like you get, an' you have to go all down on it.~
  ++ ~[PC] I am just worried that you do not realize how much work you may have set yourself up for. Perhaps I was hasty in my judgement. If someone can succeed at this, it is probably you.~ + followers_06
  ++ ~[PC] You have been my follower. Your will is not in question, but your ability to lead is definitely my concern. I just do not see you becoming their leader.~ + followers_06
  ++ ~[PC] Sure. Glory. That's what they call it these days. Look, I just think that you are setting yourself up for disappointment. You are a long way from them. It is hard to lead in those circumstances.~ + followers_06
  ++ ~[PC] I am sorry... I am proud to hear that you are getting some recognition. Perhaps this is the start of bigger things for you.~ + followers_06
  ++ ~[PC] Alright. If you do this, you should think about how to make the most of it. Set up tolls on the local roads, build some alliances with the nearest freeholds, that sort of thing.~ + followers_06  
  ++ ~[PC] Fine. I hope it works out for you. Now stop talking and move along.~ + followers_06
END

IF ~~ followers_035
  SAY ~[ARAN] Now, don't you be teasin' 'em on account o' their bad taste in sponsors, eh? There be a scribe or two, a cleric o' Sune, an' a handful o' fighters.~
  = ~[ARAN] They just want an opportunity to get together, a place to call home, an' mayhap to feel a mite bit useful. I can understand that right plain.~
  ++ ~[PC] That sounds like a useful group of followers to have.~ + followers_06
  ++ ~[PC] They must not have enough experience to be useful, or they would be out on their own finding their own followers.~ + followers_06
  ++ ~[PC] Just as long as you aren't starting the Sword Coast Inn, Writer's Theater, and Brothel. Sometimes these things just spiral out of control, you know.~ + followers_06
  ++ ~[PC] If you trust them and they have proven themselves to you, then I support your decision. If you need more coin, just ask.~ + followers_06
  ++ ~[PC] Just do not expect me to help you throw good coin after bad. This is entirely on you. I doubt it will work.~ + followers_06
  ++ ~[PC] Fine. I hope it works out for you. Now stop talking and move along.~ + followers_06
END

IF ~~ followers_045
  SAY ~[ARAN] I did a few favors an' helped out a mite bit before I met you, an' that be th' truth o' it. I guess you have naught in th' way o' knowin' when a good deed gets rewarded.~
  ++ ~[PC] So, they get a few new adventures and a base of operations, and you gain access to the resources of a group of experienced assistance.~ + followers_06
  ++ ~[PC] It sounds more like they know who to turn to when they need steady income. They must know you are too trusting.~ + followers_06
  ++ ~[PC] I wonder how long it is before one of them decides to start imitating your speech patterns and telling pointless stories...~ + followers_06
  ++ ~[PC] Perhaps someday they will pay a solid dividend. Having a private freehold could be useful. Having experienced adventurers to give missions to could help you, too.~ + followers_06
  ++ ~[PC] We have enough to deal with here and now without you chasing some wild dream of becoming the next Lord of the Coast.~ + followers_06  
  ++ ~[PC] I hope it works out for you. Now stop talking and move along.~ + followers_06
EXIT

IF ~~ followers_055
  SAY ~[ARAN] These be lads an' lasses what I trust. They have been on th' Shield Wall wi' me. An' mayhap I can make my own judgements on what to do wi' my coin, eh?~
  ++ ~[PC] That sounds much better. You are taking charge, and not backing down. You  might be able to give them some good leadership after all.~ + followers_06
  ++ ~[PC] It is your coin. I just think it is a waste of your resources and a distraction.~ + followers_06
  ++ ~[PC] Whoa, so serious! Relax! It is a better idea than the last venture you were thinking about spending coin to support.~ + followers_06
  ++ ~[PC] If you trust them and they have proven themselves to you, then I support your decision. If you need more coin, just ask.~ + followers_06
  ++ ~[PC] Just do not expect me to help you throw good coin after bad. This is entirely on you. I doubt it will work.~ + followers_06
  ++ ~[PC] Fine. I hope it works out for you. Now stop talking and move along.~ + followers_06
EXIT

IF ~~  followers_06
  SAY ~[ARAN] Well, we will see, I guess. Right now, th' lads an' lasses be right happy enough settin' up an encampment an' spendin' my coin right quick to clear out th' unwanted elements. Good to know I have some kind o' investment in th' future.~
  IF ~~ THEN EXIT
END
Link to comment

Interesting thread!

 

The idea is a rather cool one. In GemRB, I'd think it would work well; I always wanted a true "build your own stronghold" thing. DA and some other games do this; in Skyrim, I run http://www.nexusmods.com/skyrim/mods/22330/? Tundra Defense.

 

For this mod, though, the goal is to provide an interactive "backstory"; scenery dialogue that gives more of a sense of immersion. Plus I have had it in Beta for years - adding a full-on "build-your-own-stronghold-outside-the-storyline" is a good idea for an independent mod, but on Aran this will just be something new for PC and Aran to talk about. The existing strongholds provide a similar set of interactions. Wrapping up a release candidate is not the time or place to put huge game altering changes :)

Link to comment

OK, so in testing now - not yet updated onto GitHub as i want to recheck everything (stitching these into the current "not underdark" talks involved some updating of vars, and that always calls for multiple re-checks).

 

Note to self - just prior to release, do a "map the talks in-project" post.

 

Three "scenery" talks spaced out over the Friendship Track in SoA.

 

Still to do before release - the two "status" talks for epilogue and integrating the "status check" into the PID. Need more summer vacation and less Mass Effect. Luckily, SWTOR is losing its appeal - played out, I think, and not looking forward to the next expansion.

 

Contents of the "Follower Talks", as coded:

 

/* AD&D 1E, 2E - Followers for High Level Characters; Hirelings; Henchmen; Ftr L 9 Freehold */
/* follower talk 1 */

IF ~Global("c-aranfriendbg2","GLOBAL",11)~ THEN BEGIN a5183
  SAY @13567 /* [ARAN] Heh. Apparently, I have been wanderin' wi' you so long that I have followers o' my own now. */
  = @13568 /* [ARAN] I do be guessin' that when a lad gets to a certain point, folks think he be worth backin' up. Just never thought I'd have that happen. */
  ++ @13569 /* [PC] Congratulations! How did this all happen? */ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",12) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5184
  ++ @13570 /* [PC] This is a distraction. We  need assistance here and now, not some long term plan. */ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",12) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5185
  ++ @13571 /* [PC] Aran Whitehand. Adventurer, Raconteur..... Landlord. */ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",12) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5186
  ++ @13572 /* [PC] Could any of them be useful to us right now? */ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",12) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5187
  ++ @13573 /* [PC] So you are leaving and starting your own project. */ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",12) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5188
  ++ @13574 /* [PC] I hope it works out for you. Now stop talking and move along. */ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",12) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5194
END

IF ~~ a5184
  SAY @13575 /* [ARAN] Well, a few of th' lads an' lasses from some o' th' past guild work I were doin' heard what we were about, an' it seems they wanted to chip in an' help. */
  = @13576 /* [ARAN] I done told 'em that I weren't goin' to be around much, on account o' we be adventurin', but they would take naught but yes for an answer. */
  ++ @13577 /* [PC] Where are they settling? */ + a5189
  ++ @13578 /* [PC] This is a very bad idea. You should not be sponsoring followers. */ + a5190
  ++ @13579 /* [PC] Let me guess... they are all walking around trying to imitate your speech patterns, and swearing up a storm. */ + a5191
  ++ @13580 /* [PC] It sounds as if they really look up to you. */ + a5192
  ++ @13581 /* [PC] You fell for that hook, line, and sinker. Now they get to adventure on your coin and have no real oversight. */ + a5193
  ++ @13574 /* [PC] I hope it works out for you. Now stop talking and move along. */ + a5194
END

IF ~~ a5185
  SAY @13582 /* [ARAN] Look, they have naught in th' way o' half th' experience we have. They would not survive th' first battle. They be a fair sight stronger than th' average mercenary, but nowhere near what we can do. */
  ++ @13577 /* [PC] Where are they settling? */ + a5189
  ++ @13583 /* [PC] So they are not useful to us now, and they will take your coin and distract you from helping me. */ + a5190
  ++ @13584 /* [PC] Some days I am not sure what we can do. And most days, I really don't know what YOU can do! */ + a5191
  ++ @13585 /* [PC] It sounds like you are getting an independent reputation as someone who can get things done. */ + a5192
  ++ @13586 /* [PC] How can you trust that they are really your followers, and not just taking your coin and having a great time at the local inn? */ + a5193
  ++ @13574 /* [PC] I hope it works out for you. Now stop talking and move along. */ + a5194
END

IF ~~ a5186
  SAY @13587 /* [ARAN] Me. A landlord. An' in charge o' other people. It boggles th' mind, it do. */
  ++ @13577 /* [PC] Where are they settling? */ + a5189
  ++ @13578 /* [PC] This is a very bad idea. You should not be sponsoring followers. */ + a5190
  ++ @13588 /* [PC] Wait, back up... someone actually sees you as a... a... leader? Gods, they really do not know with whom they are dealing! */ + a5191
  ++ @13585 /* [PC] It sounds like you are getting an independent reputation as someone who can get things done. */ + a5192
  ++ @13586 /* [PC] How can you trust that they are really your followers, and not just taking your coin and having a great time at the local inn? */ + a5193
  ++ @13574 /* [PC] I hope it works out for you. Now stop talking and move along. */ + a5194
END

IF ~~ a5187
  SAY @13589 /* [ARAN] I am not rightly sure. They have a bit more experience than th' average soldier, but most o' them are just lookin' to stop wanderin' around old ruins an' attemptin' to avoid a hideous death over a few coppers an a tradebar's worth o' figurines. */
  ++ @13577 /* [PC] Where are they settling? */ + a5189
  ++ @13578 /* [PC] This is a very bad idea. You should not be sponsoring followers. */ + a5190
  ++ @13588 /* [PC] Wait, back up... someone actually sees you as a... a... leader? Gods, they really do not know with whom they are dealing! */ + a5191
  ++ @13585 /* [PC] It sounds like you are getting an independent reputation as someone who can get things done. */ + a5192
  ++ @13586 /* [PC] How can you trust that they are really your followers, and not just taking your coin and having a great time at the local inn? */ + a5193
  ++ @13574 /* [PC] I hope it works out for you. Now stop talking and move along. */ + a5194
END

IF ~~ a5188
  SAY @13590 /* [ARAN] Tyr's Eye, how could you be thinkin' that? They be perfectly self sufficient, except for some coin an' some basic directions. No call for me to go sit an' supervise. */
  ++ @13577 /* [PC] Where are they settling? */ + a5189
  ++ @13591 /* [PC] You have no independent experience. You are not there in person. You have a habit of getting distracted. These are not positive indicators for this kind of venture. */ + a5190
  ++ @13592 /* [PC] WWait, back up... someone actually sees you as a... a... leader? Gods, they really do not know with whom they are dealing! */ + a5191
  ++ @13593 /* [PC] Where did you find them? Or did they just hear about you on the road, and decide to seek you out? */ + a5192
  ++ @13586 /* [PC] How can you trust that they are really your followers, and not just taking your coin and having a great time at the local inn? */ + a5193
  ++ @13574 /* [PC] I hope it works out for you. Now stop talking and move along. */ + a5194
END

IF ~~ a5189
  SAY @13594 /* [ARAN] Well, I have a little bit o' land my father traded for, up on th' Sword Coast. I figured wi' th' coin from adventurin', I'd set up a small tower an' tradin' port right on th' coast. */
  ++ @13595 /* [PC] A lighthouse? Or some sort of library tower? A shipbuilding operation might be very handy in that location. */ + a5194
  ++ @13596 /* [PC] That is a dangerous area, and this project is most likely to end up like so many have in the past - yet another abandoned ruined tower cluttering the coastline. */ + a5194
  ++ @13597 /* [PC] Trading wits? Words? Wait... you could capture the entire wolf pelt bounty. I think I have two people you will want to meet. Hmmm... what were those names...  */ + a5194
  ++ @13598 /* [PC] I travelled the southern part of that area while dealing with the Iron Throne. It is a very dangerous area. Sirenes, pirates, hobgoblin tribes, orcs, gibberling hordes... but the opportunity is hard to pass up. */ + a5194
  ++ @13599 /* [PC] If it were me, I would stick to the Trade Way and rebuild some of the destroyed travel towers. Perhaps even set up tolls. Perhaps you could expand the operation. */ + a5194
  ++ @13574 /* [PC] I hope it works out for you. Now stop talking and move along. */ + a5194
END

IF ~~ a5190
  SAY @13600 /* [ARAN] Blighted hells. A lad gets somethin' special happenin' to him, gets a little piece o' the' glory like you get, an' you have to go all down on it. */
  ++ @13601 /* [PC] I am just worried that you do not realize how much work you may have set yourself up for. Perhaps I was hasty in my judgement. If someone can succeed at this, it is probably you. */ + a5194
  ++ @13602 /* [PC] You have been my follower. Your will is not in question, but your ability to lead is definitely my concern. I just do not see you becoming their leader. */ + a5194
  ++ @13603 /* [PC] Sure. Glory. That's what they call it these days. Look, I just think that you are setting yourself up for disappointment. You are a long way from them. It is hard to lead in those circumstances. */ + a5194
  ++ @13604 /* [PC] I am sorry... I am proud to hear that you are getting some recognition. Perhaps this is the start of bigger things for you. */ + a5194
  ++ @13605 /* [PC] Alright. If you do this, you should think about how to make the most of it. Set up tolls on the local roads, build some alliances with the nearest freeholds, that sort of thing. */ + a5194  
  ++ @13606 /* [PC] Fine. I hope it works out for you. Now stop talking and move along. */ + a5194
END

IF ~~ a5191
  SAY @13607 /* [ARAN] Now, don't you be teasin' 'em on account o' their bad taste in sponsors, eh? There be a scribe or two, a cleric o' Sune, an' a handful o' fighters. */
  = @13608 /* [ARAN] They just want an opportunity to get together, a place to call home, an' mayhap to feel a mite bit useful. I can understand that right plain. */
  ++ @13609 /* [PC] That sounds like a useful group of followers to have. */ + a5194
  ++ @13610 /* [PC] They must not have enough experience to be useful, or they would be out on their own finding their own followers. */ + a5194
  ++ @13611 /* [PC] Just as long as you aren't starting the Sword Coast Inn, Writer's Theater, and Brothel. Sometimes these things just spiral out of control, you know. */ + a5194
  ++ @13612 /* [PC] If you trust them and they have proven themselves to you, then I support your decision. If you need more coin, just ask. */ + a5194
  ++ @13613 /* [PC] Just do not expect me to help you throw good coin after bad. This is entirely on you. I doubt it will work. */ + a5194
  ++ @13606 /* [PC] Fine. I hope it works out for you. Now stop talking and move along. */ + a5194
END

IF ~~ a5192
  SAY @13614 /* [ARAN] I did a few favors an' helped out a mite bit before I met you, an' that be th' truth o' it. I guess you have naught in th' way o' knowin' when a good deed gets rewarded. */
  ++ @13615 /* [PC] So, they get a few new adventures and a base of operations, and you gain access to the resources of a group of experienced assistance. */ + a5194
  ++ @13616 /* [PC] It sounds more like they know who to turn to when they need steady income. They must know you are too trusting. */ + a5194
  ++ @13617 /* [PC] I wonder how long it is before one of them decides to start imitating your speech patterns and telling pointless stories... */ + a5194
  ++ @13618 /* [PC] Perhaps someday they will pay a solid dividend. Having a private freehold could be useful. Having experienced adventurers to give missions to could help you, too. */ + a5194
  ++ @13619 /* [PC] We have enough to deal with here and now without you chasing some wild dream of becoming the next Lord of the Coast. */ + a5194  
  ++ @13574 /* [PC] I hope it works out for you. Now stop talking and move along. */ + a5194
END

IF ~~ a5193
  SAY @13620 /* [ARAN] These be lads an' lasses what I trust. They have been on th' Shield Wall wi' me. An' mayhap I can make my own judgements on what to do wi' my coin, eh? */
  ++ @13621 /* [PC] That sounds much better. You are taking charge, and not backing down. You  might be able to give them some good leadership after all. */ + a5194
  ++ @13622 /* [PC] It is your coin. I just think it is a waste of your resources and a distraction. */ + a5194
  ++ @13623 /* [PC] Whoa, so serious! Relax! It is a better idea than the last venture you were thinking about spending coin to support. */ + a5194
  ++ @13612 /* [PC] If you trust them and they have proven themselves to you, then I support your decision. If you need more coin, just ask. */ + a5194
  ++ @13613 /* [PC] Just do not expect me to help you throw good coin after bad. This is entirely on you. I doubt it will work. */ + a5194
  ++ @13606 /* [PC] Fine. I hope it works out for you. Now stop talking and move along. */ + a5194
END

IF ~~ a5194
  SAY @13624 /* [ARAN] Well, we will see, I guess. Right now, th' lads an' lasses be right happy enough settin' up an encampment an' spendin' my coin right quick to clear out th' unwanted elements. Good to know I have some kind o' investment in th' future. */
  IF ~~ THEN EXIT
END

/* AD&D 1E, 2E - Followers for High Level Characters; Hirelings; Henchmen; Ftr L 9 Freehold */
/* follower talk 2 */

IF ~Global("c-aranfriendbg2","GLOBAL",17)~ THEN BEGIN a5195
  SAY @13625 /* [ARAN] Well, now, that be a bit o' a problem I never had before. Those followers o' mine want some advice. */
  ++ @13626 /* [PC] What sort of advice? */ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",18) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5196
  ++ @13627 /* [PC] They may need to learn things the way we have... the hard way. */ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",18) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5197
  ++ @13628 /* [PC] I think you can handle giving them a little guidance. We have certainly survived through enough to have some confidence. */ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",18) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5198
  ++ @13629 /* [PC] Never get in a drinking match with two dwarves and a fire giant?  */ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",18) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5200
  ++ @13630 /* [PC] We do not have time for this, Aran. We should press on.  */ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",18) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5206
END

IF ~~ a5196
  SAY @13631 /* [ARAN] It seems like they have found themselves a cave or some sort o' cavern under a bluff right along th' coast, an' they think it might be worth an expedition. */
  ++ @13632 /* [PC] Ah, memories... I found one of those, once, right along the coast by Candlekeep. It was guarded by sirenes, filled with monsters, and even had treasure. */ + a5201
  ++ @13633 /* [PC] Well, give them some basic advice on supplies and preparation, and then let them do their job. */ + a5202
  ++ @13634 /* [PC] Great. A cave. We have plenty of experience with those. Usually they involve screaming, and running, and things being set on fire. And spiders. */ + a5203
  ++ @13635 /* [PC] You are not asking to go all the way back to the Sword Coast to investigate a cave, are you? */ + a5205
  ++ @13630 /* [PC] We do not have time for this, Aran. We should press on.  */ + a5206
END

IF ~~ a5197 SAY @13636 /* [ARAN] Now, we do get more than our fair share o' folks who want to give us advice. Whether we be takin' it or not, they still offer it. */ IF ~~ THEN GOTO a5199 END
IF ~~ a5198 SAY @13637 /* [ARAN] Well, that be true enough. An' th' thing they be interested in be somethin' we can relate to. */ IF ~~ THEN GOTO a5199 END
 
IF ~~ a5199
  SAY @13631 /* [ARAN] It seems like they have found themselves a cave or some sort o' cavern under a bluff right along th' coast, an' they think it might be worth an expedition. */
  ++ @13632 /* [PC] Ah, memories... I found one of those, once, right along the coast by Candlekeep. It was guarded by sirenes, filled with monsters, and even had treasure. */ + a5201
  ++ @13633 /* [PC] Well, give them some basic advice on supplies and preparation, and then let them do their job. */ + a5202
  ++ @13638 /* [PC] Tell them that clearing a perimeter, setting up a solid defense, and planning out the site takes precedence over random sink holes that may spell inevitable death. */ + a5203
  ++ @13635 /* [PC] You are not asking to go all the way back to the Sword Coast to investigate a cave, are you? */ + a5205
  ++ @13630 /* [PC] We do not have time for this, Aran. We should press on.  */ + a5206
END

IF ~~ a5200
  SAY @13639 /* [ARAN] Funny, funny... an' probably advice I should have had told to me long ago. */
  ++ @13640 /* [PC] Look, telling someone what to do on their first big adventure spoils all the fun. */ + a5201
  ++ @13641 /* [PC] I think you should give them a list of local dry goods suppliers, a map to the nearest healing shrines and temples, and let them figure the rest out. */ + a5202
  ++ @13638 /* [PC] Tell them that clearing a perimeter, setting up a solid defense, and planning out the site takes precedence over random sink holes that may spell inevitable death. */ + a5203
  ++ @13642 /* [PC] So, what are you going to advise them to do? */ + a5204
  ++ @13630 /* [PC] We do not have time for this, Aran. We should press on.  */ + a5206
END

IF ~~ a5201
  SAY @13643 /* [ARAN] I think it be worth a look. */
  ++ @13635 /* [PC] You are not asking to go all the way back to the Sword Coast to investigate a cave, are you? */ + a5205
  ++ @13641 /* [PC] I think you should give them a list of local dry goods suppliers, a map to the nearest healing shrines and temples, and let them figure the rest out. */ + a5202
  ++ @13644 /* [PC] You are an incurable optimist, aren't you. */ + a5206
  ++ @13645 /* [PC] Do you have any specific advice you can give them? */ + a5204
  ++ @13630 /* [PC] We do not have time for this, Aran. We should press on.  */ + a5206
END

IF ~~ a5202
  SAY @13646 /* [ARAN] So, healin' advice, check. Supplies, includin' some decent rope an' mayhap a sack o' four or two, check. */
  ++ @13647 /* [PC] Tell them to prepare for giant spiders, wandering vampiric mists, flesh golems, and random but inevitable death. */ + a5203
  ++ @13648 /* [PC] I hope they know the difference between a wet mossy rock and a grey ooze. */ + a5206
  ++ @13649 /* [PC] Burial shrouds. Lots of burial shrouds. Something to haul their broken bodies home. */ + a5203
  ++ @13650 /* [PC] That sounds appropriate. Having good supplies can make the difference between success and failure. */ + a5206
  ++ @13630 /* [PC] We do not have time for this, Aran. We should press on.  */ + a5206 
END

IF ~~ a5203
  SAY @13651 /* [ARAN] Now, it will be naught in th' way o' bein' so bad, eh? We done survived worse things than most could imagine. Mayhap they will find a nice little cave wi' a good challenge an' a bit o' treasure. */
  ++ @13644 /* [PC] You are an incurable optimist, aren't you. */ + a5206
  ++ @13652 /* [PC] You can always send a second expedition to bring back their dead bodies. If there are any bodies left. */ + a5206
  ++ @13653 /* [PC] You are right. They have to have better luck than we do... */ + a5206
  ++ @13654 /* [PC] They are not us. */ + a5206
  ++ @13630 /* [PC] We do not have time for this, Aran. We should press on.  */ + a5206
END

IF ~~ a5204
  SAY @13655 /* [ARAN] I have some small ideas, but I have made naught in th' way o' a clear decision. Clear a site an' set up for a settlement, or explore somethin' nearby that can wait for a bit. That be a difficult call. */
  ++ @13656 /* [PC] Setting up a camp and a detailed perimeter sounds like a smart idea. Then when they have more of a settlement, they will have a place to retreat to if things go wrong. */ + a5206
  ++ @13657 /* [PC] Clearing the cave should probably take priority. Is it just a cave, or is it a passage to Underdark? That would make settling there a bit of a challenge. */ + a5206
  ++ @13658 /* [PC] I think they should find a new site father away from caves and caverns. */ + a5206
  ++ @13659 /* [PC] They are the ones with the most immediate knowledge. Let them make the decision. */ + a5206
  ++ @13630 /* [PC] We do not have time for this, Aran. We should press on.  */ + a5206 
END

IF ~~ a5205
  SAY @13660 /* [ARAN] Oh, hells no. But they can do it, an' mayhap it will prove to be a new source o' income. Or mayhap a good mine, a good resource for buildin' that tower. It could be anythin'. An old-fashioned adventure. */
  ++ @13661 /* [PC] You sound very excited for them. */ + a5206
  ++ @13662 /* [PC] I wish them well. I miss those days. Well, except for the running away from packs of wolves and gibberlings. I do not miss that. */ + a5206
  ++ @13663 /* [PC] It is none of my business. Tell them whatever you want. */ + a5206
  ++ @13664 /* [PC] Make sure they have an effective cleric or a pile of healing potions. Caves can be tricky. */ + a5206
  ++ @13665 /* [PC] If it were me, I would tell them to stay at the camp and take up farming. This adventuring business has brought me a great deal of pain. */ + a5206
END

IF ~~ a5206
  SAY @13666 /* [ARAN] Aye, sure enough. Though... well, I'd best make my own mind up an' send along a message. No point in bein' in charge o' somethin' if I do naught in th' way o' leadin', even if from a fair distance. */
  IF ~~ THEN EXIT
END

/* AD&D 1E, 2E - Followers for High Level Characters; Hirelings; Henchmen; Ftr L 9 Freehold */
/* follower talk 3 */

IF ~Global("c-aranfriendbg2","GLOBAL",27)~ THEN BEGIN a5207
  SAY @13667 /* [ARAN] Cyric's Bleached Bones, all that blighted work for naught. */
  ++ @13668 /* [PC] Your curry was not that bad this time, Aran. In fact, it was pretty good. */ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",28) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5208
  ++ @13669 /* [PC] You are holding that letter like it was a living thing that you are attempting to strangle. */ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",28) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5208
  ++ @13670 /* [PC] What is wrong? */ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",28) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5208
  ++ @13671 /* [PC] Yes. You are still swearing, and your accent is still very strong. All my careful re-training work on you has vanished. */ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",28) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5208
  ++ @13672 /* [PC] Whatever it is, Aran, we do not have time to deal with it right now. */ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",28) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5208
END

IF ~~ a5208
  SAY @13673 /* [ARAN] That band o' adventurers what attached themselves to me went ahead into th' cave. An' they found.... */
  = @13674 /* [ARAN] Naught. */
  = @13675 /* [ARAN] Great piles o' grand stinkin' heapin' blighted NOTHIN'. */
  ++ @13676 /* [PC] Well, that was always a possibility. Sometimes a cave is just a cave. */ + a5209
  ++ @13677 /* [PC] I bet that if it were me, there would have been a band of Orcs. Or a massive inter-planar being with horrible breath and magical weapons. */ + a5210
  ++ @13678 /* [PC] That is a little disappointing. */ + a5212
  ++ @13679 /* [PC] They survived! */ + a5211
  ++ @13680 /* [PC] I am serious. We do not have time to deal with it right now. We need to drop this and move on. */ + a5218
END

IF ~~ a5209
  SAY @13681 /* [ARAN] WE wander about tryin' to get from here to there an' back all intact, an' are swarmed wi' monsters o' myth an' legend. THEY set out to find adventure, an' find th' start o' a great root cellar. */
  ++ @13682 /* [PC] Aran... have you ever really looked at how different we are from.... ordinary? */ + a5213
  ++ @13683 /* [PC] Wait a minute. This is good news. No Underdark exits, no tribe of goblins to fight off, and they can excavate the stone to build fortifications and buildings! */ + a5214
  ++ @13684 /* [PC] I blame the leadership. Particularly your lack of leadership. */ + a5215
  ++ @13685 /* [PC] This is a distraction. You need to tell them to stick to the business of planning the settlement, and leave the adventuring to us. */ + a5216
  ++ @13686 /* [PC] Well, that grand "follower" experiment is over, I assume. */ + a5218
END

IF ~~ a5210
  SAY @13687 /* [ARAN] Serves me blighted right. I have gotten so used to us openin' every door an' bein' attacked that I assume every place is inhabited, filled wi' treasure, an' there for th' discoverin'. */
  ++ @13688 /* [PC] You are travelling with me. They are not. */ + a5213
  ++ @13689 /* [PC] Aran, how are you getting and sending all these letters and messages? We are not exactly in touch with a reliable network of couriers. */ + a5217
  ++ @13684 /* [PC] I blame the leadership. Particularly your lack of leadership. */ + a5215
  ++ @13685 /* [PC] This is a distraction. You need to tell them to stick to the business of planning the settlement, and leave the adventuring to us. */ + a5216
  ++ @13686 /* [PC] Well, that grand "follower" experiment is over, I assume. */ + a5218
END

IF ~~ a5211
  SAY @13690 /* [ARAN] Yes, they survived. Gond's Great Gears, they barely broke sweat on a blighted buttock! */
  IF ~~ THEN GOTO a5212
END

IF ~~ a5212
  SAY @13691 /* [ARAN] I spend hours an' days sendin' messages, usin' what precious few sorcerered stones to send supply lists, plans, local mercenary contacts, and authorizin' th' use o' coin to fund th' expedition, and there be naught there but dust, a little spring pool, an' some blighted moss. */
  ++ @13682 /* [PC] Aran... have you ever really looked at how different we are from.... ordinary? */ + a5213
  ++ @13683 /* [PC] Wait a minute. This is good news. No Underdark exits, no tribe of goblins to fight off, and they can excavate the stone to build fortifications and buildings! */ + a5214
  ++ @13684 /* [PC] I blame the leadership. Particularly your lack of leadership. */ + a5215
  ++ @13692 /* [PC] "Sorcerered stones"... */ + a5217
  ++ @13693 /* [PC] Perhaps it is time to let them know that they should stick to building a simple settlement. */ + a5218
END

IF ~~ a5213
  SAY @13694 /* [ARAN] Aye, I get that th' Prophecies, an' th' Bhaalspawn thing, an' all that mean we are havin' more adventure every day than most would in their entire lives. I just... */
  ++ @13695 /* [PC] ...wanted them to have a successful first adventure? */ + a5218
  ++ @13696 /* [PC] ...wanted the cave to be filled with ferocious monsters that they could win glory by defeating? */ + a5218
  ++ @13697 /* [PC] ...wanted to find an abandoned gold mine that could fund a full settlement and set you up for retirement? */ + a5218
  ++ @13698 /* [PC] ...wanted them to be useful, instead of a large waste of money and time? */ + a5218
  ++ @13699 /* [PC] ...wasted my time telling me about a bunch of idiots who chose to follow you about playing at being adventurers. */ + a5218
END

IF ~~ a5214
  SAY @13700 /* [ARAN] Aye, mayhap you have a point there. It could be a right fine storage annex, or mayhap even a vault. An' savin' supplies from th' wear an' tear o' th' weather be a good outcome, I expect. */
  = @13701 /* [ARAN] But I were hopin' for more in th' way o' a morale boost for them. It be blighted hard to say 'you done found a wonderful empty hole. Congratulations'. */
  ++ @13702 /* [PC] You might surprise yourself. Even a small success is a great morale booster, if you handle it right. You just need to avoid showing how much you do not like that outcome. */ + a5218
  ++ @13703 /* [PC] I think you should have them move the settlement site closer to that cavern, and use it. */ + a5218
  ++ @13704 /* [PC] Not every adventure results on fine gems and expensive magical weapons. I think morale is about what is next, not what is now. */ + a5218
  ++ @13686 /* [PC] Well, that grand "follower" experiment is over, I assume. */ + a5218
  ++ @13693 /* [PC] Perhaps it is time to let them know that they should stick to building a simple settlement. */ + a5218
END

IF ~~ a5215
  SAY @13705 /* [ARAN] An' what be my failure? */
  ++ @13706 /* [PC] Getting upset at a setback. This is not the first time an expedition has ended in failure. Get yourself together. */ + a5218
  ++ @13707 /* [PC] Not leading from the front. You should have gone there and made sure the job was done right. Of course, you couldn't do that... */ + a5218
  ++ @13708 /* [PC] Having followers. They tend to disappoint the one they claim to be following. */ + a5218
  ++ @13709 /* [PC] Lack of decent scouting. Someone should have watched that cave for several weeks before entering. Perhaps even before asking to mount an expedition. */ + a5218
  ++ @13710 /* [PC] Oh, let me count the many, many ways... */ + a5218
END

IF ~~ a5216
  SAY @13711 /* [ARAN]  Now, that be right harsh. Not every adventure be a great haul o' lewels an' items. Sometimes just findin' a new safer route, or mayhap some usable rock be a step forward. */
  IF ~~ THEN GOTO a5218 
END

IF ~~ a5217
  SAY @13712 /* [ARAN] I got me some pebbles what can be called an' swapped between large spaces. Blighted expensive to use, on account o' the time spent on th' other end by th' mage or sorceror callin' th' stone, but it can bring along a sheet o' vellum all wrapped up tight an' sealed. Naught in th' way o' more, but it works passably to get th' stones to swap places. */
  = @13713 /* [ARAN] From there, th' courier network takes it on right fine. How in th' hells else would I be able to get an' receive messages in some o' th' places we have been? */
  ++ @13714 /* [PC] I.... had never though about that. */ + a5218
  ++ @13715 /* [PC] Perhaps it is time to let your followers know that they should stick to building a simple settlement. */ + a5218
  ++ @13716 /* [PC] Transferring messages via magical displacement of pebbles, followed by a courier system. Oh, let me count the many, many ways that could go wrong... */ + a5218
  ++ @13717 /* [PC] Well, I am sorry that your first big independent expedition ended in failure. */ + a5218
  ++ @13718 /* [PC] Well, I am sorry that  do not see how much they have accomplished on your behalf. */ + a5218
END

IF ~~ a5218
  SAY @13719 /* [ARAN] Hells. I just be disappointed, is all. But I did see somethin' in one o' those sets o' notes I picked up a ways back... hmmm... */
  = @13720 /* [ARAN] Swordcoastswordcoastswordcoast... err, no, that be naught.... lookin' for th' coastal region, not inland...  */
  = @13721 /* [ARAN] Mayhap... yes. There be an abandoned tower only two days travel up th' coast. Right here. Mayhap they will have better luck there. Now, to send off some sort o' plan... */
  IF ~~ THEN EXIT
END 
Link to comment

Archived

This topic is now archived and is closed to further replies.

×
×
  • Create New...