Yet more fixes

[CamDawg]

Yet more fixes via PM, the same who sent the previous batch of fixes.

// wrong string over Delon's head - from Firkraag's "I have an offer" to "Please! Won't somebody listen to me?"
COPY_EXISTING ~delon.bcs~ ~override~
  DECOMPILE_AND_PATCH BEGIN
    REPLACE_TEXTUALLY ~DisplayStringHead(Myself,20820)~ ~DisplayStringHead(Myself,20821)~
  END

// wrong sounds and restore dialog - vicg3 is a fanatic, not Amnian soldier
COPY_EXISTING ~vicg3.cre~ ~override~
  WRITE_LONG  0x0a4 61631 // Kneel and repent!
  WRITE_LONG  0x0b8 61639 // No! My... my god will save me!
  WRITE_LONG  0x0c8 61636 // Death to the disbeliever!
  WRITE_LONG  0x10c 61631 // Kneel and repent!
  WRITE_LONG  0x110 61633 // Cast off your old beliefs and be saved!
  WRITE_LONG  0x114 61634 // I am one of the few who are chosen.
  WRITE_LONG  0x118 61635 // Why do you persist with your false gods?
  WRITE_LONG  0x1b8 61636 // Death to the disbeliever!
  WRITE_ASCII 0x2cc ~vicg3~ #8
  BUT_ONLY

// females with male sounds
COPY_EXISTING ~udelf03.cre~ ~override~
  WRITE_LONG 0x0a4 11063 // Good day and hello to you.
  WRITE_LONG 0x0ec 11075 // [felff05]
  WRITE_LONG 0x0f0 11076 // [felff06]
  WRITE_LONG 0x10c 11070 // Few of the fair folk concern themselves with the affairs of the state.
  WRITE_LONG 0x110 11065 // I much prefer the wooded regions, but one must be flexible in these times.
  WRITE_LONG 0x114 11063 // Good day and hello to you.
  WRITE_LONG 0x118 11070 // Few of the fair folk concern themselves with the affairs of the state.
  BUT_ONLY

// gnomes using halfling animations
COPY_EXISTING ~cyrando.cre~ ~override~
  WRITE_LONG 0x28 24580 // CLERIC_MALE_GNOME
  BUT_ONLY

// gnomes using halfling animations
COPY_EXISTING ~celvan.cre~ ~override~
  WRITE_LONG 0x28 24836 // FIGHTER_MALE_GNOME
  BUT_ONLY

// restoring dialog
COPY_EXISTING ~kpsold03.cre~ ~override~
  WRITE_ASCII 0x2cc ~kpsold03~ #8
  BUT_ONLY

// burch shouldn't use giran's scripting; often left before you had a chance to speak with him
COPY_EXISTING ~burch1.cre~ ~override~
  WRITE_ASCII 0x250 ~~ #8 // blanks boy1, which made him leave after hannah is rescued 
  BUT_ONLY

// helpful folks disappear before they can actually help; see also vvhelp.dlg, ar0700.are
COPY_EXISTING ~vvhelp.cre~ ~override~
              ~vvpriest.cre~ ~override~
  WRITE_ASCII 0x248 ~~ #8 // delete vvshaesc from override
  BUT_ONLY

// descript: May place 3 slots into the proficiency 'two weapon fighting style'
COPY_EXISTING ~weapprof.2da~ ~override~
  SET_2DA_ENTRY 31 41 1 ~1~ // 2 > 1 star for swashbucklers in two-handed style
  SET_2DA_ENTRY 32 41 1 ~1~ // 2 > 1 star for swashbucklers in sword and shield style
  SET_2DA_ENTRY 33 41 1 ~1~ // 2 > 1 star for swashbucklers in one-handed style
  BUT_ONLY

// helpful folks disappear before they can actually help; see also vvhelp.cre, vvhelp.dlg, vvpriest.cre
COPY_EXISTING ~ar0700.are~ ~override~
  LPF ALTER_AREA_ACTOR INT_VAR flag_time_0 = 1 flag_time_1 = 1 flag_time_2 = 1 flag_time_3 = 1 flag_time_4 = 1 flag_time_19 = 1 flag_time_20 = 1 flag_time_21 = 1 flag_time_22 = 1 flag_time_23 = 1 // present only at night
    flag_time_5 = 0 flag_time_6 = 0 flag_time_7 = 0 flag_time_8 = 0 flag_time_9 = 0 flag_time_10 = 0 flag_time_11 = 0 flag_time_12 = 0 flag_time_13 = 0 flag_time_14 = 0 flag_time_15 = 0 flag_time_16 = 0 flag_time_17 = 0 flag_time_18 = 0
    STR_VAR actor_name = "Priest of Talos" END

And the additional dialogue fixes:

// wrong answer to reply
ALTER_TRANS RGRWLF01 BEGIN 6 END BEGIN 1 END BEGIN ~EPILOGUE~ ~GOTO 18~ END

// adds a cernd line to jaheira's interjection; originally > cernd 16, now cernd 78 > 16
ALTER_TRANS BJAHEIR BEGIN 15 END BEGIN END BEGIN ~EPILOGUE~ ~EXTERN CERND 78~ END

// adds one more line, routes 15 > 16 instead of just 16
ALTER_TRANS TRGRD03 BEGIN  4 END BEGIN 2 3 END BEGIN ~EPILOGUE~ ~GOTO 15~ END
ALTER_TRANS TRGRD03 BEGIN 15 END BEGIN     END BEGIN ~EPILOGUE~ ~GOTO 16~ END

// restores one more line about STs
ALTER_TRANS BODHI BEGIN 85 END BEGIN END BEGIN ~EPILOGUE~ ~GOTO 86~ END

// restoring one more line makes a better response from Bodhi here
ALTER_TRANS BODHI BEGIN 11 END BEGIN 0 END BEGIN ~EPILOGUE~ ~GOTO 14~ END

// restore one more line about bodhi
ALTER_TRANS ARAN BEGIN 24 END BEGIN 0 END BEGIN ~EPILOGUE~ ~GOTO 11~ END

// helpful folks disappear before they can actually help; see also vvhelp.cre, vvpriest.cre, ar0700.are
ALTER_TRANS VVHELP BEGIN 7 END BEGIN 0 END BEGIN ~ACTION~ ~EscapeArea()~ END

// was 9 > 14, now 9 > 13 > 14 for better reply
ALTER_TRANS PPSAEM2 BEGIN 9 END BEGIN 1 END BEGIN ~EPILOGUE~ ~GOTO 13~ END

// dialogue only appropriate for player1
ADD_STATE_TRIGGER SAHKNG01 62 ~InPartySlot(LastTalkedToBy,0)~

// gives Mazzy a bit more exposition, same routing now as state 0
ALTER_TRANS MAZZY BEGIN 15 END BEGIN 2 END BEGIN ~EPILOGUE~ ~GOTO 45~ END

// restore one more line for Keldorn rejoining
ALTER_TRANS KELDORP BEGIN 30 END BEGIN 0 END BEGIN ~ACTION~ ~~ ~EPILOGUE~ ~GOTO 31~ END // delete joinparty from 30, as 31 already has it

// restore one more line for Yoshimo rejoining
ALTER_TRANS YOSHP BEGIN 4 END BEGIN 1 END BEGIN ~ACTION~ ~~ ~EPILOGUE~ ~GOTO 1~ END // delete joinparty from 4, as 1 already has it

// restore one more line for Nalia rejoining
ALTER_TRANS NALIAP BEGIN 6 END BEGIN 1 END BEGIN ~ACTION~ ~~ ~EPILOGUE~ ~GOTO 14~ END// delete joinparty from 6, as 14 already has it

// restore one more line for Edwin rejoining
ALTER_TRANS EDWINP BEGIN 4 8 END BEGIN 0 END BEGIN ~ACTION~ ~~ ~EPILOGUE~ ~GOTO 1~ END// delete joinparty from 4&8, as 1 already has it

// jan's interjection only makes sense if Valygar is dead
ALTER_TRANS TOLGER BEGIN 76 END BEGIN 0 END BEGIN TRIGGER ~~ END
ADD_TRANS_TRIGGER TOLGER 76 ~Dead("valygar")~  DO 3
ALTER_TRANS EDWINJ BEGIN 49 END BEGIN 0 END BEGIN TRIGGER ~~ END
ADD_TRANS_TRIGGER EDWINJ 49 ~Dead("valygar")~  DO 2
ALTER_TRANS NALIAJ BEGIN 233 END BEGIN 0 END BEGIN TRIGGER ~~ END
ADD_TRANS_TRIGGER NALIAJ 233 ~Dead("valygar")~  DO 1

// viconia has an interjection available here before aerie
EXTEND_BOTTOM JAHEIRAJ 391
  IF ~IsValidForPartyDialog("Viconia")~ EXTERN ~VICONIJ~ 56
END

Edited November 27, 2017 by CamDawg

[Prof Errata]

Does it mean that the BG2 Fixpack v12 is practically finished ?

[Jarno Mikkola]

@CamDawg: Will the Fixpack be for the EE games too ?... cause the Kit.ids/kitlist.2da & kitplacement is really screwed between the two games and the Fixpack would be a good place to fix it in. Lession to learn from that, when making official games, don't use unofficial tools with features like the assigned kit placement.
Or, we'll need to have that issue reported, and wait for the next official patch for both games.